|
 |
You must be clipping it instead of differencing. I don't use Moray but
obviously this is waht happened. 'hollow' doesn't matter in CSG, it's
for fog, media, atmosphere, halo to see or not.
Posting at news.povray.org/moray.win might be better for answers.
Lark wrote:
>
> I'm trying to make a semicircular lense with a CSG made out of a cylinder
> and a cube. The cube kind of cuts half of the cylinder off. Anyway, when I
> do this, the half-cylinder that remains is hollow, like a wierd taco shell!
> I've checked, and nothing is hollow(I'm using moray 3.01). A lense doesn't
> work too well with no insides. Can anyone help? Thanks!
--
omniVERSE: beyond the universe
http://members.aol.com/inversez/POVring.htm
=Bob
Post a reply to this message
|
|
|
|
Lark wrote:
>
> I'm trying to make a semicircular lense with a CSG made out of a cylinder
> and a cube. The cube kind of cuts half of the cylinder off. Anyway, when I
> do this, the half-cylinder that remains is hollow, like a wierd taco shell!
> I've checked, and nothing is hollow(I'm using moray 3.01). A lense doesn't
> work too well with no insides. Can anyone help? Thanks!
A quick introduction to working CSG operations. Render this
example code. It demonstrates lens properties, material
properties, and just a few of the possible methods of using
CSG operations to create lens shaped objects.
If you need further assistance feel free to ask.
// Using an intersection with a plane to slice off half the cylinder
#declare Lens1 =
intersection{
cylinder{x*-3,x*3,1
pigment{rgbf<1,.7,.7,1>}
interior{ior 1.95}
}
plane{-z,-0
pigment{rgbf<1,.7,.7,1>}
interior{ior 1.95}
}
}
// Using a difference to create a concave cylindrical lense
#declare Lens2 =
difference{
cylinder{x*-3,x*3,1
pigment{rgbf<.7,.7,1,1>}
interior{ior 1.95}
}
cylinder{x*-3.1,x*3.1,1
translate<0,0,-.25>
pigment{rgbf<.7,.7,1,1>}
interior{ior 1.95}
}
}
// Using an intersection to create a convex lense from 2 spheres
#declare Lens3 =
intersection{
sphere{<0,0, .75>,1.5
pigment{rgbf 1}
interior{ior 1.95}
}
sphere{<0,0,-.75>,1.5
pigment{rgbf 1}
interior{ior 1.95}
}
}
object{Lens1 rotate 90*-y translate< 2, 2,0>}
object{Lens2 rotate 90*y translate<-2, 2,0>}
object{Lens3 rotate 90*y translate< 2,-4,0>}
object{Lens1 translate< 3,-1,0>}
object{Lens2 translate<-3,-1,0>}
object{Lens3 translate<-2,-4,0>}
plane{-z,-15 pigment{checker color rgb 1 color rgb 0 scale 5}}
light_source{<0,190,-300>rgb 1}
light_source{<0, 15,-575>rgb 1}
camera{location<0,0,-12>look_at 0}
--
Ken Tyler
tyl### [at] pacbell net
Post a reply to this message
|
|
