|
 |
Jim Holsenback nous illumina en ce 2008-07-18 10:28 -->
> "Reactor" <rea### [at] hotmail com> wrote in message
> news:web.487f9f80f15fb2b6210497120@news.povray.org...
>> Povray can do this, but I would like to see your code so we can figure out
>> why
>> it isn't.
>>
>> -Reactor
>
> Ok ..... here's the source file photons commented out. Don't need that just
> yet right?
No! You absolutely NEED to turn photons on now. Without photons on, there is no
reflection of the beam.
>
> I've attached a reference image. Notice I can see the target in the
Please don't post image here, it's not a binaries group.
Instead, include a reference to a similarly named post on povray.binaries.images
> reflective object .... also the reflection of the beam from the source.
> That's not the beam bending but it's reflection. I also commented out the
> optical device as I don't need that yet either. One change I made was the
You effectifely don't need any visible object emiting your light.
> intensity of the looks_like light source ..... it WAS a color vector * 1000
> ..... I just bumped up the intensity of the scattering media to make up for
> lowering the intensity of the emitter light source. Orginally the light beam
> hitting the target produced an almost white-ish look (highly saturated)
> ..... a laser beam should leave a red (or light source) colored point of
> light .... correct?
A laser can be any colour, from far infrared to hard UV. IR and UV are
invisible. A UV laser can cause the air to turn fluoressent and emit light, and
that light can have several colours, and apears white if the beam is strong enough.
Visible laser are 100% saturated, monochromatic lights. So, just make sure that
at least one component is set to zero.
>
> Thanks
> Jim
> ---
>
> global_settings {
> max_trace_level 10
> /*photons {
> count 100000
> autostop 0
> media 1000
> max_trace_level 10
> }*/
> }
Uncomment that photons block. Otherwise, the beam will never get reflected.
>
> background {rgb 0.125}
>
> #declare Camera = <15,1.5,2.5>;
>
> camera { location Camera look_at <0,0,2.5>}
>
> // makes the lightsource visable
> box {<100,100,100>,<-100,0,-100>
> hollow on
> pigment {rgbt 1}
> //photons {pass_through}
> interior {
> media {
> intervals 1
> samples 1 //5,25
Need more samples. Use 100 or possibly more.
> confidence 1 - 1/1000
> variance 1/1000
> ratio 0.9
> scattering {
> 1, color rgb 10
> extinction 0.0
> }
> method 3
> aa_threshold 0.1
> aa_level 4
You don't need that much, aa_level 2 or 3 should be enough.
> density {color rgb <1,1,1>}
> }
> }
> }
>
> // reflector yellow border
> union {
> box {<-2.5,-0.1,-2.5>, <2.5,0.1,2.5>
> pigment{rgb 1}
> finish{ ambient 0 diffuse 0 reflection 1}
> }
> box {<-2.6,0,-2.6>, <2.6,0,2.6>
> pigment{rgb <1,1,0>}
> finish{ ambient 0.5}
> }
> rotate z*90
> rotate y*315
> //photons {target reflection on refraction on}
> }
Uncomment this. This is required for the photons to work.
>
> // recptor blue border
> union {
> box {<-0.1,-1.5,2.5>, <0.1,1.5,-2.5>
> pigment {
> onion scale 0.5
> color_map {
> [0.0 rgb 1]
> [0.35 rgb 1]
> [0.35 rgb 0.1]
> [1.0 rgb 0.1]
> }
> }
> finish{ ambient 0.5 diffuse 0.5 reflection 0 }
> }
> box {<0,-1.6,2.6>, <0,1.6,-2.6> pigment {rgb <0,0,4>}}
> rotate y*90
> //photons {target reflection on refraction on}
Not needed.
> translate <0,0,5>
> }
>
> // optic device
> /*sphere {
> 0, 0.5
> pigment{ color rgbt <1,1,1,.95> }
> hollow on
> finish{ ambient 0 diffuse 0 reflection .5 }
> interior{ ior 1.5 }
> //photons {target reflection on refraction on}
> scale <0.01,1,1>
> translate <2.5,0,0>
> }*/
>
> // the emitter
> light_source {
> <0,0,0>
> color rgb <1.0000, 0.2900,0.2000>
Make it: color rgb<10,0,0> if you want a red laser.
For a laser, at least one colour component MUST be zero.
> cylinder
For a laser, you should also add parallel.
> tightness 0
> radius .025
> falloff .025
> point_at <-1,0,0>
> fade_distance 500
You don't need light fading in this case as the fading of laser is negligeable
at human scale.
> fade_power 2
> /*photons {
> reflection on
> refraction off
> }*/
Optional. Thise are on by default for any light_source.
> looks_like {cylinder{0,<0.1,0,0>,0.1 pigment {rgb <4,0,0>}}}
> translate <5,0,0>
> }
>
>
>
--
Alain
-------------------------------------------------
You know you've been raytracing too long when you look at a matrix transform and
know instantly what it does.
John VanSickle
Post a reply to this message
|
|
|
|
here's one to check out
adapt Blue Herrin's code like,
#declare reflector =
box {
<-0.5, -4, -4>, <0, 4, 4>
hollow
pigment { rgbft <0,1,0,.1,.9> } //White }
finish {
reflection { 1 }
}
photons {
target
reflection on
refraction on
}
rotate z * 45
translate x * -9
}
object { reflector }
in place of current reflector, I dont know why I am see what I am seeing.
3 beams reflected and transmitted? well I really cant see it yet, very slow.
render center region with drag, low low res
next logical step experiment with prism shape , perhaps other shapes
Post a reply to this message
|
|
|
|
alphaQuad nous illumina en ce 2008-07-18 16:54 -->
> here's one to check out
>
> adapt Blue Herrin's code like,
>
> #declare reflector =
> box {
> <-0.5, -4, -4>, <0, 4, 4>
> hollow
> pigment { rgbft <0,1,0,.1,.9> } //White }
> finish {
> reflection { 1 }
> }
> photons {
> target
> reflection on
> refraction on
> }
> rotate z * 45
> translate x * -9
> }
> object { reflector }
>
>
> in place of current reflector, I dont know why I am see what I am seeing.
> 3 beams reflected and transmitted? well I really cant see it yet, very slow.
>
> render center region with drag, low low res
>
> next logical step experiment with prism shape , perhaps other shapes
>
>
>
>
In that situation, it's obvious that you should see multiple beams.
A beam that reflect off the front surface.
A first transmited beam that goes out of the back.
Another that goes into the box, reflect off the back and emerge a little farther.
When it reatch the front face, part of the beam get reflected back into the box.
This gives you the second beam exiting from the back after 2 reflections.
Yet another that reflect trice inside the box.
A forth that have reflected 5 times.
Then a fift after 7 reflections...
Each successive beam become dimer, and, in your case, the forth one is to faint
to be seen.
If you add "conserve_energy" you'll notice that the extra beans goes away.
--
Alain
-------------------------------------------------
Tricks and treachery are the practice of fools, that don't have brains enough to
be honest.
Benjamin Franklin
Post a reply to this message
|
|
