Simon de Vet wrote in message <387CE40F.87A18A6D@istar.ca>...
>What patch are you using?

Nathan Kopp's WinMegaPOV 0.3

>
>When I cut and paste the code for the asteroid into my MegaPatch, it
doesn't
>work :(
>

enclosed is the source to the posted scene (minus the standard radiosity
settings), it might help.

Justin

#local pov=<0,0.5,-1>;
#local dist=5;
#local poi=<0,0,-0.75>;
#local pov=vnormalize(pov)*dist+poi;
#local rot=0;//25*-z;
#local quality = 1;

camera {
 location pov
 sky vrotate(y*1,rot)
 right vrotate(x*4/3,rot)
 look_at poi
 normal { bump_map { png "logomask.png" interpolate 2 } 1 translate -0.5 }
}

global_settings {
 max_trace_level 20
 number_of_waves 20
}

#local tp1 =
 function {
  pigment {
   spiral1 1
   sine_wave
   colour_map {
    [0 rgb -1]
    [1 rgb 1]
   }
  }
 }

#local tp2 =
 function {
  pigment {
   granite
   scale 3
   colour_map {
    [0 rgb 0]
    [1 rgb 1]
   }
  }
 }

#local tp3 =
 function {
  pigment {
   onion
   frequency 5
   sine_wave
   translate y*0.5
   colour_map {
    [0 rgb 0]
    [1 rgb 1]
   }
  }
 }

#local tc1 = texture {
 pigment {
  granite
  scale 3
  colour_map {
   [0 rgb <0.5,0.1,0.1>]
   [0.1 rgb <0.8,0.5,0.1>]
   [1 rgb 1]
  }
 }
 finish {
  ambient 0
  diffuse 1
 }
}

#declare base=function {"Sphere",<1>}

#declare cracked=function {
 pigment {
  crackle
  colour_map {
   [0 rgb 0]
   [1 rgb 1]
  }
  scale 0.5
 }
}

#macro iso1()
 isosurface {
  function {
   base(x,y,z)+tp2(x,y,z)*0.2+cracked(x,y,z)
  }
  max_gradient 6
  eval
  accuracy 0.001
  bounded_by{sphere{0,1}}
  texture { tc1 }
  translate x*-1.5
 }
#end

#macro iso2()
 isosurface {
  function { base(x,y,z)+tp1(x,y,z)*0.2+tp2(x,y,z)*0.5 }
  max_gradient 63
  eval
  accuracy 0.001
  bounded_by { sphere { 0,1 } }
  texture { tc1 }
  translate x*1.5
 }
#end

#macro iso3()
 isosurface {
  function {
   base(x,y,z)+tp2(x,y,z)*0.2+tp3(x,y,z)*0.1
  }
  max_gradient 4
  eval
  accuracy 0.001
  bounded_by{sphere{0,1}}
  texture { tc1 }
  translate z*-1.5
 }
#end

#macro mediasphere()
 sphere { 0, (dist+1)
  pigment { rgbt 1 }
  hollow
  interior {
   media {
    scattering { 1,1/dist }
    intervals 1
    samples 20,20
    method 3
    variance 1/64
    confidence 1-1/10
   }
  }
 }
#end

#macro lights(pos,bright)
 #local ang= degrees(atan2(2.5,(dist*2)));

 light_source {
  y*dist*2+pos
  rgb 1*bright
  spotlight
  point_at pos
  radius ang*0.9
  falloff ang
  tightness 1
 }
#end

lights(z*-0.75,5)
mediasphere()
iso1()
iso2()
iso3()

Post a reply to this message