POV-Ray : Newsgroups : povray.binaries.images : reduction to the essentials Server Time: 27 Jul 2017 22:48:45 GMT
  reduction to the essentials (Message 1 to 10 of 25)  
Goto Latest 10 Messages Next 10 Messages >>>
From: Norbert Kern
Subject: reduction to the essentials
Date: 8 Jul 2017 17:05:01
Message: <web.59610f6fdda8b45d98e703220@news.povray.org>
Abstracts are nice, especially those true to the motto "reduction to the
essentials".
Here I variated a nice scene of Christian Perle (
http://chris.silmor.de/ray/POVImgs2.html ).
Essential here is a max_trace_level higher than 5.

Code is short enough to show it here -

// A variation of:

// Inside the box
// 9/2016 Christian Perle
// http://chris.silmor.de/ray/pov2/inner_box.html
// http://chris.silmor.de/ray/POVImgs2.html // for further images and sources

#version 3.7;

global_settings {
        assumed_gamma 1
        max_trace_level 28
}

camera {
        perspective
 location <-0.24,0.2,-1.3>
 direction 1.2*z
 look_at <0,-0.05,1>
 rotate <0,0,-11>
        right x*image_width/image_height
}

#macro RoundBox ()

#local A = <-0.5,-0.5,-0.5>;
#local B = <0.5,0.5,0.5>;
#local Edge = 0.01;
#local AA = <min (A.x,B.x),min (A.y,B.y),min (A.z,B.z)>;
#local BB = <max (A.x,B.x),max (A.y,B.y),max (A.z,B.z)>;
#local LBF = AA;
#local RBF = <BB.x,AA.y,AA.z>;
#local RBB = <BB.x,AA.y,BB.z>;
#local LBB = <AA.x,AA.y,BB.z>;
#local LTF = <AA.x,BB.y,AA.z>;
#local RTF = <BB.x,BB.y,AA.z>;
#local RTB = BB;
#local LTB = <AA.x,BB.y,BB.z>;

merge {
        sphere {LBF, Edge}
        sphere {RBF, Edge}
        sphere {RBB, Edge}
        sphere {LBB, Edge}
        sphere {LTF, Edge}
        sphere {RTF, Edge}
        sphere {RTB, Edge}
        sphere {LTB, Edge}
        cylinder {LBF, RBF, Edge}
        cylinder {LBB, RBB, Edge}
        cylinder {LTB, RTB, Edge}
        cylinder {LTF, RTF, Edge}
        cylinder {LBF, LTF, Edge}
        cylinder {RBF, RTF, Edge}
        cylinder {RBB, RTB, Edge}
        cylinder {LBB, LTB, Edge}
        cylinder {LTB, LTF, Edge}
        cylinder {LBB, LBF, Edge}
        cylinder {RTB, RTF, Edge}
        cylinder {RBB, RBF, Edge}
        box {AA-Edge*x, BB+Edge*x}
        box {AA-Edge*y, BB+Edge*y}
        box {AA-Edge*z, BB+Edge*z}
}

#end

#declare RotBox =
object {
 RoundBox ()
 rotate 45*x
 rotate 35.26438968*z
}

merge {
 object {RotBox scale 0.9 interior {ior 1}}
 object {RotBox translate <1,0,0> interior {ior 1.5}}
 object {RotBox translate <-1,0,0> interior {ior 2}}
 object {RotBox translate <0,1,0> interior {ior 2.5}}
 object {RotBox translate <0,-1,0> interior {ior 3}}
 object {RotBox translate <0,0,2.5> interior {ior 3.5}}
 object {RotBox translate <0,0,-2.5> interior {ior 4}}
 hollow
 pigment {color rgb 0.05}
 finish {
  reflection 1
  phong 1
  phong_size 20
  irid {0.3 thickness 0.45}
 }
 rotate 90*x
}

Norbert


Post a reply to this message


Attachments:
Download 'inside the box_nk.jpg' (875 KB)

Preview of image 'inside the box_nk.jpg'
inside the box_nk.jpg


 

From: Simon J  Cambridge
Subject: Re: reduction to the essentials
Date: 8 Jul 2017 21:30:01
Message: <web.59614df668cc8a4f21bb12460@news.povray.org>
"Norbert Kern" <nor### [at] t-onlinede> wrote:
> Abstracts are nice, especially those true to the motto "reduction to the
> essentials".
> Here I variated a nice scene of Christian Perle (
> http://chris.silmor.de/ray/POVImgs2.html ).
> Essential here is a max_trace_level higher than 5.
>
> Code is short enough to show it here -
>
> // A variation of:
>
> // Inside the box
> // 9/2016 Christian Perle
> // http://chris.silmor.de/ray/pov2/inner_box.html
> // http://chris.silmor.de/ray/POVImgs2.html // for further images and sources
>
> #version 3.7;
>
> global_settings {
>         assumed_gamma 1
>         max_trace_level 28
> }
>
> camera {
>         perspective
>  location <-0.24,0.2,-1.3>
>  direction 1.2*z
>  look_at <0,-0.05,1>
>  rotate <0,0,-11>
>         right x*image_width/image_height
> }
>
> #macro RoundBox ()
>
> #local A = <-0.5,-0.5,-0.5>;
> #local B = <0.5,0.5,0.5>;
> #local Edge = 0.01;
> #local AA = <min (A.x,B.x),min (A.y,B.y),min (A.z,B.z)>;
> #local BB = <max (A.x,B.x),max (A.y,B.y),max (A.z,B.z)>;
> #local LBF = AA;
> #local RBF = <BB.x,AA.y,AA.z>;
> #local RBB = <BB.x,AA.y,BB.z>;
> #local LBB = <AA.x,AA.y,BB.z>;
> #local LTF = <AA.x,BB.y,AA.z>;
> #local RTF = <BB.x,BB.y,AA.z>;
> #local RTB = BB;
> #local LTB = <AA.x,BB.y,BB.z>;
>
> merge {
>         sphere {LBF, Edge}
>         sphere {RBF, Edge}
>         sphere {RBB, Edge}
>         sphere {LBB, Edge}
>         sphere {LTF, Edge}
>         sphere {RTF, Edge}
>         sphere {RTB, Edge}
>         sphere {LTB, Edge}
>         cylinder {LBF, RBF, Edge}
>         cylinder {LBB, RBB, Edge}
>         cylinder {LTB, RTB, Edge}
>         cylinder {LTF, RTF, Edge}
>         cylinder {LBF, LTF, Edge}
>         cylinder {RBF, RTF, Edge}
>         cylinder {RBB, RTB, Edge}
>         cylinder {LBB, LTB, Edge}
>         cylinder {LTB, LTF, Edge}
>         cylinder {LBB, LBF, Edge}
>         cylinder {RTB, RTF, Edge}
>         cylinder {RBB, RBF, Edge}
>         box {AA-Edge*x, BB+Edge*x}
>         box {AA-Edge*y, BB+Edge*y}
>         box {AA-Edge*z, BB+Edge*z}
> }
>
> #end
>
> #declare RotBox =
> object {
>  RoundBox ()
>  rotate 45*x
>  rotate 35.26438968*z
> }
>
> merge {
>  object {RotBox scale 0.9 interior {ior 1}}
>  object {RotBox translate <1,0,0> interior {ior 1.5}}
>  object {RotBox translate <-1,0,0> interior {ior 2}}
>  object {RotBox translate <0,1,0> interior {ior 2.5}}
>  object {RotBox translate <0,-1,0> interior {ior 3}}
>  object {RotBox translate <0,0,2.5> interior {ior 3.5}}
>  object {RotBox translate <0,0,-2.5> interior {ior 4}}
>  hollow
>  pigment {color rgb 0.05}
>  finish {
>   reflection 1
>   phong 1
>   phong_size 20
>   irid {0.3 thickness 0.45}
>  }
>  rotate 90*x
> }
>
> Norbert

That is beautiful! And thank you for the introduction to Christian Perle. I
haven't come across his stuff before.

Cheers,

Simon.


Post a reply to this message

From: Alain
Subject: Re: reduction to the essentials
Date: 9 Jul 2017 00:09:46
Message: <5961744a@news.povray.org>
Le 17-07-08 à 12:59, Norbert Kern a écrit :

> merge {
>   object {RotBox scale 0.9 interior {ior 1}}
>   object {RotBox translate <1,0,0> interior {ior 1.5}}
>   object {RotBox translate <-1,0,0> interior {ior 2}}
>   object {RotBox translate <0,1,0> interior {ior 2.5}}
>   object {RotBox translate <0,-1,0> interior {ior 3}}
>   object {RotBox translate <0,0,2.5> interior {ior 3.5}}
>   object {RotBox translate <0,0,-2.5> interior {ior 4}}
>   hollow
>   pigment {color rgb 0.05}
>   finish {
>    reflection 1
>    phong 1
>    phong_size 20
>    irid {0.3 thickness 0.45}
>   }
>   rotate 90*x
> }
> 
> Norbert
> 

Very nice.
I have a question : Why set those IORs? There is no transparency and no 
fresnel reflection, so, nothing were the ior can have any effect.

Now, let render this with fresnel turned ON or with some transparency.


Alain


Post a reply to this message

From: Norbert Kern
Subject: Re: reduction to the essentials
Date: 9 Jul 2017 16:30:01
Message: <web.5962580468cc8a4f2926c5a90@news.povray.org>
Alain <kua### [at] videotronca> wrote:

> Very nice.
> I have a question : Why set those IORs? There is no transparency and no
> fresnel reflection, so, nothing were the ior can have any effect.
>
> Now, let render this with fresnel turned ON or with some transparency.
>
>
> Alain



Ha - very smart Alain,

you caught me...
Fresnel lets the iridescence disappear - and iridescence is the second
essential.
Here's another image of Christian Perle (with revised code, I hope).



// A variation of:

// Inside the blob
// 10/2005 Christian Perle
// http://chris.silmor.de/ray/pov2/inner_blob.html
// http://chris.silmor.de/ray/POVImgs2.html // for further images and sources

#version 3.7;

global_settings {
        assumed_gamma 2.2
        max_trace_level 7
}

camera {
        location <-0.24,0.2,-1>
        direction 1.6*z
        look_at <0,0,1>
        rotate <0,0,11>
        right x*image_width/image_height
}

light_source {<0,0,0> color rgb <0,0.25,0>}
light_source {<0.1,-0.1,0> color rgb <0.25,0,0>}
light_source {<-0.1,0.1,0> color rgb <0,0,0.25>}

blob {
        threshold 0.6
        component 1, 0.8, <0,0,0>
        component 1, 1, <1,0,0>
        component 1, 1, <-1,0,0>
        component 1, 1, <0,1,0>
        component 1, 1, <0,-1,0>
        component 1, 1, <0,0,1>
        component 1, 1, <0,0,-1>
        pigment {color rgb 0.05}
        finish {
                reflection 1
                phong 1
                phong_size 6
                irid {0.15 thickness 0.38}
        }
        rotate 100*x
}


Norbert


Post a reply to this message


Attachments:
Download 'inside the blob_nk.jpg' (775 KB)

Preview of image 'inside the blob_nk.jpg'
inside the blob_nk.jpg


 

From: Norbert Kern
Subject: Re: reduction to the essentials
Date: 9 Jul 2017 16:40:00
Message: <web.59625c2068cc8a4f2926c5a90@news.povray.org>
"Simon J. Cambridge" <nomail@nomail> wrote:

>
> That is beautiful! And thank you for the introduction to Christian Perle. I
> haven't come across his stuff before.
>
> Cheers,
>
> Simon.



Hi Simon,

there are so many unknown sources...
When I worked on a special topic (my 3000 materials project), I stressed Google
with literally thousands of different queries around new *.pov sources. So I
came across Christians homepage.
Perhaps this is another interesting homepage -
https://karczmarczuk.users.greyc.fr/TEACH/Imagerie.old/POV/ .


Cheers,

Norbert


Post a reply to this message

From: clipka
Subject: Re: reduction to the essentials
Date: 9 Jul 2017 19:07:30
Message: <59627ef2$1@news.povray.org>
Am 09.07.2017 um 18:24 schrieb Norbert Kern:

> Fresnel lets the iridescence disappear

What?
It shouldn't do that.


Post a reply to this message

From: Norbert Kern
Subject: Re: reduction to the essentials
Date: 9 Jul 2017 21:35:01
Message: <web.5962a10d68cc8a4f2926c5a90@news.povray.org>
clipka <ano### [at] anonymousorg> wrote:
> Am 09.07.2017 um 18:24 schrieb Norbert Kern:
>
> > Fresnel lets the iridescence disappear
>
> What?
> It shouldn't do that.



Then - try this replacement of the terminal part of code in message 1.
You will recieve pure dark grey (rgb 0.05).

Norbert




#declare RotBox =
object {
 RoundBox () scale 1.2
 rotate <45,0,35>
}

merge {
 object {RotBox scale 0.9}
 object {RotBox translate <1,0,0>}
 object {RotBox translate <-1,0,0>}
 object {RotBox translate <0,1,0>}
 object {RotBox translate <0,-1,0>}
 object {RotBox translate <0,0,2.5>}
 object {RotBox translate <0,0,-2.5>}
 hollow
 pigment {color rgb 0.001}
 finish {
  reflection {1 fresnel on}
  irid {0.05 thickness 0.315}
 }
 rotate 90*x
}


Post a reply to this message

From: Bald Eagle
Subject: Re: reduction to the essentials
Date: 10 Jul 2017 16:25:00
Message: <web.5963a9f368cc8a4fc437ac910@news.povray.org>
clipka <ano### [at] anonymousorg> wrote:

> What?
> It shouldn't do that.

'Things move along so rapidly nowadays that people saying: It cant be done,
are always being interrupted by somebody doing it.'

:D


Post a reply to this message

From: Stephen
Subject: Re: reduction to the essentials
Date: 10 Jul 2017 17:18:32
Message: <5963b6e8@news.povray.org>
On 7/10/2017 5:23 PM, Bald Eagle wrote:
> clipka <ano### [at] anonymousorg> wrote:
>
>> What?
>> It shouldn't do that.
>
> 'Things move along so rapidly nowadays that people saying: âIt canât be done,â
> are always being interrupted by somebody doing it.'
>
A wise saying oh! Grasshopper. But the rice paper still proves a 
challenge. :)

-- 

Regards
     Stephen


Post a reply to this message

From: Bald Eagle
Subject: Re: reduction to the essentials
Date: 10 Jul 2017 20:55:01
Message: <web.5963e88368cc8a4fc437ac910@news.povray.org>
Stephen <mca### [at] aolcom> wrote:

> A wise saying oh! Grasshopper. But the rice paper still proves a
> challenge. :)

> Regards
>      Stephen

Keep practicing, Drunken Master.  ;)


Post a reply to this message

Goto Latest 10 Messages Next 10 Messages >>>

Copyright 2003-2008 Persistence of Vision Raytracer Pty. Ltd.