POV-Ray 3.6 on Win98 machine 650M processor with 256M Ram.

With the union included in case(1), both frames render as expected. With 
the union commented out in case(1) (as shown here), the first frame 
renders as expected, but the second renders *very* slowly.

// -F +KFI1 +KFF2
#declare VL = array[04] {
     <-0.577350,-0.577350,00.577350>, <-0.577350,00.577350,-0.577350>,
     <00.577350,-0.577350,-0.577350>, <00.577350,00.577350,00.577350>
}

#local TestMesh = mesh {
     triangle { VL[00], VL[01], VL[03] }
     triangle { VL[00], VL[02], VL[01] }
     triangle { VL[00], VL[03], VL[02] }
     triangle { VL[01], VL[02], VL[03] }
     translate z*10
}

#local TestLargeUnion = union {
     #local c0 = 0; #while ( c0 < 100 )
         cylinder { VL[0], VL[1]+<0,0,c0>, .003 }
         cylinder { VL[0], VL[2]+<0,0,c0>, .003 }
         cylinder { VL[0], VL[3]+<0,0,c0>, .003 }
         cylinder { VL[1], VL[2]+<0,0,c0>, .003 }
         cylinder { VL[2], VL[3]+<0,0,c0>, .003 }
         cylinder { VL[3], VL[1]+<0,0,c0>, .003 }
     #local c0 = c0 + 1; #end
     translate z*10
}

#switch ( frame_number )
     #case ( 1 )
         object { TestMesh }
         //object { TestLargeUnion }
         background { rgb <1,0,0> }
     #break
     #case ( 2 )
         object { TestMesh }
         object { TestLargeUnion }
         background { rgb <0,1,0> }
     #break
#end

Post a reply to this message

Shay wrote:

> POV-Ray 3.6 on Win98 machine 650M processor with 256M Ram.
> 

Confirmed on 1200M processor with 384M Ram running Slackware Linux.

  -Shay

Post a reply to this message

news:40fe7064$1@news.povray.org...
> Confirmed on 1200M processor with 384M Ram running Slackware Linux.
Confirmed on a P3/NT4 machine with 640 M Ram.

Here's a simpler scene. It's the number of elements in the first frame that
causes the trouble in the following frames. 3 spheres in the first frame =
OK ; 2 spheres or less = not OK.
Definitely worth a bug report.

camera{location -z*100}
#if (frame_number=1)
    sphere{0,1 pigment{rgb x} finish{ambient 1}}
    sphere{0,1 translate y*2 pigment{rgb x} finish{ambient 1}}
    sphere{0,1 translate y*4 pigment{rgb x} finish{ambient 1}}
 #else
    #declare i=0;
    #while (i<1000)
        sphere{0,1 translate y*i*2 pigment{rgb y} finish{ambient 1}}
        #declare i=i+1;
    #end
#end

-- 

**********************
http://www.oyonale.com
**********************
- Graphic experiments
- POV-Ray and Poser computer images
- Posters

Post a reply to this message

"Gilles Tran" wrote:
> Here's a simpler scene. It's the number of elements
> in the first frame that causes the trouble in the
> following frames. 3 spheres in the first frame =
> OK ; 2 spheres or less = not OK.
> Definitely worth a bug report.

I think it's a feature, though IMO not a very clever one.

The number of objects in a scene determines if Auto Bounding is turned on.
However, it is the number of objects in the *first* frame that determines if
Auto Bounding *for the entire animation* is turned on or off.

To work around the problem, make sure that Auto Bounding is simply always
turned on by putting this in your master povray.ini file:

Bounding_Threshold = 0

Rune
-- 
3D images and anims, include files, tutorials and more:
rune|vision:  http://runevision.com
POV-Ray Ring: http://webring.povray.co.uk

Post a reply to this message

Rune wrote:

Thanks, Gilles and Rune, for getting to the bottom of this. 
Bounding_Threshold = 0 works.

  -Shay

Post a reply to this message