POV-Ray : Newsgroups : povray.advanced-users : Fake shadows in 32-bit images? : Re: Fake shadows in 32-bit images? Server Time
28 Mar 2024 19:56:08 EDT (-0400)
  Re: Fake shadows in 32-bit images?  
From: Norbert Kern
Date: 6 May 2021 18:55:00
Message: <web.6094444e7599ad52fd796d7fb7ae6630@news.povray.org>
Alain Martel <kua### [at] videotronca> wrote:

>
> Another thing : As that scene use radiosity, you need to replace any
>
>
> reasonable value. Something in the 0.65..0.8 range.


Hi,

When using radiosity it's useful to include a big sphere and a ground plane,
each with no_image.
I also added some zeros to the y scale of the "shadow" to remove an artifact at
Bald Eagle's nice solution.


Norbert


// +fn +ua

#version 3.7;

#declare RAD = 4;

global_settings {
        assumed_gamma 1
        max_trace_level 5
        noise_generator 2
        #if (RAD > 0)
                radiosity {
                        pretrace_start 0.08
                        pretrace_end 0.04/RAD
                        count 30*RAD
                        nearest_count min (20, RAD)
                        error_bound 2/RAD
                        low_error_factor 0.5
                        recursion_limit 1
                        gray_threshold 0
                        minimum_reuse 0.015
                        brightness 1
                        adc_bailout 0.005
                        normal on
                        media on
                }
        #end
}

camera {
        location <0,5,-9>
        look_at <0,0.65,0>
        right x*image_width/image_height
        angle 10
}

#declare LS = <5,15,-10>;

light_source {LS color rgb <1,0.96,0.9>}

#declare LS2 = -vnormalize (LS);

#declare ShadowTrans =
transform {
        matrix <
                1, 0, 0,
                LS2.x, LS2.y, LS2.z
                0, 0, 1,
                0, 0, 0
        >
}

#declare Object =
union {
        cylinder {0, y, 0.05}
        sphere {y, 0.25}
}

object {Object pigment {rgb 1} no_shadow}

object {
        Object
        transform {ShadowTrans}
        scale <1,0.00001,1>
        pigment {rgbt <0,0,0,0.5>}
}

plane {y, 0 pigment {color rgb 1} no_image}

sphere {
        0, 1000
        pigment {color rgb <0.3,0.4,0.7>}
        no_image
}


Post a reply to this message

Copyright 2003-2023 Persistence of Vision Raytracer Pty. Ltd.