I have this landscape I'm working on. I'm trying to use media to generate a
blue sky. Basically, it is a scattering media of type 4, and the color it
scatters is <.2,.2,.0001>*.0005. This gets me the blue sky I want. However,
all the objects in the scene turn blue. I have some white snow that
especially turns blue, almost the same blue as the sky. I have tried
setting ambient to 1 with radiosity turned on, but it still comes up blue.

2nd Problem: I've been trying really hard to come up with a good texture to
coat the mountains so that it looks like they have snow on top, but not
down below. This is what I have so far for that:

#declare pigment1 =
pigment
{
  slope
  {
    y, .5, 1
  }
  color_map
  {
    [0 color rgbf <0,0,0,1>]
    [.25 color rgbf <1,1,1,.9>]
    [1 color rgbf <1,1,1,0>]
  }
}

#declare pigment2 =
pigment
{
  slope
  {
    y, .5, 1
  }
  color_map
  {
    [0 color rgbf <0,0,0,1>]
    [.6 color rgbf <1,1,1,0>]
    [1 color rgbf <1,1,1,0>]
  }
}

#declare pigment3 =
pigment
{
  slope
  {
    <0,2,3>
  }
  turbulence .5
  color_map
  {
    [0 color rgbf <1,1,1,0>]
    [.4 color rgbf <1,1,1,1>]
    [.6 color rgbf <1,1,1,.6>]
    [1 color rgbf <1,1,1,1>]
  }
}

#declare rock =
  isosurface
  {
    function
    {
      (y-fnpigment2(x,y,z).gray*100)-(fnpigment1(x,y,z).gray +
fnpigment3(x,y,z).gray*10 + fnpigment4(x,y,z).gray*10 +
fnpigment5(x,y,z).gray*.05)
    }
    contained_by
    {
      box
      {
        <-5000,0,-5000>,<5000,500,5000>
      }
    }
    max_gradient 4
    texture
    {
      T_Stone44
    }
    texture
    {
      pigment
      {
        gradient y
        turbulence <0,.1,0>
        pigment_map
        {
          [0 color rgbf <1,1,1,1>]
          [.3 pigment1]
          [.79 pigment2]
          [.8 color rgbf <1,1,1,0>]
          [1 color rgbf <1,1,1,0>]
        }
        scale y*1000
      }
      finish
      {
        ambient .6
      }
    }
    texture
    {
      pigment
      {
        gradient y
        turbulence <0,.1,0>
        pigment_map
        {
          [0 color rgbf <1,1,1,1>]
          [.3 pigment3]
          [1 pigment3]
        }
        scale y*1000
      }
      finish
      {
        ambient .6
      }
    }
    scale <1,4,1>
  }

The first two declared pigments are supposed to contribute to the appearance
of snow that has accumulated on the flat parts, while it tends to fall away
from cliff-sides exposing rock. The 3rd declared pigment is supposed to add
more snow on the sides of the slopes facing directly away from the main
light_source. All of these have transparent parts because they lie on top
of the texture for the stone. This is the first texture in the actual
isosurface object. The second texture is a pigment map that is supposed to
properly combine all the declared pigments. The last one is there to make
sure that all the areas that are over a certain height are completely snow
covered.

The problem is that I have not been able to find any peaks that are
completely snow-covered. Just small scattered patches. I'm a little bit
unsure how to make sure that the top end of my gradient is at the top of
the peaks.

Post a reply to this message

In article <web.3fa31f44e63905fc30a67eb20@news.povray.org>,
 "Justin Smith" <t74### [at] yahoocom> wrote:

> I have this landscape I'm working on. I'm trying to use media to generate a
> blue sky. Basically, it is a scattering media of type 4, and the color it
> scatters is <.2,.2,.0001>*.0005. This gets me the blue sky I want. However,
> all the objects in the scene turn blue. I have some white snow that
> especially turns blue, almost the same blue as the sky. I have tried
> setting ambient to 1 with radiosity turned on, but it still comes up blue.

You don't show the code for the media you're using. Anyway, the solution 
is simple: make the media less dense, and make the sky container bigger 
to compensate.

-- 
Christopher James Huff <cja### [at] earthlinknet>
http://home.earthlink.net/~cjameshuff/
POV-Ray TAG: chr### [at] tagpovrayorg
http://tag.povray.org/

Post a reply to this message

Christopher James Huff wrote:
>In article <web.3fa31f44e63905fc30a67eb20[at]news.povray.org>,
> "Justin Smith" <t74### [at] yahoocom> wrote:
>
>> I have this landscape I'm working on. I'm trying to use media to generate a
>> blue sky. Basically, it is a scattering media of type 4, and the color it
>> scatters is <.2,.2,.0001>*.0005. This gets me the blue sky I want. However,
>> all the objects in the scene turn blue. I have some white snow that
>> especially turns blue, almost the same blue as the sky. I have tried
>> setting ambient to 1 with radiosity turned on, but it still comes up blue.
>
>You don't show the code for the media you're using. Anyway, the solution
>is simple: make the media less dense, and make the sky container bigger
>to compensate.

Thanks. Actually, I decided for now to go with just enclosing the scene in a
giant blue sphere, but I still want to use media for general air thickness
so that distant objects look faded. Here is my current media block:

box
{
  <-5000,0,-5000>,<5000,800,5000>
  texture
  {
    pigment
    {
      color rgbt <1,1,1,1>
    }
  }
  interior
  {
    media
    {
      method 3
      samples 4
      intervals 1
      scattering
      {
        4,
        color rgb <1,1,1>*.00075
        extinction 1
      }
    }
  }
  hollow
}

The air thickness looks about right, but I've noticed that objects casting
shadows don't seem to be casting shadows through the air itself as I've
seen in other scenes with media. Is there anything special I have to turn
on that I've forgotten? There is a keyword "media_attenuation" that goes in
the light_source but I'm not really sure if that is it, and since it
currently takes about 6 hours to render this image with media, I think it
would be quicker to ask here.

Post a reply to this message

"Justin Smith" <t74### [at] yahoocom> wrote in message
news:web.3fa45ec67933238264ba676d0@news.povray.org...
>
> The air thickness looks about right, but I've noticed that objects casting
> shadows don't seem to be casting shadows through the air itself as I've
> seen in other scenes with media. Is there anything special I have to turn
> on that I've forgotten? There is a keyword "media_attenuation" that goes
in
> the light_source but I'm not really sure if that is it, and since it
> currently takes about 6 hours to render this image with media, I think it
> would be quicker to ask here.


Should not need media_attenuation on, since that is for fading the light as
it passes through the media. You'd likely get even less shadowing that way.
The scattering extinction 1 could be the culprit, so try it at 0 or near
zero and see if that helps or hinders what you had in mind for the overall
effect. Oh yeah, and use partial render output instead of the entire image
and you can see certain parts much quicker than that 6 hours. If you use the
Windows (or Mac) POV then click/drag the cursor at the spot needed to test.
Start with a small resolution to get the window to appear first then change
the output resolution before doing the selection area. Pardon me if you knew
about it already but sounded like you hadn't.

You have mentioned that you didn't like the bluish snow from radiosity being
used. Try setting its grey_threshold near to 1 (default is 0). That should
help prevent the color-bleed.

I saw your questions a couple days ago but I needed to check out what you
wanted to do about getting the snow to be more in the shadows than sunlit
sides of the terrain. I had done this kind of thing long ago but I had
practically forgotten how to use the slope pigment pattern. Maybe I've
relearned it again because I think I achieved the right effect after some
trial and error. Scaling was really throwing me off, I reduced your bounding
box vertically a lot, and changed a few aspects of the textures too.

I might have been better off searching for a previous scene file rather than
rewriting it.  :-)

Anyway, I'll post it over at povray.text.scene.files so you can have a look
at the changes. I'll call it "mountians with snow preferential to shadows"
so you'll know what to look for.

Bob H.

Post a reply to this message

In article <web.3fa45ec67933238264ba676d0@news.povray.org>,
 "Justin Smith" <t74### [at] yahoocom> wrote:

> The air thickness looks about right, but I've noticed that objects casting
> shadows don't seem to be casting shadows through the air itself as I've
> seen in other scenes with media. Is there anything special I have to turn
> on that I've forgotten? There is a keyword "media_attenuation" that goes in
> the light_source but I'm not really sure if that is it, and since it
> currently takes about 6 hours to render this image with media, I think it
> would be quicker to ask here.

media_attenuation will have little effect with such a low-density media 
except to slow it down. That feature controls the attenuation of light 
passing through the media, which will probably be unnoticeable. The most 
likely problem is that you don't have enough samples, there aren't 
enough to pick up the shadows. Or they may just not be very visible with 
the settings and angles you have.

-- 
Christopher James Huff <cja### [at] earthlinknet>
http://home.earthlink.net/~cjameshuff/
POV-Ray TAG: chr### [at] tagpovrayorg
http://tag.povray.org/

Post a reply to this message

Thank you Bob H. for the work you did to help me out. I'm not sure if I'm
going to go with that, but I did learn a bit from it. I'm still
experimenting around.

-Justin Smith

Post a reply to this message