I would like to see images that are not easy to make without the patch.


#version Unofficial MegaPov 0.6;

#declare Texture = 3;

#switch(Texture)
  #case(1)
    #declare FurKindOf =
      texture
      { pigment
        { bozo color_map
          { [0 rgb .2][.25 rgb <.3,.3,.2>]
            [.75 rgb <.7,.7,.2>][1 rgb <.8,.8,.2>]
          }
          scale .4
          turbulence .2
        }
        finish { crand .15 }
      }

    sphere { 0,1.2 texture { FurKindOf } }
  #break
  
  #case(2)
    #declare Rust =
      texture
      { pigment
        { bumps color_map
          { [0 rgbt 1][.6 rgbt 1]
            [.6 rgb <1,.4,.2>][.9 rgb <.9,.7,.3>]
          }
          turbulence 1
          scale .3
        }
        normal { bumps .5 scale .02 }
      }

    #declare Rad=.2;
    #declare Loc=1.2-Rad;
    union
    { cylinder { <-Loc,-Loc,-Loc>,<-Loc,-Loc, Loc>,Rad }
      cylinder { < Loc,-Loc,-Loc>,< Loc,-Loc, Loc>,Rad }
      cylinder { <-Loc, Loc,-Loc>,<-Loc, Loc, Loc>,Rad }
      cylinder { < Loc, Loc,-Loc>,< Loc, Loc, Loc>,Rad }
      cylinder { <-Loc,-Loc,-Loc>,< Loc,-Loc,-Loc>,Rad }
      cylinder { <-Loc, Loc,-Loc>,< Loc, Loc,-Loc>,Rad }
      cylinder { <-Loc,-Loc, Loc>,< Loc,-Loc, Loc>,Rad }
      cylinder { <-Loc, Loc, Loc>,< Loc, Loc, Loc>,Rad }
      cylinder { <-Loc,-Loc,-Loc>,<-Loc, Loc,-Loc>,Rad }
      cylinder { <-Loc,-Loc, Loc>,<-Loc, Loc, Loc>,Rad }
      cylinder { < Loc,-Loc,-Loc>,< Loc, Loc,-Loc>,Rad }
      cylinder { < Loc,-Loc, Loc>,< Loc, Loc, Loc>,Rad }
      sphere { <-Loc,-Loc,-Loc>,Rad }
      sphere { <-Loc,-Loc, Loc>,Rad }
      sphere { <-Loc, Loc,-Loc>,Rad }
      sphere { <-Loc, Loc, Loc>,Rad }
      sphere { < Loc,-Loc,-Loc>,Rad }
      sphere { < Loc,-Loc, Loc>,Rad }
      sphere { < Loc, Loc,-Loc>,Rad }
      sphere { < Loc, Loc, Loc>,Rad }

      texture { pigment { rgb 0 } finish { reflection .4 } }
      texture { Rust }
    }
  #break
  
  #case(3)
    #declare ZigZagFunc =
      function { if(((abs((x+1000)%2.5-1.4)-.5)%1)*4-((y+1000)%1.2), 0, 1) }
    #declare ZigZag =
      pigment
      { function { ZigZagFunc(atan2(x,z)*15/pi,y,z) }
        color_map { [0 rgb z][1 rgb x] }
      }
    
    sphere { 0,1.2 pigment { ZigZag scale .3 } }
  #break
#end

camera { location <0,1,-8>*.9 look_at 0 angle 35 }
light_source
{ <10,20,-25>*2, 1
  spotlight point_at 0 radius 20 falloff 30
  area_light x*15,y*15,10,10 adaptive 2 orient
}
plane { y,-1.2 pigment { rgb 1 } }

Post a reply to this message

Attachments:
Download 'pic1.jpg' (14 KB) Download 'pic2.jpg' (24 KB) Download 'pic3.jpg' (21 KB)

Preview of image 'pic1.jpg'

Preview of image 'pic2.jpg'

Preview of image 'pic3.jpg'