In this version, adding a non-zero reflection to the hexagon plane makes
the intended invisible heat-haze plane noticeable.

... The question is, why?

That part of the heat-haze plane should be completely transparent and
has only a negligible ior of 1.01. (The ior 1.01 is needed for POVRay to
have to normals modifiers take effect.)

The little chunk of code is:


light_source { <500,1000,-750> color rgb <1,1.1,1.125>}
light_source { <-25,150,50> color rgb <.5,.33,.25> shadowless}

camera
{
  location  <0,7.5,-30>
  angle 34
  look_at   <0,5.75,0>
  rotate -5*y
}


// a heat-haze effect

#declare HotWave=
texture {pigment {rgbf 0.97} finish{reflection 0} normal {wrinkles 0.4}
scale <0.0011,0.07,0.1>}

#declare CoolWave=
texture {pigment {rgbf 0.99} finish{reflection 0} normal {wrinkles 0.1}
scale <0.0017,0.05,0.15>}

#declare NoWave=
texture {pigment {rgbf 1} finish{reflection 0 ambient 0} normal
{wrinkles 0}}


plane {-z, 0
      material {          
        texture {gradient y
          texture_map {
                [.00 NoWave]
                [.02 NoWave]
                [.11 HotWave]
                [.23 CoolWave]
                [.33 CoolWave]
                [.45 NoWave]
          }
          scale <1,55,1>
        }
        interior {ior 1.01}
      }
      rotate 66*x
      translate 7*z
      translate 44*x
}


plane{
  y, 0.12
  texture{ hexagon
    texture{
      pigment{ color rgb <0.5, 0.2, 0.1> }
      finish { crand 0.15  ambient .5  phong 0.7  reflection 0.27 }
    },
    
    texture{
      pigment{ color rgb <0.2, 0.2, 0.5> }
      finish { crand 0.00  ambient .3  phong 0.3  reflection 0.40 }
    }, 
    
    texture{
      pigment{ color rgb 0.5 }
      // A non-zero reflection value here shows the heat-haze plane!
      finish {  crand 0.05  ambient .50   phong 1  reflection 0.43 }
    }
    
    scale 7.99   
  }
} 

#include "colors.inc"
#include "skies.inc"
sky_sphere {S_Cloud2}

 
-- 
----------------
Martin Lomas
mar### [at] ml1couk
----------------

Post a reply to this message

Attachments:
Download 'galileo thermometer 05 cr.jpg' (82 KB)

Preview of image 'galileo thermometer 05 cr.jpg'