|
![](/i/fill.gif) |
Gail Shaw wrote:
>
> Very very nice. Are the clouds media or textured planes/boxes? Could I see
> the code for them
> please?
>
Thanks,
the clouds are fairly standard, used in quite a lot of my scenes, it's
just a bozo pattern on a sphere:
#declare P_Clouds1=
pigment {
gradient z
pigment_map {
[ 0.3
bozo
color_map {
[0.2 color rgbt < 0.91, 0.96, 0.99, 0.0>]
[0.4 color rgbt < 0.91, 0.96, 0.99, 1.0>]
}
turbulence 0.85
lambda 2.8
omega 0.6
octaves 8
scale <0.5,0.5,0.2>
]
[0.5 color rgbt 1]
}
rotate 80*z
}
#declare Sky_Bckg_13 =
texture {
pigment {
gradient z
color_map {
[0.0 color rgb < 0.780, 0.835, 0.976 >]
[0.27 color rgb < 0.300, 0.450, 0.950 >]
}
turbulence 0.05
}
finish { diffuse 0 ambient 1 }
}
texture {
pigment { P_Clouds1 }
finish { diffuse 0 ambient 1 }
}
sphere {
<0, 0, 0>, 1
texture {
Sky_Bckg_13
rotate -20*z
}
scale<1000, 1000, 200>
no_shadow
hollow on
}
--
Christoph Hormann <chr### [at] gmx de>
IsoWood include, radiosity tutorial, TransSkin and other
things on: http://www.schunter.etc.tu-bs.de/~chris/
Post a reply to this message
|
![](/i/fill.gif) |