JRG <jrg### [at] hotmailcom> wrote:
> Either post a wallpaper version or the source.

global_settings { photons { count 100000 } }

#macro Glow(Col, Scale)
  sphere
  { 0,1 pigment { rgbt 1 }
    hollow
    interior
    { media
      { emission 1/Scale
        density { spherical density_map { [0 rgb 0][1 rgb Col] } }
      }
    }
    scale Scale
  }
#end

camera { location <-4.5,2,-5> look_at 0 angle 35 }
light_source
{ 0, 1
  looks_like { Glow(1, .2) }
  fade_power 2 fade_distance 2
  area_light x*.2,y*.2,7,7 adaptive 0 circular orient
}
light_source
{ x*4+z*3, <1,.5>
  looks_like { Glow(<1,.5>, .2) }
  fade_power 2 fade_distance 2
  area_light x*.2,y*.2,7,7 adaptive 0 circular orient
}
plane
{ y,-1 pigment { rgb <.5,.8,1> }
  finish { specular .5 reflection { .2,.5 } conserve_energy }
}
union
{ #declare Ind=-2;
  #while(Ind<=7)
    sphere
    { <Ind,-.75,1>, .25
      photons { target reflection on refraction on collect off }
    }
    sphere
    { <Ind,-.75,2>, .25
      photons { target reflection on refraction on collect off }
    }
    #declare Ind=Ind+1;
  #end
  pigment { rgbf <1,1,1,.9> }
  finish { specular .6 roughness .02 reflection { .2,.5 } }
  interior { ior 1.5 }
}


-- 
#macro M(A,N,D,L)plane{-z,-9pigment{mandel L*9translate N color_map{[0rgb x]
[1rgb 9]}scale<D,D*3D>*1e3}rotate y*A*8}#end M(-3<1.206434.28623>70,7)M(
-1<.7438.1795>1,20)M(1<.77595.13699>30,20)M(3<.75923.07145>80,99)// - Warp -

Post a reply to this message