Alain nous apporta ses lumieres en ce 2008/01/28 15:06:
> nemesis nous apporta ses lumieres en ce 2008/01/27 20:20:
>> so, any free time in your hands?  want to put that quad core to stress 
>> with
>> povray 3.7beta?  If you're, try the little scene below.  With +AM2 
>> +A0.04 +J1.0
>> 1024X768 on a P4 2.66, it just brought my PC to a crawl for the whole 
>> weekend!
>> It all began with a challenge in a brazilian forum, when some guy 
>> claimed this
>> scene:
>> http://200.213.105.41/greysilica/exemplos/cjcopojateado.png
>>
>> took him 48 hours to render with Blender internal renderer.
>>
>> Surely something was wrong, or so I thought.  Well, in the region 
>> between the
>> bottom of second row cups and the top of first row cups, render time 
>> was about
>> 11 minutes a line!  It is all about refractions, normals and fresnel
>> reflections.  40 hours total on a P4 2.66 with povray 3.6.1...
>>
>> I'm sure it's possible to optimize it with some no_image, no_shadow 
>> trickery
>> with doubles and no_reflection in the main cups, but I didn't thought 
>> of it
>> beforehand!
>>
> Just rendered here with 3.7.
> LOT faster with +am2 +a0.3 at 1360*1024 AMD Athlon TBird 1400MHz.
> Added adc_bailout 0.013.
> Render time: 1:48:15.
> Only thing, your glasses look much darker.
> 
New render with +a0.1. Render time of 8:54:55 with nothing else changed. 
Imperceptible difference.

So, what's killing you is the aa with the micro normals.
Increasing the resolution will have the benefit of reducing the aa work, 
increasing the chance that adjacent pixels difference to be under the aa treshold.

-- 
Alain
-------------------------------------------------
A clear conscience is usually the sign of a bad memory.

Post a reply to this message

alphaQuad wrote:
> Maybe bigger bumps are needed with super-sampling? or removed from tex() for
> additional speed.

so thinks Alain in a message below.

>> I'll play with it, but first I need to come up with a better bezier curve... :)
> hope I get to see it.

for some reason, my bezier curves are not getting as smooth as I 
expected.  I'll update the scene when I get a smooth curve... you guys 
of course can play with it at will... I'm actually putting various 
speed/parameter variables all around...

Post a reply to this message

Christian Froeschlin nous apporta ses lumieres en ce 2008/01/29 08:40:
> Jan Dvorak wrote:
> 
>> Nicolas Alvarez napsal(a):
>>>
>>> I heard (filter + transmit) should be <= 1 for things to look correctly.
>>
>> f+t <= 1
>> f   >  0
>> t   >  0
>>
>> Did I forget something?
> 
> Reflection would also play into the equations.
> 
> The keyword "conserve_energy" can be useful.
 From the original scene: (plus my comments)
#macro tex( col )
pigment { rgb col }// this generate a "suspicious expression after rgb" warning
normal { bumps .1 scale .002 }// micro normal. Killer with high aa settings.
finish { ambient 0 diffuse .4 brilliance 1.2
specular .97 roughness .02
metallic .1
reflection { .2,.9 metallic .1 fresnel on exponent 1 }
conserve_energy
}
#end

conserve_energy is there.

-- 
Alain
-------------------------------------------------
Grandchildren are God's reward for not killing your own.

Post a reply to this message

Christian Froeschlin wrote:
> The keyword "conserve_energy" can be useful.

it's there.  And taking it away seems to produce a far more brighter 
picture, although as unrealistic as the original...

Post a reply to this message

Alain escribió:
> So, what's killing you is the aa with the micro normals.
> Increasing the resolution will have the benefit of reducing the aa work, 
> increasing the chance that adjacent pixels difference to be under the aa 
> treshold.
> 

Did you try uncommenting the focal blur line?

Post a reply to this message

/* wip 2.  more parametrized and using tips by Alain and elsewhere...
* DOF on (very light, just for testing AA other than supersampling
* normals off
* area_light off
* fresnel reflections on
* refractions on
* caustics on

* rendertime: 1:54 min on P4 3.00 800x600
*/



#local HQ = 0;			/* general high quality */
//#local FT = 0; //<0,0,0,.3,.68>;	/* filter/transmit */
#local FT = <0,0,0,.6,.38>;	/* filter/transmit */
#local AREALIGHTS = 0;
#local NORMALS = 0;
#local DOF = 1;			/* depth of field camera blur */
#local REFLECTIONS = 1;
#local REFRACTION = 1.55; 	/* 0, nothing; 1.55 glass; 1.33 water etc */
#local MEDIA = 0;
#local CAUSTICS = 1;
#local CAUSTICSgather = 1;
#local CRAZY = 0;


global_settings {
	#if (CRAZY)
	max_trace_level 40
	//adc_bailout .08
	#end
	#if (HQ)
	max_trace_level 40
	adc_bailout .02
	#else
	max_trace_level 60
	adc_bailout .06
	#end

	#if (CAUSTICS)
	photons {
		#if (CAUSTICSgather)
		save_file "cups-wip2.phm"
		count image_width*image_height
		max_trace_level 30
		adc_bailout .02
		#else
		load_file "cups-wip2.phm"
		#end
	}
	#end
}

background { rgb 1 }


#local cup =
	lathe { bezier_spline
     48, //nr points
     /*   0*/ <0, 2.8571826>, <174.28571, 2.8571826>, 
<197.14286,2.8571826>, <197.14286,2.8571826>,
     /*   1*/ <197.14286, 2.8571826>, <197.14286, 2.8571826>, 
<211.42857,-2.8571174>, <228.57143,14.285683>,
     /*   2*/ <228.57143, 14.285683>, <245.71429, 31.428583>, 
<242.85714,85.714283>, <242.85714,85.714283>,
     /*   3*/ <242.85714, 85.714283>, <242.85714, 85.714283>, 
<265.71429,80.000003>, <291.42857,105.71428>,
     /*   4*/ <291.42857, 105.71428>, <317.14286, 131.42857>, 
<308.57143,108.57143>, <308.57143,185.71428>,
     /*   5*/ <308.57143, 185.71428>, <308.57143, 262.85714>, 
<308.57143,742.85714>, <308.57143,742.85714>,
     /*   6*/ <308.57143, 742.85714>, <308.57143, 742.85714>, 
<317.14286,737.14285>, <308.57143,754.28571>,
     /*   7*/ <308.57143, 754.28571>, <300, 771.42857>, <288.57143,780>, 
<280,768.57143>,
     /*   8*/ <280, 768.57143>, <271.42857, 757.14285>, 
<294.28571,165.71428>, <277.14286,148.57143>,
     /*   9*/ <277.14286, 148.57143>, <260, 131.42857>, 
<231.42857,131.42857>, <217.14286,105.71428>,
     /*  10*/ <217.14286, 105.71428>, <202.85714, 80.000003>, 
<205.71429,54.285713>, <185.71429,45.714283>,
     /*  11*/ <185.71429, 45.714283>, <165.71429, 37.142883>, 
<2.8571429,2.8571826>, <0,2.8571826>

		sturm
		scale y*.8
		scale 1/1000
	}

#local cup2 = lathe { bezier_spline
     60, //nr points
     /*   0*/ <0, -1.7382813e-05>, <0, 18.571383>, <0,15.178483>, 
<0,15.178483>,
     /*   1*/ <0, 15.178483>, <6.25, 16.964183>, <27.321429,13.571383>, 
<31.250001,14.642783>,
     /*   2*/ <31.250001, 14.642783>, <31.250001, 14.642783>, 
<47.197559,12.769183>, <57.321429,20.675883>,
     /*   3*/ <57.321429, 20.675883>, <64.070661, 25.946983>, 
<67.105608,35.385283>, <69.58272,39.821383>,
     /*   4*/ <69.58272, 39.821383>, <72.837451, 45.650183>, 
<84.294576,84.731483>, <86.071436,102.5>,
     /*   5*/ <86.071436, 102.5>, <87.857146, 120.35714>, 
<85.357146,145>, <82.142856,165.71429>,
     /*   6*/ <82.142856, 165.71429>, <78.966586, 186.1836>, 
<91.342866,204.15811>, <96.071426,208.57143>,
     /*   7*/ <96.071426, 208.57143>, <101.42857, 213.57142>, 
<106.78572,215>, <107.5,210.71428>,
     /*   8*/ <107.5, 210.71428>, <108.21429, 206.42857>, 
<103.92858,210.71428>, <99.642856,187.85714>,
     /*   9*/ <99.642856, 187.85714>, <95.357146, 165>, 
<103.92858,148.57143>, <104.64286,125.71428>,
     /*  10*/ <104.64286, 125.71428>, <105.35715, 102.85714>, 
<101.42858,87.142853>, <97.857149,75.000003>,
     /*  11*/ <97.857149, 75.000003>, <94.285715, 62.857143>, 
<80.115281,24.737083>, <76.428572,19.821483>,
     /*  12*/ <76.428572, 19.821483>, <72.142858, 14.107183>, 
<64.730914,9.7242826>, <64.464285,5.7142826>,
     /*  13*/ <64.464285, 5.7142826>, <64.071714, -0.18991738>, 
<61.964286,-1.7382813e-05>, <61.964286,-1.7382813e-05>,
     /*  14*/ <61.964286, -1.7382813e-05>, <61.964286, -1.7382813e-05>, 
<0,-1.7382813e-05>, <0,-1.7382813e-05>
	sturm
	scale .002*2
	scale (x+z)*.7
	translate y*1.7382813e-05
}

#macro tex( col )
material {
	texture {
	pigment { rgbft col + FT }
	//pigment { rgbt 1 }
	#if (NORMALS) normal { bumps .1 scale .002 } #end
	#if (1)
	finish { ambient .06 diffuse .4 brilliance 1.2
			specular .92
			#if (NORMALS)
			roughness .04
			#else
			roughness .01
			#end
			metallic .07
			#if (REFLECTIONS)
			reflection { .06,.5 metallic .07 fresnel 1 exponent 1.2 falloff 2 }
			conserve_energy
			#end
	}
	#end
	}
	interior {
		#if (REFRACTION) ior REFRACTION #end
		fade_power 2 fade_distance .02 fade_color rgbft col+FT
		#if (MEDIA)
	    media {
                 intervals 8 samples 2,6
                 emission 3.81*(col)
                 absorption 12*(1-col)
                 #if (CRAZY) scattering { 0, (col)*7 extinction 1 } #end
				scale .2
                 #if (1)
                 density {
					bumps scale .002
                     color_map {[0 rgb 1][.5 rgb 1][.56 rgb 0][1 rgb 0]}
                 }
                 #end
         }
		#end
	}
}
	photons { target refraction on }
hollow
#end

union {
	plane { y 0
		pigment { rgb 1 }
		//pigment { checker rgb .6 rgb 1 rotate y*35 }
		finish { ambient .1 diffuse .7  specular 1 roughness .2 }
		photons { collect on refraction on }
	}
	object { cup translate z*.7 tex( <.9,.86,.4> ) }
	#if (1)
	object { cup translate z*(.7+1.3) tex( <1,.96,.84> ) }
	object { cup translate 0 tex( <.7,.8,1> ) }
	object { cup translate x*.7 tex(<1,1,1> )}
	object { cup translate x*.7+z*.7 tex(<.96,1,.67> )}
	object { cup translate x*.7+z*.7*2 tex(<.7,1,.7> )}
	object { cup2 translate -x*.7 tex(<1,.6,.6> ) }
	object { cup2 translate -x*.7+z*(.0+1.3) tex(<.5,.5,.8> ) }
	object { cup translate -x*.7*2+z*(-.7+1.3) tex(<.7,1,.94> ) }
	#end
	light_source { 1.8*(3-z*5-x) 1.2
		#if (AREALIGHTS)
		area_light x,z,5,5 jitter circular adaptive 0
		#end
		photons { refraction on }
	}
	hollow

	//rotate -y*45
	rotate -x*30
	translate <.1,-1/2.6,4.0> //z*2.6-y/3+x*.1
}

  light_source { -z*8 .7 shadowless }

  camera { angle 50
	#if (DOF)
	aperture .04 blur_samples 60 confidence 1 focal_point y/2.2+z*4.5
	#end
}

Post a reply to this message

Attachments:
Download 'cups-wip2.jpg' (39 KB)

Preview of image 'cups-wip2.jpg'

Nice. The glass material looks more convincing. I also like your new glasses, 
much more elegant.

Now, how about adding some dispersion...

nemesis nous apporta ses lumieres en ce 2008/01/30 14:37:

> #macro tex( col )
> material {
>     texture {
>     pigment { rgbft col + FT }
>     //pigment { rgbt 1 }
>     #if (NORMALS) normal { bumps .1 scale .002 } #end
>     #if (1)
>     finish { ambient .06 diffuse .4 brilliance 1.2
>             specular .92
>             #if (NORMALS)
>             roughness .04
>             #else
>             roughness .01
>             #end
>             metallic .07
>             #if (REFLECTIONS)
>             reflection { .06,.5 metallic .07 fresnel 1 exponent 1.2 
> falloff 2 }
>             conserve_energy
>             #end
>     }
>     #end
>     }
>     interior {
>         #if (REFRACTION) ior REFRACTION #end
>         fade_power 2 fade_distance .02 fade_color rgbft col+FT

dispersion 0.03#if(CRAZY)dispersion_samples 20 #else dispersion_samples 9 #end

>         #if (MEDIA)
>         media {
>                 intervals 8 samples 2,6
>                 emission 3.81*(col)
>                 absorption 12*(1-col)
>                 #if (CRAZY) scattering { 0, (col)*7 extinction 1 } #end
>                 scale .2
>                 #if (1)
>                 density {
>                     bumps scale .002
>                     color_map {[0 rgb 1][.5 rgb 1][.56 rgb 0][1 rgb 0]}
>                 }
>                 #end
>         }
>         #end
>     }
> }
>     photons { target refraction on }
> hollow
> #end
> 


-- 
Alain
-------------------------------------------------
You know you've been raytracing too long when you call in sick in order to render.
David Kraics

Post a reply to this message

Alain escribió:
> Now, how about adding some dispersion...

And don't use CPU time as an excuse :)

Post a reply to this message

Nicolas Alvarez wrote:
> Alain escribió:
>> Now, how about adding some dispersion...
> 
> And don't use CPU time as an excuse :)

you guys are amazing!  I'll add dispersion, and next you'll want media 
ON in the material!  :P

but really, the best tip so far was the adc_bailout control variable. 
What an amazing speed boost for so little loss in quality... BTW, 
Nicolas, there is adc_bailout and max_trace_level specifically in the 
global photons block as well.  Did you try that with the scene you 
rendered for Sven?  Perhaps it'd drop down as well...

well, obviously normals are off in this scene so I'll test that eventually.

About the new bezier curve:  I think I'm getting the hang of it, but 
it's still not perfect.  It shows some sharp divisions between one curve 
segment and the next.  But now I think I know the reason:  the control 
points should be further away from the tangential point.  It's much 
easier to draw the curve and then edit the points to tweak the curve.

Next render, I hope I get some progress in that front...

Post a reply to this message

nemesis nous apporta ses lumieres en ce 2008/01/31 13:17:
> Nicolas Alvarez wrote:
>> Alain escribió:
>>> Now, how about adding some dispersion...
>>
>> And don't use CPU time as an excuse :)
> 
> you guys are amazing!  I'll add dispersion, and next you'll want media 
> ON in the material!  :P
> 
> but really, the best tip so far was the adc_bailout control variable. 
> What an amazing speed boost for so little loss in quality... BTW, 
> Nicolas, there is adc_bailout and max_trace_level specifically in the 
> global photons block as well.  Did you try that with the scene you 
> rendered for Sven?  Perhaps it'd drop down as well...
> 
It's an override. If not specified, the photons will inherit the general 
settings. If you set those, the photon's max_trace_level and adc_bailout will 
replace the general values only for the photons computing.

-- 
Alain
-------------------------------------------------
WARNING: The consumption of alcohol is a major factor in dancing like a retard.

Post a reply to this message