thanks, i was thinking that uv mapping was megapov only so i was only
looking there.  no i just have to figure out which tringle is which and
what i want to texture it with.

Nathan Kopp wrote:
> 
> "ryan constantine" <rco### [at] yahoocom> wrote...
> > > >, or do i need to convert to mesh2?  if so how?  or can i use
> > > > uv mapping?  how?
> > >
> > > Yes.
> >
> > which?  all?
> 
> Yes, you can use uv mapping. You do not have to convert to mesh2.
> 
> > i read it, but i'm a little foggy.  as a regular mesh, there are no face
> > entries right?  unless i'm blind i only saw instructions for texturing
> > mesh2 objects.
> 
> Are you looking in the MegaPov documentation or the official POV 3.1
> documentation?  I was referring to the 3.1 docs.  From that documentation,
> in the "Mesh Object" section, you'll read:
> 
> ------ begin quote -------
> Now let's begin. We will create a simple box with differently colored sides.
> We create an empty file called meshdemo.pov and add the following lines.
> 
>   camera {
>     location <20, 20, -50>
>     look_at <0, 5, 0>
>   }
>   light_source { <50, 50, -50> color rgb<1, 1, 1> }
>   #declare Red = texture {
>     pigment { color rgb<0.8, 0.2, 0.2> }
>     finish { ambient 0.2 diffuse 0.5 }
>   }
>   #declare Green = texture {
>     pigment { color rgb<0.2, 0.8, 0.2> }
>     finish { ambient 0.2 diffuse 0.5 }
>   }
>   #declare Blue = texture {
>     pigment { color rgb<0.2, 0.2, 0.8> }
>     finish { ambient 0.2 diffuse 0.5 }
>   }
> 
> We must declare all textures we want to use inside the mesh before the mesh
> is created. Textures cannot be specified inside the mesh due to the poor
> memory performance that would result.
> 
> Now we add the mesh object. Three sides of the box will use individual
> textures while the other will use the global mesh texture.
> 
>   mesh {
>     /* top side */
>     triangle { <-10, 10, -10>, <10, 10, -10>, <10, 10, 10>
>       texture { Red }
>     }
>     triangle { <-10, 10, -10>, <-10, 10, 10>, <10, 10, 10>
>       texture { Red }
>     }
>     /* bottom side */
>     triangle { <-10, -10, -10>, <10, -10, -10>, <10, -10, 10> }
>     triangle { <-10, -10, -10>, <-10, -10, 10>, <10, -10, 10> }
>     /* left side */
>     triangle { <-10, -10, -10>, <-10, -10, 10>, <-10, 10, 10> }
>     triangle { <-10, -10, -10>, <-10, 10, -10>, <-10, 10, 10> }
>     /* right side */
>     triangle { <10, -10, -10>, <10, -10, 10>, <10, 10, 10>
>       texture { Green }
>     }
>     triangle { <10, -10, -10>, <10, 10, -10>, <10, 10, 10>
>       texture { Green }
>     }
>     /* front side */
>     triangle { <-10, -10, -10>, <10, -10, -10>, <-10, 10, -10>
>       texture { Blue }
>     }
>     triangle { <-10, 10, -10>, <10, 10, -10>, <10, -10, -10>
>       texture { Blue }
>     }
>     /* back side */
>     triangle { <-10, -10, 10>, <10, -10, 10>, <-10, 10, 10> }
>     triangle { <-10, 10, 10>, <10, 10, 10>, <10, -10, 10> }
>     texture {
>       pigment { color rgb<0.9, 0.9, 0.9> }
>       finish { ambient 0.2 diffuse 0.7 }
>     }
>   }
> --------- end quote --------
> 
> >  is there a uv mapping tut' out there?
> 
> I don't think there currently is.  Sorry.
> 
> -Nathan

Post a reply to this message