ok, I'm a definat noob, and I can not figure out how to do texture maps. I
looked at the tutorial, but that just confused me, is there any sites out
there or ayone who can give an easy to understand answer as to how they
work? I would greatly appriciate it. thanks

Post a reply to this message

"dragon9654" <dra### [at] yahoocom> wrote in message 
news:web.4438363b4d2ff27191f9b85f0@news.povray.org...
> ok, I'm a definat noob, and I can not figure out how to do texture maps.
> looked at the tutorial, but that just confused me, is there any sites out
> there or ayone who can give an easy to understand answer

texture_map is a way to specify whole textures as parts of another pattern. 
Hopefully the following example is self explanatory, if not don't give up 
yet. If you figure out how color_map in pigments work, well, it's the same 
kind of thing.

#declare Texture1=
texture {
 pigment {
  bozo
  color_map {
   [0 red 1]
   [1 green 1]
  }
 }
 normal {
  wrinkles 0.5
 }
 finish {
  specular 0.5
  roughness 0.005
 }
 scale 0.25
}

#declare Texture2=
texture {
 pigment{
  granite
  color_map {
   [0 blue 1]
   [1 green 1]
  }
 }
 normal {
  bumps 0.5
 }
 finish {
  specular 0.5
  roughness 0.005
 }
 scale 0.5
}

// new texture using those in texture map
#declare TextureMap=
texture {
    marble // turbulence 0.5
    texture_map {
        [0 Texture1]
        [1 Texture2]
    }
}

sphere {0,1 texture {TextureMap}}

camera {location -3*z}
light_source {<10,10,-10>,1}

Post a reply to this message

"Bob H" <omniverse@charter%net> wrote:
> "dragon9654" <dra### [at] yahoocom> wrote in message
> news:web.4438363b4d2ff27191f9b85f0@news.povray.org...
> > ok, I'm a definat noob, and I can not figure out how to do texture maps.
> > looked at the tutorial, but that just confused me, is there any sites out
> > there or ayone who can give an easy to understand answer
>
> texture_map is a way to specify whole textures as parts of another pattern.
> Hopefully the following example is self explanatory, if not don't give up
> yet. If you figure out how color_map in pigments work, well, it's the same
> kind of thing.
>
> #declare Texture1=
> texture {
>  pigment {
>   bozo
>   color_map {
>    [0 red 1]
>    [1 green 1]
>   }
>  }
>  normal {
>   wrinkles 0.5
>  }
>  finish {
>   specular 0.5
>   roughness 0.005
>  }
>  scale 0.25
> }
>
> #declare Texture2=
> texture {
>  pigment{
>   granite
>   color_map {
>    [0 blue 1]
>    [1 green 1]
>   }
>  }
>  normal {
>   bumps 0.5
>  }
>  finish {
>   specular 0.5
>   roughness 0.005
>  }
>  scale 0.5
> }
>
> // new texture using those in texture map
> #declare TextureMap=
> texture {
>     marble // turbulence 0.5
>     texture_map {
>         [0 Texture1]
>         [1 Texture2]
>     }
> }
>
> sphere {0,1 texture {TextureMap}}
>
> camera {location -3*z}
> light_source {<10,10,-10>,1}

Thanks a lot, I'll play around with that, it's starting to make
more sense now, thanks

Post a reply to this message