I just finished this animation.  Took a while to debug, etc.

//BEGIN SOURCE
/*
[Animated, 20 frames]
Initial_Frame=1
Final_Frame=20
Width=512
Height=384
Cyclic_Animation=on

[]
*/

/////////////////
//RIPPLED WATER//
/////////////////

#declare stereogram=0;
#if (stereogram)
  #version unofficial MegaPov 0.7;
  global_settings {
    post_process{depth{7,11}}
  }
#end

#declare minc=0.1;
#declare x1=-8;
#declare x2=8;
#declare y1=-6;
#declare y2=6;
#declare os=clock;
#debug concat(str(os,0,5),"\n")
light_source {
  <0,-5,10>, color rgb 1
}
camera {
  location <0,-5,10>
  look_at <0,0,0>
}
#declare MTex = texture{pigment{color rgb <0,0,1>}}
#macro Pyth(px,py)
  sin(sqrt(sqr(px)+sqr(py))*2+(os*2*pi))/3
#end
#macro SinTri (xd,yd,inc)
  triangle {
    <xd,yd,Pyth(xd,yd)>,
    <xd+inc,yd,Pyth(xd+inc,yd)>,
    <xd,yd+inc,Pyth(xd,yd+inc)>
    texture{MTex}
  }
  triangle {
    <xd+inc,yd,Pyth(xd+inc,yd)>,
    <xd,yd+inc,Pyth(xd,yd+inc)>,
    <xd+inc,yd+inc,Pyth(xd+inc,yd+inc)>
    texture{MTex}
  }
#end
mesh {
  #declare sx=x1;
  #declare sy=y1;
  #while (sx<=x2)
    #while (sy<=y2)
      SinTri(sx,sy,minc)
      #declare sy=sy+minc;
    #end
    #declare sx=sx+minc;
    #declare sy=y1;
  #end
}
//END SOURCE

If you render this, make sure you set the INI file to the scene file.

_________________
Chris Howie
cra### [at] yahoocom
http://winimizer.virtualave.net

Post a reply to this message

Attachments:
Download 'Wave.m1v.mpg' (39 KB)