Ironically, you're not far from the truth.
Here are the texture declares I use:

#declare Scarring =
texture {pigment {bozo color_map {[0 rgb .175 transmit .75][1 rgb .175 transmit
1]}scale 2}}
texture {pigment {bozo pigment_map {[0 bozo color_map {[0 rgb .125 transmit .75][1 rgb
.125 transmit 1]}scale .125][.5 rgb .175 transmit 1]}scale 2}translate 25}
#declare Rusting =
texture {pigment {bozo color_map {[0 rgb <1,.5,.4> transmit .75][1 rgb <1,.5,.4>
transmit 1]}scale 2}}
texture {pigment {bozo pigment_map {[0 bozo color_map {[0 rgb <1,.5,.4> transmit
.75][1 rgb <1,.5,.4> transmit 1]}scale .125][.5 rgb .175 transmit 1]}scale 2}translate
25}
#declare Rusting2 =
texture {pigment {bozo color_map {[0 rgb <1,.5,.4> transmit .875][1 rgb <1,.5,.4>
transmit 1]}scale 2}}
texture {pigment {bozo pigment_map {[0 bozo color_map {[0 rgb <1,.5,.4> transmit
.875][1 rgb <1,.5,.4> transmit 1]}scale .125][.5 rgb .175 transmit 1]}scale
2}translate 25}
#declare Dirt =
texture {pigment {bozo color_map {[0 rgb <.6,.5,.4> transmit .75][1 rgb <.6,.5,.4>
transmit 1]}scale 2}}
texture {pigment {bozo pigment_map {[0 bozo color_map {[0 rgb <.6,.5,.4> transmit
.75][1 rgb <.6,.5,.4> transmit 1]}scale .125][.5 rgb <.6,.5,.4> transmit 1]}scale
2}translate 5}
#declare Chipping =
texture {
pigment {bozo pigment_map {[.4 bozo color_map {[.2 rgb 1 transmit .125][.3 rgb 1
transmit 1]} turbulence 1/2 scale .125/2][.5 rgb .175 transmit 1]}scale 8}
}
#declare Chipping2 =
texture {
normal {bozo normal_map {[.4 bozo normal_map {[.2 bumps scale 1/16/12 bump_size
1/12][.3 bumps scale 1/8 bump_size 0]} turbulence 1/2 scale .125/2][.5 bumps scale 1/8
bump_size 0]}scale 8}
pigment {bozo pigment_map {[.4 bozo color_map {[.2 rgb 1 transmit .125][.3 rgb 1
transmit 1]} turbulence 1/2 scale .125/2][.5 rgb .175 transmit 1]}scale 8}
}
#declare Chipping3 =
texture {
pigment {bozo pigment_map {[.4 bozo color_map {[.2 rgb 1.5][.3 rgb 1 transmit 1]}
turbulence 1/2 scale .125/2][.5 rgb .175 transmit 1]}scale 8}
}

I take these and layer them on, just like in the real world.  Here are some examples:

//Concrete Pavement Texture
pigment {rgb 1}
normal {dents scale 1 turbulence 1 bump_size 1/3}
finish {ambient .1 diffuse .9 phong .05 phong_size 2 crand .05}
texture {Scarring scale <1,4,4>}
texture {Scarring scale <1,4,4> scale 2}

//Adobe-like building texture:
pigment {rgb <1,.95,.9>}
normal {dents scale 1/4}
finish {ambient .1 diffuse .9 phong .05 phong_size 2 crand .1}
texture {Scarring scale 4*y}
texture {Scarring scale 4*y scale 2}
texture {Rusting2 scale 2*y scale 1/2 translate 20}
texture {Chipping scale 1/4}
texture {Rusting scale 2*y scale 2 translate -20}


//Signpost Texture:
pigment {rgb <.875,1,.8755>}
finish {ambient 0 diffuse 1 phong .25 phong_size 10}
texture {Scarring scale 4*y}
texture {Chipping scale 3/4}
texture {Rusting  translate 45 scale 4*y}

// A nice, frothy water texture.
pigment {rgb <.05,.1,.075>*2 transmit .25}
normal {granite .25
phase clock
translate  -5*x*clock
scale <1,1,4>*10}
finish {ambient 0 diffuse 1 phong 2 phong_size 200 metallic reflection .5
conserve_energy}
scale 2/3
}
texture {Chipping}
texture {Chipping2 scale 2}
texture {Chipping2 scale 4}
texture {Chipping3 scale 4 translate 20}
texture {Chipping3 scale 4 translate -20}
texture {Chipping2 scale 6}
interior { ior 1.33    media { absorption rgb (1-<.8,.9,1>)*50 method 2 }}


The sky is the limit.  Remember that there are no clean textures.  Every one should
have at least one {Scarring} texture applied to it.
Oh, By the way, these texture samples come from my next IRTC entry.  Please no one use
them to oust me, hmmm?

Good luck!

--
H.E. Day

Post a reply to this message