here we go


I had to hack it a bit but It works exactly as I want

I took out the big glow but hey it looks great

Thanks dude


Zeger Knaepen wrote:

> Good enough?
> 
> Here's the code for the blade.  It's about .05 wide and 1 long and extends
> from <0,0,0> to <0,1,0>
> 
> #declare Bladecolor=<0,1,0>;
> sphere {
>  0,4
>  pigment{rgbt 1}
>  interior {
>   media {
>    emission 1
>    method 3
>    density {
>     spherical
>     color_map {
>      [0 rgb 0]
>      [1 rgb Bladecolor*.2]
>     }
>     scale <1,2,1>*<2,1,2>
>    }
>   }
>   media {
>    emission 1
>    method 3
>    density {
>     spherical
>     color_map {
>      [0 rgb 0]
>      [.05 rgb Bladecolor]
>      [.1 rgb 1]
>     }
>     scale .5
>    }
>    density {
>     cylindrical
>     color_map {
>      [.8 rgb 0]
>      [.9 rgb Bladecolor*2]
>      [.95 rgb 10]
>      [1 rgb 40]
>     }
>    }
>   }
>   media {
>    emission 1
>    method 3
>    density {
>     spherical
>     color_map {
>      [0 rgb 0]
>      [1 rgb (<1,1,1>+Bladecolor)*5]
>     }
>     poly_wave 4
>     scale <.3,1,.3>
>    }
>    density {
>     spherical
>     color_map {
>      [0 rgb 0]
>      [.2 rgb 1]
>     }
>     translate y*1
>    }
>    translate -y*.55
>    scale <2,1,2>
>   }
>  }
>  hollow
>  scale <.4,1,.4>
>  translate y*.5
> }
> 
> cu!
> --
> ZK AKA SaD
> http://www.povplace.be.tf
> "I don't take money, only girly giggles."
> 
> 
>

Post a reply to this message

Attachments:
Download 'test color.jpg' (41 KB)

Preview of image 'test color.jpg'