|
![](/i/fill.gif) |
HI Joseph,
What I would do is use a CSG difference to chop out each of the flutes from your
column. Use an #while...#end loop to control the number of flutes, something like
this:
#declare Flute_Radius=0.25;
#declare Column_Radius=2;
#declare Number_Of_Flutes=20;
#declare Flute=
union {
cylinder { <0,-10,0>,<0,10,0>,Flute_Radius}
sphere { <0,-10,0>,Flute_Radius}
sphere { <0,10,0>,Flute_Radius}
}
#declare Column=
difference {
cylinder { <0,-10.5,0>,<0,10.5,0>,Column_Radius } // Un-fluted column
// Set up a loop
#declare Count=0;
#while ( Count<=Number_Of_Flutes)
object { Flute
translate x*Column_Radius
rotate y*(Count*(360/Number_Of_Flutes))
}
#declare Count=Count+1;
#end
}
object { Column
scale .5
rotate x*45
texture { pigment {Red} finish {Shiny}}
}
I hope this helps you. Incidentally, the last time I posted any code, half of it went
missing, so I've attatched the code as well.
Andy.
Joseph Prever wrote in message <368E27DB.28B7CE6B@turbont.net>...
>What is the technique in POV 3.x for making fluted columns (or fluted
>anything)? Or do I need a help app?
>Any response will be greatly appreciated. Thank you for your time.
>
>-Joe Prever
>
Post a reply to this message
Attachments:
Download 'Column.pov.txt' (2 KB)
|
![](/i/fill.gif) |