Lutz Kretzschmar wrote:
> 
> Hi Glenn Bech, you recently wrote in moray.win:
> 
> > Help! Me too ! I tried to follow a Povray media example, in Moray, by trying
> > to make a material (In the moray material editor) that was identical to
> > the povray example. That was not easy !!! (I couldn't make it!)
> Why couldn't you make it? Moray should be able to create any normal
> POV texture. If you post the POV code here I can try to reproduce it.
> 
> - Lutz
>   email : lut### [at] stmuccom
>   Web   : http://www.stmuc.com/moray

Chew on this :)


#declare Candle =
union{
  cylinder {
    <0, 0, 0>,
    <0, 1, 0>,
    1
    texture{
      pigment{rgbt 1}
    }
    interior{
      media{
        emission 1
        scattering{1,.01}
        intervals 20
        samples 1, 1
        confidence 0.999
        variance 1/100
        density {
          spherical
          cubic_wave
          turbulence 0.4
          lambda 1
          scale <0.8, 1, 0.8>
          color_map{
            [ 0 rgb 0]
            [ 1 rgb <5.0,3.0,0.0>]
          }
        }
        density {
          gradient y
          translate y
          cubic_wave
          color_map{
            [ 0 rgb 0]
            [ 1 rgb 1]
          }
        }
        density {
          gradient y
          poly_wave 0.5
          color_map{
            [ 0 rgb 0]
            [ 1 rgb 1]
          }
        }
      }
    } 
    hollow
    scale <1, 5, 1>
    translate y*1.25
  }

  intersection{
    cone{y*-8,.75,y*1,.5 pigment{rgb<1,1,.97>}finish{ambient .5 diffuse .23}}
    sphere{<.05,1,0>,.5 inverse pigment{rgb 1}finish{ambient .5 diffuse .23}}
  }

  cylinder{y*.8,y*1.5,.1 pigment{rgb 0}}
}

object{
  Candle
}

camera{
  location <0,1,-6>
  look_at 2.5 * y
}

light_source{
  <75,45,-500>
  color rgb 1
}


-- 
Ken Tyler

See my 1000+ Povray and 3D Rendering and Raytracing Links at:
http://home.pacbell.net/tylereng/index.html

Post a reply to this message