|
|
ryan constantine wrote:
>
> are your textures procedural? if so, i'd like a peek if that's okay.
>
Hi Ryan. There is no problem to share the texture.
I wanted to give the ship the aspect of a very used one.
The fringes on the hull are made with normals. They are achieved with
radial and gradient x. The granite normal takes care of a bit of bumpiness.
To get the dust, to distinct pigment were used. The first one, to draw
the horizontal dust along the hull. The second one to have broad dark areas.
This texture was inspired by an image posted by H. E. Day.
Here is the code.
#declare Metal = <.95, .95, 1>; //bluish color
#declare HullTexture =
texture{
finish{reflection .05 phong .05 phong_size 50}
normal{average
normal_map{
[1 radial .05 frequency 4 rotate 90*z]
[1 gradient x .05 translate 8*x]
[.28 granite scale<2, 1, 1>]
}
}
pigment{
average translate -6*x
pigment_map{
[.4 bozo scale <1,.01,.05>
pigment_map{
[0 gradient x
color_map{[0 rgb 1.2*Metal] [1 rgb .8*Metal]}
]
[1 rgb .8*Metal]
}
]
[.6 bozo scale <2, .25, .25>
color_map{[0 rgb .65*Metal][1 rgb .9*Metal]}
]
}
}
}
Best regards,
Alberto
Post a reply to this message
|
|