"Tony[B]" <ben### [at] catholicorg> ha scritto nel messaggio
news:3b8e6245@news.povray.org...
> That is a beautiful metal texture... explain how you did that... :)

It's a slightly modified version of a metal texture which I designed several
months ago (yes, now I remember which metal you were referring to, Jari...).
Here's the code:

#declare A=seed(123);
#declare m_r=0.3;

#declare t_irid =

texture {
wrinkles scale 0.1 warp {reset_children}
texture_map {
[0 pigment {
wrinkles
color_map {
#declare n=100;
#declare i=0;
#while (i<=1)
[i rgb
<1+m_r*rand(A)-m_r*rand(A),.93+m_r*rand(A)-m_r*rand(A),.9+m_r*rand(A)-m_r*ra
nd(A)>]
#declare i=i+1/n;
#end }
scale 0.025 }
finish {
ambient 0
diffuse 0.3
reflection_max 0.7
reflection_min 0.4
reflect_metallic
metallic
specular 1.3
roughness 0.007
brilliance 6}
normal {
dents 0.35
scale 0.05}]

[1 pigment {
wrinkles
color_map {
#declare n=100;
#declare i=0;
#while (i<=1)
 [i rgb
<.915+m_r*rand(A)-m_r*rand(A),.85+m_r*rand(A)-m_r*rand(A),.85+m_r*rand(A)-m_
r*rand(A)>]
#declare i=i+1/n;
#end }
scale 0.025 }
finish {
ambient 0
diffuse 0.4
reflection_max 0.6
reflection_min 0.3
reflect_metallic
metallic
specular .9
roughness 0.02
brilliance 5}
normal {
dents 0.5
scale 0.01}]} }

Obviously, since you are using a certain pov3.5 you may want to use
pigment_pattern instead of reset_children:

#declare t_irid =
texture {
pigment_pattern {
wrinkles color_map {[0 rgb 0][1 rgb 1]} scale 0.1}
texture_map { blah, blah, blah...
...but I've not tested this one.

To get the blurring effect of the reflections I've also changed the first
normal with:
normal {gradient y 0.3 scale 0.02 triangle_wave}

Cheers

--
Jonathan.

Post a reply to this message