> I tried it. I'm not sure how high was my max_trace_level but space
> between single copies was very dark. Maybe problem was I used for them
> union and/or merge. I will try it and on Monday send to you result to
> compare with MegaPov's picture. Thank you very much

Here a small example (image below) :

#global_settings{max_trace_level 41}
background{rgb 1}
light_source {-z*10000 1 rotate x*25 rotate y*30}
#declare Propeller=sphere{0,0.5 translate y*0.5
 texture{
  pigment{
   gradient y
   poly_wave 0.5
   color_map{
    [0 rgbf <1,1,1,0.94>][0.95 rgbf <1,1,1,1>][1 rgbf <1,1,0.9,1>]
   }
  }
  finish{ambient 0 diffuse 0}
 }
 scale <0.5,5,0.1>
 rotate -y*15
}
#declare i=0;
#declare nc = 20; // number of copies
#declare maxr=30; // max angle of rotation
union{
    #while (i<nc)
        object{Propeller rotate z*maxr*((i/nc))}
        object{Propeller rotate z*i*maxr/nc rotate z*120}
        object{Propeller rotate z*i*maxr/nc rotate z*240}
        #declare i=i+1;
    #end
    difference{
     sphere{0,1}
     plane{z,0 inverse}
     texture{
      pigment{spiral1 1 color_map{[0.3 rgb 1][0.3 rgb 0]} scale <1,1,0.8>}
      finish{ambient 0 diffuse 1}
     }
      scale <0.8,0.8,1.5>
      translate z*0.3
    }
    rotate y*45
    translate z*10
}

G.
--

**********************
http://www.oyonale.com
**********************
- Graphic experiments
- POV-Ray and Poser computer images
- Posters

Post a reply to this message

Attachments:
Download 'propeller.jpg' (4 KB)

Preview of image 'propeller.jpg'