Inspired by Dennis Clarke I made my own version of the SUN logo.
Here it is - and the source code is below (it's not very long).

Hope you like it.

Rune
--
\ Include files, tutorials, 3D images, raytracing jokes,
/ The POV Desktop Theme, and The POV-Ray Logo Contest can
\ all be found at http://rsj.mobilixnet.dk (updated January 28)
/ Also visit http://www.povrayusers.org

// Sun logo version by Rune S. Johansen
#declare Clock = cos(clock*pi)/-2+0.5;
#declare W = 0.8; // Thickness of letters
#declare D = 0.8; // Depth of letters
#declare U = // A single "U"
union {
   box {<-1-W,-2,-D>,<-1+W,3+W,D>}
   box {<+1+W,-2,-D>,<+1-W,3+W,D>}
   difference {
      cylinder {-D*z,+D*z,1+W}
      cylinder {-2*z,+2*z,1-W}
      box {<-2,0,-2>,<2,2,2>}
      translate -2*y
   }
   pigment {color <1,0.8,0>}
   finish {phong 1}
   rotate 180*y*Clock
   rotate 180*x*Clock
}
#declare UU = // Two U's
union {
   object {U rotate +90*z translate -2*y}
   object {U rotate -90*z translate +2*y}
   rotate 90*z*Clock
}
#declare Sun = // The whole logo
union {
   object {UU rotate 000*z translate <-4,+4,0> rotate +180*y*Clock}
   object {UU rotate 090*z translate <+4,+4,0> rotate -180*x*Clock}
   object {UU rotate 180*z translate <+4,-4,0> rotate -180*y*Clock}
   object {UU rotate 270*z translate <-4,-4,0> rotate +180*x*Clock}
}
object {Sun rotate 45*z}
camera {location -25*z look_at 0}
background {color rgb 1}
light_source {<1,2,-3>*1000, color 1}

Post a reply to this message

Attachments:
Download 'sun.mpg' (121 KB)