Dear NG,

I have a pov file that was made by an old version of PovRay (version 3.0)
that I got from the net. I wanted to render it in my PovRay 3.5 and this
pov code uses "halo" which has already been removed from the new povray. I
tried replacing things with media and interior stuffs, but I don't seem to
get the right scene (See
http://xlcus.com/povray/sunset/sunset-0640x0480.jpg)

I basically cannot translate this code into 3.5 ...

sphere {<0, 0, 0>, 2
  pigment {color rgbt<1, 1, 1, 1>}
  halo {
    emitting
    spherical_mapping
    linear
    color_map {
      [ 0.00 color rgbt<0.70, 0.45, 0.00, 1.0> ]
      [ 0.82 color rgbt<1.00, 0.70, 0.00,-0.5> ]
      [ 0.84 color rgbt<1.00, 1.00, 0.50,  -1> ]
      [ 1.00 color rgbt<1.00, 1.00, 1.00,  -1> ]
    }
    scale 0.5
    samples 10
  }
  hollow
  scale <3000, 3000, 2000>
  translate<0, 300, 3000>
}


This is supposed to be the sun and the atmosphere in the code. The entire
code is available in the website where I took it
http://xlcus.com/povray/sunset/sunset.pov

I liked the sunset here. Does anyone know of other nice sunset/sunrise
codes? (I prefer sunrise in most cases)

Thanks in advance.

Sincerely,
Jose Capco

Post a reply to this message

I got a more or less similar effect (not identical, but I suppose
acceptable) by converting it to an emitting media and tuning the
density colors until it looked similar:

sphere {<0, 0, 0>, 2
  pigment {color rgbt<1, 1, 1, 1>}
  interior
  { media
    { emission .0001
      density
      { spherical density_map
        {
          [ 0.00 color rgb<0.70, 0.45, 0.00>*.2 ]
          [ 0.82 color rgb<1.00, 0.70, 0.00> ]
          [ 0.84 color rgb<1.00, 1.00, 0.50> ]
          [ 1.00 color rgb<1.00, 1.00, 1.00>*30 ]
        }
      }
      scale 0.5
    }
  }
  hollow
  scale <3000, 3000, 2000>
  translate<0, 300, 3000>
}


-- 
#macro N(D)#if(D>99)cylinder{M()#local D=div(D,104);M().5,2pigment{rgb M()}}
N(D)#end#end#macro M()<mod(D,13)-6mod(div(D,13)8)-3,10>#end blob{
N(11117333955)N(4254934330)N(3900569407)N(7382340)N(3358)N(970)}//  - Warp -

Post a reply to this message

Warp <war### [at] tagpovrayorg> wrote:
> I got a more or less similar effect (not identical, but I suppose
> acceptable) by converting it to an emitting media and tuning the
> density colors until it looked similar:
>
> sphere {<0, 0, 0>, 2
>   pigment {color rgbt<1, 1, 1, 1>}
>   interior
>   { media
>     { emission .0001
>       density
>       { spherical density_map
>         {
>           [ 0.00 color rgb<0.70, 0.45, 0.00>*.2 ]
>           [ 0.82 color rgb<1.00, 0.70, 0.00> ]
>           [ 0.84 color rgb<1.00, 1.00, 0.50> ]
>           [ 1.00 color rgb<1.00, 1.00, 1.00>*30 ]
>         }
>       }
>       scale 0.5
>     }
>   }
>   hollow
>   scale <3000, 3000, 2000>
>   translate<0, 300, 3000>
> }
>

Oh, I wonder why one should tune the density map (I missed that part.. I
just put down the raw code with the same density map). Thanks, I'll try it
once I reach home. Is using density_map different from the color_map (I
think one can have color_map inside the density .. anyway I'll take a look
at pov documentation at home, I'm just not very used to working with media)

Sincerely,
Jose Capco

Post a reply to this message