The subject line says it all. Which is the best way to model the sun? 
Ideally, I would like to be able to model the sun in the IR, visible, UV 
and X-ray. Eventually, I would like to morph between these wavelengths 
in an animation. Here is an example photo:

http://antwrp.gsfc.nasa.gov/apod/ap010419.html

I also noticed this orrery:

http://news.povray.org/povray.binaries.images/33847/

I checked the archives. Someone had previously asked for the source code 
for the sun in the orrery but I couldn't find any follow up and do not 
believe one was posted. (Unless I missed it.)

Any advice on the best approach? (For example, how would I do magnetic 
field lines using media?)

Thanks in advance for all suggestions and warnings of what doesn't work 
well.

Apollo16

Post a reply to this message

"Apollo16" <kki### [at] earthlinknet> wrote in message
news:3FD### [at] earthlinknet...
> The subject line says it all. Which is the best way to model the sun?
> Ideally, I would like to be able to model the sun in the IR, visible, UV
> and X-ray. Eventually, I would like to morph between these wavelengths
> in an animation. Here is an example photo:
>
> http://antwrp.gsfc.nasa.gov/apod/ap010419.html
>

All pov images output UV and X-rays - this is why you have to confirm "I am not
a pregnant woman" before installing...

Seriously though, pov cannot model a 'sun' - i.e. you can't construct an object
using atomic physics - all you can do is create something that looks like a sun.

So, ignoring the stuff about animating the scene, and also the stuff about
magnetic field lines for a later date....

Sun surface - well you could use media, but essentially the visible surface can
be rendered as a texture
Sun corona - for this you will want to use media.

Try playing around with something like this:

#version 3.5;

#include "colors.inc"

global_settings {
  assumed_gamma 1.0
}

camera {
  location  <0.0, 0.0, -3.0>
  look_at   <0.0, 0.0,  0.0>
}

#declare SPig1_1 =
pigment{
  granite scale 1/8
  pigment_map{
    [0.0 rgb<164/255,20/255,0/255>]
    [0.3 rgb<150/255,10/255,0/255>]
    [0.8 rgb<150/255,10/255,0/255>]
    [1.0 rgb<164/255,20/255,0/255>]
  }
}

#declare SPig1_2 =
pigment{
  granite scale 1/8
  pigment_map{
    [0.0 rgb<194/255,50/255,0/255>]
    [0.4 rgb<241/255,86/255,4/255>]
    [0.7 rgb<255/255,155/255,37/255>]
    [1.0 rgb<194/255,50/255,0/255>]
  }
}

#declare SPig1_3 =
pigment{
  granite scale 1/8
  pigment_map{
    [0.0 rgb<241/255,86/255,4/255>]
    [0.5 rgb<255/255,155/255,37/255>]
    [1.0 rgb<241/255,86/255,4/255>]
  }
}

#declare SPig1 =
pigment{
  granite scale 1
  pigment_map{
    [0.2 SPig1_1]
    [0.5 SPig1_2]
    [0.7 SPig1_3]
    [0.8 rgb<255/255,244/255,230/255>]
  }
}

#declare STex1 =
texture{
  pigment{
    SPig1
  }
  finish{ambient 1}
}

// sun surface object
sphere{
  0, 1
  texture{
    STex1
  }
}

#declare SInt1 =
interior{
  media{
    method 3
    emission rgb<1.00,0.1,0.0>*5
    density{spherical scale 1.25 turbulence 0.1}
    density{agate scale 0.25 color_map{[0.8 rgb 0][0.9 rgb 1]}}
  }
  media{
    method 3
    emission rgb<1.00,0.1,0.0>*1
    density{spherical scale 1.15 turbulence 0.0}
  }
}

// corona object
sphere{
  0,1.5
  hollow
  pigment{rgbf 1}
  interior{SInt1}
}

Post a reply to this message

Sorry... I should have used the word render... I am not really modeling 
the sun in the astrophysical sense of the word. (That was part of my 
thesis and I am finished with that my friend... I am finished with it!) 
What I am looking to do is "render" the sun so that I can use this as a 
demo in my undergraduate courses.

Thus... what you have started me off with is great! Just what I wanted. 
Your version needs a shave but... Now that you have given me a great 
start, I should be able to whip a good example together in no time! 
Thanks again!

Apollo16

P.S. When I render the sun, I'll be sure to wear a sunscreen with an spf 
of 5000!

Tom Melly wrote:

>"Apollo16" <kki### [at] earthlinknet> wrote in message
>news:3FD### [at] earthlinknet...
>  
>
>>The subject line says it all. Which is the best way to model the sun?
>>Ideally, I would like to be able to model the sun in the IR, visible, UV
>>and X-ray. Eventually, I would like to morph between these wavelengths
>>in an animation. Here is an example photo:
>>
>>http://antwrp.gsfc.nasa.gov/apod/ap010419.html
>>
>>    
>>
>
>All pov images output UV and X-rays - this is why you have to confirm "I am not
>a pregnant woman" before installing...
>
>Seriously though, pov cannot model a 'sun' - i.e. you can't construct an object
>using atomic physics - all you can do is create something that looks like a sun.
>
>So, ignoring the stuff about animating the scene, and also the stuff about
>magnetic field lines for a later date....
>
>Sun surface - well you could use media, but essentially the visible surface can
>be rendered as a texture
>Sun corona - for this you will want to use media.
>  
>

Post a reply to this message

"Apollo16" <kki### [at] earthlinknet> wrote in message
news:3FD### [at] earthlinknet...

> Thus... what you have started me off with is great! Just what I wanted.

No worries - repost a request when you're ready to animate it....

Post a reply to this message

I know this isn't specifically what he's asking, yet I thought I'd share my
little Sun1 Macro:

// a is angle across the sky.
#macro sun (a)

 light_source
 {
  <0, 0, 1000>
  color rgb <1, 1, 0.97>
  parallel

  area_light
  <40, 0, 0> <0, 0, 40>
  4, 4
  adaptive 0
  jitter
  circular
  orient

  looks_like
  {
   union
   {
    sphere
    {
     <0, 0, 0>, 1
     hollow

     pigment { color rgbft <1, 1, 1, 1, 0> }

     interior
     {
      media
      {
       emission 0.05

       density
       {
        spherical
        poly_wave

        density_map
        {
         [ 0  rgbt <0, 0, 0, 0> ]
         [ 30 rgbt <1, 1, 1, 0> ]
         [ 60  rgbt <1, 1, 1, 0> ]
        }
       }
      }
     }

     scale <200, 200, 200>
    }
   }
  }

  rotate -a*x
 }

#end

Post a reply to this message