"JRG" <jrg### [at] hotmailcom> wrote in message
news:3bbe1623@news.povray.org...
> Just the colors? It looks really cool to me. Please tell us how you did
it.

    Messed with someone else's code from earlier today. Uh.... Mike
Williams, in the message "Cutting in isosurfaces" in povray.general


#declare Cut_Width = 0.1;
#declare Blobbyness = 0.001;
#declare Edge_Sharpness = 6;

#declare Sphere = function {f_sphere(x,y,z,1)} // Sphere
#declare Plane  = function {(abs(x)-Cut_Width)} // Double plane

isosurface {
  function { (1+Blobbyness) - Blobbyness^Sphere(x,y,z)
              + Blobbyness^(Plane(x,y,z)*Edge_Sharpness)
              + Blobbyness^(Plane(y,x,z)*Edge_Sharpness)
        }
        max_gradient 3000
        contained_by{sphere{0,1.01}}
        pigment {rgb 1}
}

    I changed it to ...

#include "functions.inc"

#declare Cut_Width = 0.03;
#declare Blobbyness = 0.001;
#declare Edge_Sharpness = 12;

#declare Sphere = function {f_sphere(x,y,z,1)} // Sphere
#declare Plane  = function {(abs(x)-Cut_Width)} // Double plane

isosurface {
  function { (1+Blobbyness) - Blobbyness^Sphere(x,y,z)
              + Blobbyness^(Plane(x,y,z)*Edge_Sharpness)
              + Blobbyness^(Plane(y,x,z)*Edge_Sharpness)
              + Blobbyness^(Plane(z,x,y)*Edge_Sharpness)
              + Blobbyness^(Plane(x+y,y,z)*Edge_Sharpness)
              + Blobbyness^(Plane(x-y,y,z)*Edge_Sharpness)
              + Blobbyness^(Plane(x+z,y,z)*Edge_Sharpness)
              + Blobbyness^(Plane(x-z,y,z)*Edge_Sharpness)
              + Blobbyness^(Plane(y+z,x,z)*Edge_Sharpness)
              + Blobbyness^(Plane(y-z,x,z)*Edge_Sharpness)
        }
        max_gradient 3000
        contained_by{sphere{0,1.01}}
        pigment {onion color_map {
                                       [0.0 rgb x*2.5]
                                       [1.0 rgb < 0.2, 0.2, 0.3 >]
                                       } // end color map
                                  scale 1.07
                                  turbulence 0.125
                } // end pigment
        //normal  { bozo 1 scale 0.05 turbulence 1 }
        finish  { ambient 0.5 }

Post a reply to this message