"Sander" <san### [at] stolscom> wrote:
>
> I don't know about the gate itself: I never saw one before. But I like the
> floor very much - what do you do to the texture to give it this natural
> look?

Here's what I used (well, I've cleaned it up a bit for readability):

  #declare T_CleanFloor = texture { /* grey-blue painted cement */
    pigment { bozo
      colour_map {
        [0 rgb <0.8875,0.8875,0.9>]
        [1 rgb <0.7000,0.7500,0.8>]
      }
      warp { turbulence 1 lambda 2 omega 0.9 }
    }
    finish { specular 0.5 roughness 0.01 }
  }

  #declare T_FloorDirt = texture { /* dark brown, non-shiny dirt */
    pigment { colour rgb <0.55,0.45,0.35> } 
  }

  #declare T_DirtyFloor = texture { bozo
    texture_map {
      [0.75 T_CleanFloor]
      [1.00 T_FloorDirt]
    }
    warp { turbulence 1 lambda 3 omega 0.95 }
    scale 10
  }

I know it could have been done with a layered texture, but that
generally seems to render more slowly, and this image takes long enough
as it is!  :-)


-- 
Jeff Lee         shi### [at] gatenet         http://www.gate.net/~shipbrk/

Post a reply to this message