"Tailkinker" <gro### [at] yahoocouk> wrote in message
news:3ddce1d3@news.povray.org...
> I've been working on this Star Wars ship, and want to use it in an
> animation.  For the engine glow, I've been using a rack of light_source.
> The problem is, not only does it slow the trace down to a crawl, it
> doesn't even look right.  So:  Is there a way I can get a nice blazing
> blue-white engine flame for this ship?
>

Some emitting media? You might want to add a light as well to the media to
illuminate the near-by bits of ship.

basic example:

#version 3.5;

#include "colors.inc"

global_settings {
  assumed_gamma 1.0
}

// ----------------------------------------

camera {
  location  <0.0, 0.5, -4.0>
  look_at   <0.0, 0.0,  0.0>
}

// ----------------------------------------

#declare BasicShip =
union{
  box{
    0,1
    translate -0.5
  }

  difference{
    cylinder{
      0,x*1,0.25
    }
    cylinder{
      0,x*1.1,0.2
    }
  }
  sphere{
    0,0.2
    pigment{rgbf 1}
    interior{
      media{
        method 3
        emission rgb 1
        density{
          spherical
          turbulence 0.05
          scale 0.2
          density_map{
            [0 rgb 0]
            [0.5 rgb <0,0,2>]
            [1 rgb 5]
          }
        }
      }
    }
    hollow
    scale<4,1,1>
    translate x*1
  }
  light_source{
    0
    rgb<0,0,0.5>
    translate x*1.5
  }
  pigment{Gray}
}

object{
  BasicShip
  rotate y*45
}

Post a reply to this message

Attachments:
Download 'xwing.jpg' (4 KB)

Preview of image 'xwing.jpg'