Hola,
Tengo un problema al combinar radiosity con vidrios: Para hacer el render
hago 2 pasadas, en la primera calculo radiosity sin reflejos ni
transparencias y en la segunda leo la información de radiosity y aplico
reflejos y transparencias. En la primera pasada NUNCA salen manchas,
mientras que en la segunda pasada SIEMPRE sale alguna mancha (a veces salen
tantas que ni con el photoshop puedo arreglarlo). Y, curiosamente, las
manchas aparecen en los reflejos y, sobretodo, detrás de los vidrios.

Los parámetros que suelo usar son los siguientes:

global_settings {
  ambient_light 1.0
  assumed_gamma 2.2
  exposure 1.6
  max_trace_level 8

  #if (RAD)
    radiosity {
      brightness      1.0    //[1.0]
      recursion_limit 3      //[3]
      count           500    //[35]
      error_bound     0.1    //[1.8]
      gray_threshold  0.5    //[0.0]]

      #if(SAVERAD)
        save_file "escena.rad"
      #else
        pretrace_start 1
        pretrace_end 1
        load_file "escena.rad"
        always_sample off
      #end
  }
  #end
}

Alguna sugerencia??

Saludos,

Joel.

Post a reply to this message

JSR wrote:
> global_settings {
>   ambient_light 1.0
>   assumed_gamma 2.2
>   exposure 1.6
>   max_trace_level 8
> 
>   #if (RAD)
>     radiosity {
>       brightness      1.0    //[1.0]
>       recursion_limit 3      //[3]
>       count           500    //[35]
>       error_bound     0.1    //[1.8]
>       gray_threshold  0.5    //[0.0]]
> 
>       #if(SAVERAD)
>         save_file "escena.rad"
>       #else
>         pretrace_start 1
>         pretrace_end 1
>         load_file "escena.rad"
>         always_sample off
>       #end
>   }
>   #end
> }
> 
> Alguna sugerencia??


   Prueba a usar pretrace_start y pretrace_end (con valores mejores que los 
de por defecto) tambien en la primera pasada, creo que eso suavizaría los 
datos de radiosidad que se guardan. Tampoco veo nearest_count, con lo cual 
estas usando el valor por defecto de 5, que es algo bajo para tu error_bound.

   Saludos...

--
Jaime

Post a reply to this message

> Jaime Vives Piqueres <jaimevives [at] ignoranciaorg> wrote:
>    Prueba a usar pretrace_start y pretrace_end (con valores mejores que los
> de por defecto) tambien en la primera pasada, creo que eso suavizaría los
> datos de radiosidad que se guardan. Tampoco veo nearest_count, con lo cual
> estas usando el valor por defecto de 5, que es algo bajo para tu error_bound.

He probado con estos parámetros:
#if (RAD)
    radiosity {
      //Parámetros importantes
      brightness      1.0  //[1.0]
      recursion_limit 3    //[3]
      count           800  //[35]
      error_bound     0.2  //[1.8]
      gray_threshold  0.5  //[0.0]]
      pretrace_start  0.05 //[0.08]
      pretrace_end    0.01 //[0.04]
      nearest_count   15   //[5]

      #if(SAVERAD)
        save_file "escena.rad"
      #else
        pretrace_start 1
        pretrace_end 1
        load_file "escena.rad"
        always_sample off
      #end
  }
#end

Sigo teniendo el mismo problema, tal vez no aparecen tantas manchas ahora,
pero siguen apareciendo, y no son pequeñas precisamente. Lo curioso es que
solamente aparezcan detrás de las transparencias y en los reflejos. Puede
que el error se deba a que en la primera pasada en lugar de ocultar los
cristales lo que hago es desactivar el parámetro de transparencia, con lo
cual, no se está calculando suficiente información de radiosity detrás de
los cristales.
Voy a colgar un par de imágenes para ver un ejemplo.

Saludos,

Joel.

Post a reply to this message

JSR wrote:
> puede que el error se deba a que en la primera pasada en lugar de ocultar los
> cristales lo que hago es desactivar el parámetro de transparencia, con lo
> cual, no se está calculando suficiente información de radiosity detrás de
> los cristales.
> Voy a colgar un par de imágenes para ver un ejemplo.

   Ah... ahora lo veo claro: los cristales son opacos en la primera pasada! 
Yo normalmente quito el objeto en la primera pasada, o le asigno un simple 
pigment{rgbt 1}.

   Saludos,

--
Jaime

Post a reply to this message

>    Ah... ahora lo veo claro: los cristales son opacos en la primera pasada!
> Yo normalmente quito el objeto en la primera pasada, o le asigno un simple
> pigment{rgbt 1}.

Ya me parecía a mi que eso podía ser el problema... ok, veremos que ocurre
ahora.
Gracias,

Joel.

Post a reply to this message

He descubierto algo interesante. Después de hacer varias pruebas, de cambiar
el pretrace_start, pre_trace_end, nearest_count y después de usar solamente
pigment {rgbf 1} en la primera pasada para los cristales... y obtener el
mismo problema, me he dado cuenta de que poniendo diffuse 0.0 en los
cristales el problema se soluciona y además la segunda pasada de la
radiosity es más rápida.

Así, un material de vidrio le asigno las siguientes propiedades:
#declare mat_vidrio = texture {
  pigment { color rgbf <0.89, 0.94, 0.93, 0.8> }
  finish {
    ambient 0.0
    diffuse 0.0
    specular 0.0
    reflection { 0.1 }
  }
}

Y manteniendo los parámetros de radiosity tal y como los tenía al principio,
con una relación calidad/tiempo bastante aceptable (en mi opinión):

radiosity {
    brightness      1.0  //[1.0]
    recursion_limit 2    //[3]
    count           500  //[35]
    error_bound     0.1  //[1.8]
    gray_threshold  0.5  //[0.0]]

  #if(SAVERAD)
    save_file "escena.rad"
  #else
    pretrace_start 1
    pretrace_end 1
    load_file "escena.rad"
    always_sample off
  #end
}

Bueno, un problema menos :)

Joel.

Post a reply to this message