Here is an example of isosurfaces.  The POV code is below.
The rendering time is about 6 min for [640x480 No AA] on my PC (Celeron
600MHz).
R. Suzuki

#version 3.5;
#include "colors.inc"
#include "functions.inc"
#include "metals.inc"
#include "stones.inc"

camera {location  <0.0, 2.8, -4.0>  direction 1.8*z
        right     x*image_width/image_height
        look_at   <0.0, 0.2,  0.0>}

sky_sphere { pigment { gradient y
    color_map { [0.0 rgb <0.6,0.7,1.0>] [0.7 rgb <0.0,0.1,0.8>]}
}}
light_source { <0, 0, 0> color rgb 1.8 translate <-30, 30, -30>}

object{isosurface {
 function  {
          f_r((mod(x*80+160+sin(y*pi*3+f_noise3d(x*10,y*2,z*10)*pi*0.5
             +f_noise3d(x*39,y*3,z*41)*pi*y*0.3)*3,1)-0.5)*0.0125,0,
            (mod(z*80+160+sin(y*pi*3+f_noise3d(x*7.3,y*3,z*8.65)*pi)*3,1)
             -0.5)*0.0125)+y*y*0.04  | y-0.02   }
            contained_by { box { <-2,0.0,-2> <2,0.34,2> } }
            threshold 0.005
            accuracy 0.0005
            max_gradient 2
            rotate y*-2
            scale 2
            texture { pigment{gradient y
                  color_map { [0.0 rgb 0] [0.80 rgb 0.7] }
                }
                finish{ambient 0.25 diffuse 0.5 specular 0.4}
            }
}}

sphere{<0,0.55,-0.5>,0.4 texture {T_Stone19 scale 0.4} }

#declare pi_half=pi/2;
#declare pi_2=pi*2;
isosurface {
     function { f_mesh1(atan2(x,z)/pi_half,f_torus(x,y,z,0.75,0.15),
       atan2(y, f_r(x,0,z)-0.75)/pi_2,1/70,1/70, 1, 0.0025, 1) }
        contained_by { box { <-1,-0.4,-1>, <1,0.6,1> } }
        threshold 0.002
        accuracy 0.0002
        max_gradient 1.2
        texture {T_Copper_3A}
        scale 1.4  translate <0,0.7,-0.5>
}

Post a reply to this message

Attachments:
Download '011031b.jpg' (70 KB)

Preview of image '011031b.jpg'