I think I know what you want to do. Only thing I could come up with in a
texture-only sort of way:

/* nonaffect of light on a planes pigment diffusion */

#declare Norm=1;

camera {
  location  <0,2,-4>
  right x*image_width/image_height
  look_at   y
}

light_source {
  <0,1000,0>, 1
  rotate <-60,0,-60> // rotation off y
}

plane {
  y, 0
  pigment {rgb 1}
 #if (Norm)
  normal {gradient y 1 // matching light position (axis)
         ramp_wave
         scale 1000000 // sufficiently large scale to cover area
         rotate <-60,0,-60> // matching light rotation
  }
 #end
  finish {ambient 0.1 diffuse 0.6}
}

sphere {
        y,1
        pigment {
                color rgb 1
        }
}

This effectively sets up a normal that gives a uniformity to the light
shining on the plane. This was a quick attempt at it and so I don't know if
it'll work out well under other circumstances. It might need elaboration of
the idea.
My first thought was you needed a light_group but thought that to get both
shadow and non-diffusing together could prove difficult or impossible.
However, I didn't even try to find out so maybe that's another way.

bob h

Post a reply to this message