If you're going to be out in the desert, you want something to give you
more traction on the dunes (and any hostiles you may encounter). :)

camera {location <0, 4, -10> look_at <0, 2, 2>}

light_source {<10, 15, -30> color White}

background {color White}

#declare evil_tire =

difference {

union {
superellipsoid {<1, .3>
rotate 90*x
scale <2, 1, 2>
pigment {color rgb <.1, .1, .1>}
finish {phong .5 phong_size 30 ambient 0 diffuse .8}
normal {gradient y scallop_wave bump_size 1 scale .3}
}



#declare tread = union {

#declare this = 0
#while (this < 360)

cone {<1, 0, 0>, .2, <3, 0, 0>, 0
rotate <0, this, 0>
}

#declare this = this + 22.5
#end
}

#declare that = 0
#while (that < 1.5)
object {tread
rotate that*15*y
translate (-.7+that)*y
pigment {color rgb <.5, .5, .5>}
finish {ambient 0 phong 1 phong_size 20}
}
#declare that = that + .2
#end


}
cylinder {<0, -3, 0>, <0, 3, 0>, 1.5}

pigment {color White}
finish {phong 1 phong_size 20 diffuse .6 ambient .1}
}

object {evil_tire}

object {evil_tire rotate <90, -30, 0> translate <-6, 3, 5>}

object {evil_tire rotate <90, 40, 0> translate <5, 4, 3>}

object {evil_tire rotate <90, 60, 0> translate <-2, 2, 6>}

Post a reply to this message

Attachments:
Download 'tire.jpg' (28 KB)

Preview of image 'tire.jpg'