Hello,

I'm trying to use a model for a monitor but there's something funny about
it.
When I try to rotate it as in:

object { SYNCMASTER17  rotate -90*y }

it fails.  I think it says there's a brace missing.  I notice it's an older
model.  I
tried deleting the version specific reference and putting the ambient inside
a finish statement, but no luck.  I think there's something in there that
needs
to be tweaked so that I can rotate it.  Any help  would be appreciated.  The
code is below.

Thanks, Michael

#declare monitor = version;
#version 1.0

#declare computerwhite_plastic = texture {
  pigment {color rgb <0.9647,0.9098,0.7529>}
  normal { bumps 0.5 scale 0.1 }
  finish { phong 0.1 }
}

#declare SYNCMASTER17 =
union {
  union {
    cylinder{<0, 0,0>,<0,15,0>,125}
    box{<0,0,-125>,<150,15,125>}
    cylinder{<0,15,0>,<0,30,0>,105}
    cylinder{<0,30,0>,<0,45,0>, 85}
    sphere{<0,100,0>,90}
    box{<-120, 60,-150>,<-80,100,150>}
    box{<-135, 70,-150>,<-80,100,150>}
    box{<-150,100,-210>,<-50,430,-170>}
    box{<-150,100, 210>,<-50,430, 170>}
    box{<-150, 95,-205>,<-50,140, 205>}
    box{<-150,435,-205>,<-50,395, 205>}
    cylinder{<-150,100,-205>,<-50,100,-205> 5}
    cylinder{<-150,100, 205>,<-50,100, 205> 5}
    cylinder{<-150,430,-205>,<-50,430,-205> 5}
    cylinder{<-150,430, 205>,<-50,430, 205> 5}
    difference {
      cylinder{<-300,95,0>,<-300,420,0>,320}
      plane{<1,0,0>,-45}
    }
    difference{
      box{<-80,60,-165>,<240,390,165>}
      plane{<0,-1,0>,0 rotate <0,0,-10> translate<0,385,0>}
      plane{<0, 1,0>,0 rotate <0,0, 10> translate<0, 60,0>}
      box{<-80,55,-170>,<250,170,-145>}
      box{<-80,55, 170>,<250,170, 145>}
      box{<250,55,-170>,<220,170, 170>}
    }
    texture{computerwhite_plastic}
  }
  box {<-140,140,-170>,<-130,395,170>}
  texture {
    pigment {
      image_map {tga "SCREEN.TGA"}
      rotate <0,90,0>
      scale <1,255,340>
      translate <0,140,-170>
    }
    ambient 0.3
  }
}

Post a reply to this message

"Michael Robison" <zsp### [at] gtenet> wrote in message
news:404d2c31@news.povray.org...
>
> object { SYNCMASTER17  rotate -90*y }

It seems okay when #version 1.0 isn't set and the ambient 0.3 also put
inside a finish block. I don't recall much about the syntax requirements for
POV 1.0 but it acts like it doesn't accept transformations in a object
block.

Hmmm, as I render it and look at the monitor to see it I'd suggest lowering
the normal to around 0.1, otherwise it's a bit grainy at 0.5.

Bob H.

Post a reply to this message

Wasn't it Michael Robison who wrote:
>Hello,
>
>I'm trying to use a model for a monitor but there's something funny about
>it.
>When I try to rotate it as in:
>
>object { SYNCMASTER17  rotate -90*y }
>
>it fails.  I think it says there's a brace missing.  I notice it's an older
>model.  I
>tried deleting the version specific reference and putting the ambient inside
>a finish statement, but no luck.  I think there's something in there that
>needs
>to be tweaked so that I can rotate it.  Any help  would be appreciated.  The
>code is below.

"#version 1.0" doesn't support the "rotate -90*y" syntax so you can do
any of three things:-

1. Do it all in version 3.5, by changing the "ambient 0.3" to 
   "finish { ambient 0.3 }".

2. Do it all in version 1.0, by changing the "rotate -90*y" to 
   "rotate <0,-90,0>".

3. Do it in a mixture of versions by switching back to "#version 3.5" 
   (or "#version monitor" to revert to the default value that you saved) 
   before the "object { SYNCMASTER17  rotate -90*y }" line.

-- 
Mike Williams
Gentleman of Leisure

Post a reply to this message

Thanks, Bob and Mike, for the help on the monitor!  I appreciate
it!  I probably need to get a different screen for it.  Been a long,
long time since I used OS2.

Thanks again, Michael

Post a reply to this message