Nathan Kopp <Nat### [at] koppcom> wrote:
: radiosity uses perturbed surface normal (bumps, wrinkles, etc)

  Why is it so slow with them? My test scene (included below) takes
1 minute and 10 seconds to render without the normal map. Adding the normal
map takes more than 10 minutes to render.
  If this can't helped, then I think that it should be an option in the
radiosity-block (turned off by default).

  And another thing: It doesn't seem to work very well. Just try it:

//--------------------------------------------------------------------------
global_settings
{
  #if(version=3.1)
    ambient_light 4
    radiosity
    { count 300
      nearest_count 5
      error_bound .2
      recursion_limit 2
      low_error_factor .5
      gray_threshold 0
      minimum_reuse .015
      brightness 8
      distance_maximum .1
    }
  #else
    ambient_light 0
    ini_option "Preview_Start_Size=8"
    ini_option "Preview_End_Size=4"
    radiosity
    { count 120
      nearest_count 5
      error_bound 1
      recursion_limit 4
      low_error_factor .5
      gray_threshold 0.0
      minimum_reuse 0.015
      brightness 2.8
      max_sample 2
      adc_bailout 0.01/2
    }
  #end
}

camera { location <-1.99,0,-1.99> look_at z*2 angle 40 }
light_source
{ <-1.99,.99,-1.99>, 1
  spotlight point_at <0,-1,2> radius 15 falloff 15
}

difference
{ box { <-2,-1,-2><2,1,2> inverse }
  box
  { <-.1,-.9999,-.1><.1,.9999,.1>
    rotate y*45 scale <1,1,.5> translate <-.5,0,2>
  }
  pigment { rgb 1 }
  normal
  { gradient x 1 slope_map { [0 <0,1>][.1 <1,1>][.1 <1,0>][1 <1,0>] }
    scale 1.8
  }
}
box { <-1.999,-1,-2><-2,1,2> pigment { rgb x } }
box { <1.999,-1,-2><2,1,2> pigment { rgb z } }

superellipsoid
{ <1,.3> rotate x*90 scale <.25,.1,.25> translate <1, .9, 1.5>
  pigment { rgb 1 }
}
superellipsoid
{ <1,.3> scale <.25,.25,.2> translate <1, 0, 1.8>
  pigment { rgb 1 }
}
superellipsoid
{ <1,.3> scale <.25,.25,.2> translate <-1.2, 0, 1.8>
  pigment { rgb 1 }
}
//--------------------------------------------------------------------------

-- 
main(i,_){for(_?--i,main(i+2,"FhhQHFIJD|FQTITFN]zRFHhhTBFHhhTBFysdB"[i]
):5;i&&_>1;printf("%s",_-70?_&1?"[]":" ":(_=0,"\n")),_/=2);} /*- Warp -*/

Post a reply to this message