Nice image!

In article <3d24746e@news.povray.org>, Bryan wrote:

>I tried media, and transparency, but niether seems to work.
>if I make the beams too transparent, they have shadows on them, media won't
>'scatter' ambient light...
>
>Can I get a suggestion on how to do this?

You might try using media with a "cylindrical" density. I've found it
to work well for this sort of thing. For example (using megapov or
3.5 beta)

camera {
   location <0, 0, -1>
   look_at <0, 0, 1>
  }

cylinder {
   <0, -1, 0>,
   <0, 1, 0>,
   0.01

   hollow

   texture {
     pigment { colour rgbt <1, 1, 1, 1> }
    }

   interior {
     media {
        emission 30
        method 3
        intervals 1
        samples 3
        density {
            cylindrical
            colour_map {
                 [0.0 rgb <0, 0, 0>]
                 [0.5 rgb <0.2, 0, 0>]
                 [1.0 rgb <1, 0, 0>]
                }

            scale <0.01, 1, 0.01>
           }
       }
    }
  }

You can adjust the profile of the beam by fiddling with the
colour_map. Hope that helps,

Tom York

Post a reply to this message