Sure, the code is below

The idea wasn't my own, it was based on things from the movie The Matrix.  Go
see it btw, it's very good.

-- Begin Matrix.pov --
#include "colors.inc"

#macro randText(num)
union {       
        #local c = 0;
        #while (c<num)
                #if(rand(rseed)>0.35)
                        #if(rand(rseed)>0.5) 
                                #local char = chr(rand(rseed)*26+asc("A"))
                        #else
                                #local char = chr(rand(rseed)*26+asc("a")) 
                        #end
                        text {
                                ttf "ariblk.ttf" char 0.001,0
                                translate y*(num/2-c-1)
                        }
                #end
                #local c = c+1;
        #end
}
#end


#declare rseed = seed(3388454);

#declare c = 150;
#while (c>0)     
        #debug str(c,0,0)
        #debug "\n"
        object {
                randText(50)
                translate
<(rand(rseed)*80)-40,rand(rseed)*30-15,(rand(rseed)*80)-40>
                #declare col = rand(rseed)*0.5;
                pigment {color rgb <col,0.5,col>}
                finish {ambient 1 diffuse 0}
        }        
        #declare c = c -1;
#end

camera {
        location z*-30
        look_at z*20
        focal_point z*-10
        aperture 1
        blur_samples 20
        confidence 0.999
}
-- End Matrix.pov

Ian Burgmyer wrote:
> Whoa, nifty!  This is sure unique.
> 
> Is this ray-traced?  If it is, could I see the code?  I'm interested in how
> you accomplished this.
> 
> -One confused Ian

-- 
Sam
    mailto:smi### [at] paradisenetnz
    http://www.geocities.com/SiliconValley/Horizon/4152/

"We live and we learn. But, sadly, at different rates."
  -- Alan Magid

Post a reply to this message