|
![](/i/fill.gif) |
I've just finished the 'view from orbit' picture I've been working on
for the last month. I didn't really use realistic cloud shapes, but
used my camera's vantage point to try and fake some descent clouds using
a marble pattern with a bozo pattern in a pigment_map.
I'll be posting the image on my website when I get a few moments.
http://website.lineone.net/~sacrofts/home.htm
Actually I just finished the image this evening, so give me a day or to
:-)
Below is the code I used for my cloud layers, hope it's of use!
---code
#declare Altocumulus =
texture {
pigment{marble scallop_wave
turbulence 0.8 octaves 9
scale 2000 rotate z*-35 rotate y*-9
pigment_map{
[0.0 bozo turbulence 0.25 scale 0.01 color_map{
[0.0 rgbt 1]
[0.4 rgb 0 ]
[1.0 rgb 0 ]}
]
[0.02 bozo scale 0.01 color_map{
[0.0 rgbt 1]
[0.4 rgb 0 ]
[1.0 rgb 0 ]}
]
[0.2 bozo turbulence 0.5 scale 0.01 color_map{
[0.0 rgbt 1]
[0.7 rgb 0 ]
[1.0 rgb 0 ]}
]
[0.85 rgbt 1]
[1.0 rgbt 1]
}
}
}
#declare Altocumulus2 =
texture {
pigment{marble scallop_wave
turbulence 0.8 octaves 9
scale 2000 rotate z*-35 rotate y*-9
pigment_map{
[0.0 bozo turbulence 0.25 scale 0.009 color_map{
[0.0 rgbt 1]
[0.4 rgb 1 ]
[1.0 rgb 1 ]}
]
[0.02 bozo scale 0.01 color_map{
[0.0 rgbt 1]
[0.4 rgb 1 ]
[1.0 rgb 1 ]}
]
[0.2 bozo turbulence 0.5 scale 0.009 color_map{
[0.0 rgbt 1]
[0.7 rgb 1 ]
[1.0 rgb 1 ]}
]
[0.85 rgbt 1]
[1.0 rgbt 1]
}
}
}
#declare Stratus =
texture{
pigment{ gradient x
pigment_map{
[0.42 color rgbt 1]
[0.45 wrinkles rotate z*45 frequency 25 scale <1,5,1>
color_map{
[0.29 rgbt 1]
[0.3 rgbt <1,1,1,0.2>]
[0.5 rgbt <1,1,1,0.2>]
[0.56 rgbt 1]
[1.0 rgbt 1]} ]
[0.55 wrinkles rotate z*45 frequency 25 scale <1,5,1>
color_map{
[0.29 rgbt 1]
[0.3 rgbt <1,1,1,0.2>]
[0.5 rgbt <1,1,1,0.2>]
[0.56 rgbt 1]
[1.0 rgbt 1]} ]
[0.56 color rgbt 1]}
scale <1000,1000,1000> rotate <0,23,60> turbulence 0.25
octaves 10}
pigment{ granite rotate <-6,-20,0>
color_map{
[0.0 rgbt 1]
[0.2 rgbt 1]
[0.5 rgb 1]
[0.8 rgbt 1]
[1.0 rgbt 1]}
}
}
sphere {0,7977
texture {Stratus}
}
sphere {0, 7969
texture {Altocumulus }
texture {Altocumulus2 rotate x*-0.02 }
}
Post a reply to this message
|
![](/i/fill.gif) |