Greetings,

Perhaps someone could clear this up for me. I'm trying to generate a
scene with a partially transparent object (a lens flare disc). The
problem is that while all other objects appear visible through the
transparent object, media and fog don't. Are there some special
considerations which I'm maybe not taking into account...or what?

Any help would be greatly appreciated.

-Abe

Post a reply to this message

'hollow' and 'inverse' are two possible solutions.  If you have both media and
fog in the scene there might be nothing you can do to completely fix it though.
There's always been troubles for the combination of fog and transparent
container objects.  Sometimes you can adjust the pigment of the containers to
mask them more but it's not perfect at all.  Increasing the filter or transmit
(or combination of both) by a slight bit over 1 can help.
Anyway, there's that difficulty.  If you get no media or fog on just one side of
the disc then go with hollow and maybe inverse (or just flip the disc 180
degrees).

Bob

"Abe" <bul### [at] taconicnet> wrote in message
news:38815E78.35B88272@taconic.net...
> Perhaps someone could clear this up for me. I'm trying to generate a
> scene with a partially transparent object (a lens flare disc). The
> problem is that while all other objects appear visible through the
> transparent object, media and fog don't. Are there some special
> considerations which I'm maybe not taking into account...or what?

Post a reply to this message

ArrgggGGGHHH! <resounding slap on the forehead> I must be getting
senile!! Yes, it was missing that blasted "hollow". Works fine now.

Thanks for taking the time to respond!

-Abe

Post a reply to this message

Abe wrote:
> 
> ArrgggGGGHHH! <resounding slap on the forehead> I must be getting
> senile!! Yes, it was missing that blasted "hollow". Works fine now.

Passing through a non-hollow object appears to turn off all media
rendering for a ray.  The docs imply that only the object containing the
media needs to be hollow; actually, *any* object through which the
media will be seen needs to be hollow.

Regards,
John
-- 
ICQ: 46085459

Post a reply to this message

In article <38822DBD.812A2DD7@erols.com> , John VanSickle 
<van### [at] erolscom>  wrote:

> Passing through a non-hollow object appears to turn off all media
> rendering for a ray.  The docs imply that only the object containing the
> media needs to be hollow; actually, *any* object through which the
> media will be seen needs to be hollow.

How do you come to that conclusion? The sample scene below shows the
contrary.


     Thorsten




global_settings { assumed_gamma 2.2 }

#include "colors.inc"

camera {
   location  <0, 20, -100>
   direction <0,  0,    1>
   up        <0,  1,    0>
   right   <4/3,  0,    0>
}

plane { y, -10
   pigment {
      checker Blue, Green
      scale 20
   }
   finish {
      ambient 0.2
      diffuse 0.8
   }
   hollow
}

plane { z, 50
   pigment {
      checker Blue, Green
      scale 20
   }
   finish {
      ambient 0.2
      diffuse 0.8
   }
   hollow
}

#declare Media = media {
  emission 0.05
  intervals 5
  samples 1, 10
  confidence 0.9999
  variance 1/1000
  density {
    spherical
    ramp_wave
    turbulence 0.1
    color_map {
      [0.0 color rgb <0, 0, 0>]
      [0.1 color rgb <1, 0, 0>]
      [1.0 color rgb <1, 1, 0>]
    }
  }
}

sphere { 0, 1
  pigment { color rgbf<1, 1, 1, 1> }
  finish { ambient 0 diffuse 0 }
  interior { media { Media } }
  scale 28
  translate <29, 20, 0>
  hollow
}

sphere { 0, 1
  pigment { color rgbf<1, 1, 1, 0.7> }
  scale 12
  translate <23, 20, -50>
  hollow no // either with or without
}

light_source {
  <500, 600, -200>
  color White
}

Post a reply to this message

The problem is with single-surface objects (such as a disc) which have no
inside and outside.  Therefore, once the ray goes through it once, POV will
always think that it is still inside the object.  IMHO, those objects should
be hollow by default.

For an object like a sphere, the ray enters and then exits the object, so
POV realizes that the ray is no longer inside a non-hollow object.

-Nathan

John VanSickle <van### [at] erolscom> wrote...
> Abe wrote:
> >
> > ArrgggGGGHHH! <resounding slap on the forehead> I must be getting
> > senile!! Yes, it was missing that blasted "hollow". Works fine now.
>
> Passing through a non-hollow object appears to turn off all media
> rendering for a ray.  The docs imply that only the object containing the
> media needs to be hollow; actually, *any* object through which the
> media will be seen needs to be hollow.
>
> Regards,
> John
> --
> ICQ: 46085459

Post a reply to this message