|
![](/i/fill.gif) |
An area light is the best option for that scene but if you were to want a
larger light source the area light shadow trick starts to break down. An
alternative that creates more realistic soft light|shadow is radiosity,
though it's considerably slower. Here's a short example (add +qr to the
command line). The sky sphere serves as the light source...the light in the
scene is used for the specular highlight only.
#include "colors.inc"
global_settings{
radiosity{
pretrace_start 0.01
pretrace_end 0.01
count 100
recursion_limit 1
nearest_count 4
error_bound 0.3
brightness 1
normal on
}
}
sky_sphere {
pigment {
gradient y
color_map {
[0 color <.2, .3, .4>]
[.9 color <.2, .3, .4>]
[1 color 5*White]
}
scale 2
translate -1*y
}
rotate -90*x
rotate 30*x rotate 45*y
}
camera {location <1, 5, -7> look_at 1*y angle 40}
light_source {<0, 0, -1000> color .0001*White
rotate 30*x rotate 45*y
}
sphere {<0, 1, 0>, 1
pigment {color White}
finish {phong 100000 phong_size 120 diffuse .7}
normal {bumps 1 scale .3}
}
plane {y, 0
pigment {color White}
finish {diffuse .7}
}
Post a reply to this message
|
![](/i/fill.gif) |