Chaps wrote:
>It took me about 20 hours to render the following code.

Nice function!
Try following code.

R. Suzuki
----------------------------------
#include "colors.inc"
#include "metals.inc"
#include "functions.inc"

global_settings{max_trace_level 4}

light_source
{
  <10, 10, 10>
  color rgb 1.0
}

light_source
{
  <-5, -5, -10>
  color rgb 1.0
}


camera
{
  location  <0.0 , 5.0 ,-7.0>
  look_at   <0.0 , 0.0 , 0.0>
  right     x*image_width/image_height
}


isosurface {
        function {

max(f_spiral(sin(3*atan2(z,x)),-3+f_r(x,y,z),y,0.3,0.1,3,1,1,1.5),
                   (-0.2+abs(-3.0+f_r(x,y,z)))*1.5)}
        contained_by { sphere { 0, 3.2 } }
        //threshold 0.0
        accuracy 0.001
        max_gradient 1.5
//        evaluate 1, 1.2, 0.99
        max_trace 1

        texture {
                bozo
                texture_map {
                        [0     T_Gold_3C]
                        [0.25  T_Gold_3E]
                        [0.5   T_Chrome_3E]
                        [0.75  T_Chrome_3E]
                        [1     T_Gold_3C]
                }
        }
}

Post a reply to this message