"Marc-Hendrik Bremer" <Mar### [at] t-onlinede> wrote in message
news:392925a6$1@news.povray.org...
|
| Well, I turned it on by +QR and it gave me some interessting effects: the
| divider and the candleholder seemed to glow (probablly because of the
| ambiente-finish of the metal.inc-textures (?)). Do I have to tweak the
| default settings?

I read that you made the ambient to be 0 (maybe), I should have suggested that
too if I knew you were using MegaPov.  Which I still don't know.  If you are,
you want a global_settings {ambient_light 0} when using the radiosity.
With reflection being used in the metals, or elsewhere for that matter, you
would want a low 'diffuse' also.
Here's something I tried just now to see how to go about roughing or enhancing
such an image.
Might not be anything worthwhile but never can be sure.

// could skip MegaPov and use official version instead, just leave parts out
#version unofficial MegaPov 0.5;

global_settings {
   assumed_gamma 2.2
   ambient_light 0
// comment or change much below here
// ini_option "+w80"
// ini_option "+h60"
 ini_option "+QR"
 ini_option "Preview_Start_Size=8"
 ini_option "Preview_End_Size=4"

   radiosity{
      count 60             // CHANGE range from 20 to 150
      nearest_count 5      // CHANGE range from 3 to 10
      error_bound 1        // CHANGE - range from 1 to 3 - should correspond
with Preview_End_Size
                            //   1 : preview_end_size = 4
                            //   3 : preview_end_size = 8
                            //   use preview_start_size = 16 (or 8 for high
quality)
                            // you can go lower than 1, but then you probably
will want to set
                            // preview_end_size to 2, which is really slow
      recursion_limit 3    // CHANGE

      low_error_factor .5  // leave this
      gray_threshold 0.0   // leave this
      minimum_reuse 0.015  // leave this
      brightness 2         // exaggerated

      max_sample 1         // CHANGE - this should be the same as the
brightest object
      adc_bailout 0.01/1   // CHANGE - use adc_bailout = 0.01 /
brightest_ambient_object
   }
}

#declare Wax=texture {pigment {rgb 1}
 finish {ambient .25 diffuse .75 phong .25 phong_size 25}}
#declare Hotwax=texture {pigment {rgbf <3,3,3,.1>}
 finish {ambient 10 diffuse .5 phong .5 phong_size 75 reflection .15}}

#declare Flame=
 sphere {0,1 scale <1,2,1>*.5
         pigment {rgbf<1,.75,.25,1>} finish {ambient .9 phong .9 phong_size
3}}

// candle
union {
 light_source { 0,<.75,.5,.25>
  looks_like {Flame}
 }
 cylinder {0,y,.5
        texture {gradient y texture_map {
                [0 Wax][1 Hotwax]
        } ramp_wave}
  scale <1,3,1> translate -4*y
 }
  translate <0,4,5>
}

// tabletop
plane {y,0 pigment {rgb <.75,.5,.25>}}

// objects
box {-1,1 pigment {rgb<.3,.6,.9>} translate <-6,1,3>}
box {-1,1 pigment {rgb<.3,.9,.6>} translate <-9,1,0>}
sphere {<7,0,-2>,3 pigment {rgb 1}}
cylinder {0,.25*y,2 pigment {rgb<.8,.85,.9>}
 finish {ambient 0 diffuse .3 reflection .6}}

// camera in media sphere

camera {
  location  <0,10,-10>
  angle 67
  look_at   2*y
// normal {granite .001 scale .001}
}

sphere {0,1 hollow no_shadow
 texture {pigment {rgbf 1.5} // >1 filter for over-saturation of highlights
  normal {granite 2 scale .02} finish {crand .2} // more imperfection
 }
 interior {
        media { method 1 // comment out for official POV-Ray
               intervals 1 samples 1,2
               absorption <.125,.25,.5>*1
          // extinction can change granularity, lower is smoother
         scattering {2,.5 extinction .75}
         density {rgb .25}
        }
  }
 translate <0,10,-10>
}

// ^^^^^^^^^^^^^^^^^^^^^^^^^^^^

Post a reply to this message