3DC### [at] scrippsedu...
> I have been using POVray for a while but one thing that really mystifies
> me is the media function. Are there any good tutorial out there? At this
> point I can't even get a glowing sphere.

/* Try this. It's a macro made by Warp to create
glows. Study it and change some settings in the media
statement to see the effect  */

#macro Glow(GlowColor, Scale)
  sphere
  { 0, 1 hollow no_shadow
    pigment { rgbt 1 }
    interior
    { media
      { emission 1/Scale
        density
        { spherical density_map
          { [0 rgb 0][.5 rgb GlowColor*.5][1 rgb 1]
          }
        }
        samples 1,1 intervals 1 confidence .1 // quite fast settings
        method 3
      }
    }
    scale Scale
  }
#end

camera { location -z*10 look_at 0 angle 35 }
plane { y,-2 pigment { checker rgb 1, rgb .5 } }

light_source
{ <-1.5,1,0>, <1,.5,0>
  looks_like { Glow(<1,.5,0>, .5) }
}
light_source
{ <2,.5,0>, <0,.5,1>
  looks_like { Glow(<0,.5,1>, 1) }
}

object { Glow(<0,.5,1>, 1) translate 0 }

// Bye

Post a reply to this message