POV-Ray : Newsgroups : povray.binaries.images : QUESTION: Bump not showing? Server Time
29 Mar 2024 02:17:29 EDT (-0400)
  QUESTION: Bump not showing? (Message 1 to 10 of 91)  
Goto Latest 10 Messages Next 10 Messages >>>
From: Sven Littkowski
Subject: QUESTION: Bump not showing?
Date: 15 Jul 2017 20:40:24
Message: <596ab5f8@news.povray.org>
I never actually used bump_maps before. Now I try to use one, but not
seeing any effect. Can someone assist me?

The scene contains a stratosphere helium balloon, and the bump_map
should have created the typical balloon surface. However, I don't see
the surface changed. Before posting any images, I show you the scene
file. is there any error the way I do it?

-------------------------------------------

#version 3.7;

#include "kolors.inc"
#include "finish.inc"
#include "textures.inc"

#declare MyRadiosity = off;

global_settings
{
 #if(MyRadiosity)
  radiosity
  {
   media on
   pretrace_start 0.08
   pretrace_end   0.001
   count 400
   error_bound 0.75
   recursion_limit 1
  }
 #end
 subsurface        {}
 adc_bailout       0.0039
 ambient_light     rgb < 0.000, 0.000, 0.000 >
 assumed_gamma     1.000
 irid_wavelength   rgb < 0.250, 0.180, 0.140 >
 max_trace_level   5
 number_of_waves   10
 noise_generator   3
 charset           ascii
}

camera
{
 location < -000.0, 400.0, -500.0 >
 look_at < 0.0, -200.0, 0.0 >
 right 1.77*x
}

//
---------------------------------------------------------------------------
-------------------------------------------------------


light_source
{
 < 2500.0, 2500.0, 5000.0 >
 rgb < 0.72265625, 0.8046875, 0.80859375 > *10.0
}

//
---------------------------------------------------------------------------
-------------------------------------------------------

#declare MyRadius = 200.0;

//
---------------------------------------------------------------------------
-------------------------------------------------------

#declare MyOuterBalloonFinish = finish
{
// reflection   0.00
 crand        0.10
}

#declare MyInnerBalloonFinish = finish
{
 brilliance   1.50
 phong albedo 0.05
 metallic     0.00
 ambient      0.00
 emission     0.00
 reflection   0.50
}

#declare MyOuterBalloonTexture = texture
{
 pigment
 {
  image_map { png "H:\My Documents\My Pictures\POV-Ray\Space - Launcher
- Balloon - Type 001 - Moon Runnings - Balloon Texture.png" }
  translate -0.5
  rotate < 90.0, 0.0, 0.0 >
  scale MyRadius*2
 }
 normal
 {
  bump_map { png "H:\My Documents\My Pictures\POV-Ray\Space - Launcher -
Balloon - Type 001 - Moon Runnings - Balloon BumpMap.png" gamma 1.8
bump_size 150.0 }
  translate -0.5
  rotate < 90.0, 0.0, 0.0 >
  scale MyRadius*2
 }
 finish { MyOuterBalloonFinish }
}

#declare MyInnerBalloonTexture = texture
{
 pigment { color rgb < 0.7686275,  0.7607843,  0.7333333 > }
 finish { MyInnerBalloonFinish }
}

//
---------------------------------------------------------------------------
-------------------------------------------------------

#declare UpperBalloonShape = torus     // Balloon Radius: 175 m /
Launcher Radius: 10 m
{
 95.0, 105.0
 scale < 1.0, 0.5, 1.0 >
}

#declare LowerBalloonShape = difference
{
 sphere { < 0.0, 0.0, 0.0 > MyRadius }
 cylinder { < 0.0, 0.0, 0.0 > < 0.0, 175.001, 0.0 > MyRadius+0.001 }
 scale < 1.0, 1.5, 1.0 >
}

#declare MyBalloonHullOutside = union
{
 object { UpperBalloonShape }
 object { LowerBalloonShape }
 texture { MyOuterBalloonTexture }
}

#declare MyBalloonHull = difference
{
 object { MyBalloonHullOutside }
 object
 {
  MyBalloonHullOutside
  scale 0.99999
  texture { MyInnerBalloonTexture }
 }
 cylinder  // Launcher Openings
 {
  < 0.0, -((MyRadius*1.5)+0.001), 0.0 > < 0.0, (MyRadius+0.001), 0.0 > 3.5
  texture { MyInnerBalloonTexture }
 }
}

#declare Launcher = difference
{
 union
 {
  #declare MyLength = 10.0;
  #declare MyHeight = 0.0;
  #declare MyTop = 35.0;
  cylinder { < 0.0, -((MyRadius*1.5)+30.0), 0.0 > < 0.0, MyTop, 0.0 >
3.5 }
  box { < MyLength, -MyHeight, -0.1 > < -MyLength, MyTop, 0.1 > rotate <
0.0, 000.0, 0.0 > }
  box { < MyLength, -MyHeight, -0.1 > < -MyLength, MyTop, 0.1 > rotate <
0.0, 045.0, 0.0 > }
  box { < MyLength, -MyHeight, -0.1 > < -MyLength, MyTop, 0.1 > rotate <
0.0, 090.0, 0.0 > }
  box { < MyLength, -MyHeight, -0.1 > < -MyLength, MyTop, 0.1 > rotate <
0.0, 135.0, 0.0 > }
  box { < MyLength, -MyHeight, -0.1 > < -MyLength, MyTop, 0.1 > rotate <
0.0, 180.0, 0.0 > }
  box { < MyLength, -MyHeight, -0.1 > < -MyLength, MyTop, 0.1 > rotate <
0.0, 225.0, 0.0 > }
  box { < MyLength, -MyHeight, -0.1 > < -MyLength, MyTop, 0.1 > rotate <
0.0, 270.0, 0.0 > }
  box { < MyLength, -MyHeight, -0.1 > < -MyLength, MyTop, 0.1 > rotate <
0.0, 315.0, 0.0 > }
 }
 cylinder { < 0.0, -((MyRadius*1.5)+30.001), 0.0 > < 0.0, MyTop+0.001,
0.0 > 3.3 }
 pigment { color rgb 1.0 }
}

#declare DoublePositionLight = union
{
 union
 {
  cylinder { < 0.0, 0.0,  2.5 > < 10.0, 0.0,  2.5 > 0.20 }
  cylinder { < 0.0, 0.0, -2.5 > < 10.0, 0.0, -2.5 > 0.20 }
  pigment { color rgb < 0.05, 0.05, 0.05 > }
  finish { MyOuterBalloonFinish }
 }
 union
 {
  sphere { < 10.0, 0.0, 2.5 > 0.35 }
  sphere { < 10.0, 0.0, -2.5 > 0.35 }
  pigment { color rgbf < 1.0, 0.0, 0.0, 0.5 > }
  finish { ambient rgb < 0.3, 0.1, 0.1 > }
 }
 union
 {
  light_source
  {
   < 10.0, 0.0, 2.5 >
   rgb < 0.7, 0.0, 0.0 > *10.0
   fade_distance 50.0
   fade_power 4
  }
  light_source
  {
   < 10.0, 0.0, -2.5 >
   rgb < 0.7, 0.0, 0.0 > *1.0
   fade_distance 50.0
   fade_power 4
  }
 }
}

#declare PositionLights = union
{
 #declare MyDistance = MyRadius-0.1;
 object { DoublePositionLight translate < MyDistance, 0.0, 0.0 > rotate
< 0.0, 000.0, 0.0 > }
 object { DoublePositionLight translate < MyDistance, 0.0, 0.0 > rotate
< 0.0, 045.0, 0.0 > }
 object { DoublePositionLight translate < MyDistance, 0.0, 0.0 > rotate
< 0.0, 090.0, 0.0 > }
 object { DoublePositionLight translate < MyDistance, 0.0, 0.0 > rotate
< 0.0, 135.0, 0.0 > }
 object { DoublePositionLight translate < MyDistance, 0.0, 0.0 > rotate
< 0.0, 180.0, 0.0 > }
 object { DoublePositionLight translate < MyDistance, 0.0, 0.0 > rotate
< 0.0, 225.0, 0.0 > }
 object { DoublePositionLight translate < MyDistance, 0.0, 0.0 > rotate
< 0.0, 270.0, 0.0 > }
 object { DoublePositionLight translate < MyDistance, 0.0, 0.0 > rotate
< 0.0, 315.0, 0.0 > }
}

union
{
 object { MyBalloonHull }
 object { Launcher }
 object { PositionLights }
}

background { rgb < 0.02392157,  0.03490196,  0.04627451 > }

---
Diese E-Mail wurde von AVG auf Viren geprüft.
http://www.avg.com


Post a reply to this message

From: clipka
Subject: Re: QUESTION: Bump not showing?
Date: 16 Jul 2017 16:10:38
Message: <596bc83e$1@news.povray.org>
Am 16.07.2017 um 01:40 schrieb Sven Littkowski:
> I never actually used bump_maps before. Now I try to use one, but not
> seeing any effect. Can someone assist me?
> 
> The scene contains a stratosphere helium balloon, and the bump_map
> should have created the typical balloon surface. However, I don't see
> the surface changed. Before posting any images, I show you the scene
> file. is there any error the way I do it?

I don't see you adapting the texture to the shape of the balloon (such
as by the use of `map_type`, spherical warp, or UV mapping).


Post a reply to this message

From: omniverse
Subject: Re: QUESTION: Bump not showing?
Date: 24 Jul 2017 01:50:03
Message: <web.59758a1a9f453b979c5d6c810@news.povray.org>
Sven Littkowski <I### [at] SvenLittkowskiname> wrote:
> I never actually used bump_maps before. Now I try to use one, but not
> seeing any effect. Can someone assist me?

Here's what I managed to do with it, changed many things so your scene file will
look different. See whole scene file text below.

I discovered something, caught me by surprise, when using a planar mapping for a
bump map the opposite side will invert the normal. Well, not too surprising if
on a plane {y,0} for example, but I didn't think about the inversion for a
spherical shape like your balloon.

That might not be so much a problem, because I easily solved that by using
opposite scale (as you will see in SDL changes). The real problem I encountered
is how the vertical portions of balloon lose bumpiness. I realize it could be
dealt with by using a non-planar mapping, or maybe warp (that I was unsuccessful
with), but the image file is not usable as such.

Someone else might be able to alter it but I didn't try more than applying
spherical and cylindrical warp {} to the planar image/bump map.

Including enhanced image file here too. It was indeed low contrast before, which
can be bad for this kind of thing. You should be able to see how the bumpiness
is shown now, mainly for upper and lower parts of balloon, yet flattens out on
the sides as I said.

Remember I changed things like lights, textures, too so you are going to need to
do whatever changes you want to this. At least I think you should see the
bumpiness anyhow.

#version 3.7;

//#include "colors.inc"
//#include "finish.inc"
//#include "textures.inc"

#declare MyRadiosity = off;

global_settings
{
 #if(MyRadiosity)
  radiosity
  {
   media on
   normal on // added
   pretrace_start 0.08
   pretrace_end   0.02
   count 123
   error_bound 0.75
   recursion_limit 2
  }
 #end
 //subsurface        {}
 //adc_bailout       0.0039
 ambient_light     0.06//rgb < 0.000, 0.000, 0.000 >
 assumed_gamma     1
 irid_wavelength   rgb < 0.250, 0.180, 0.140 >
 max_trace_level   4
 number_of_waves   10
 noise_generator   3
 charset           ascii
}

camera
{
 location < 0.0, 200.0, -500.0 >
 look_at < 0.0, -150.0, 0.0 >
 right image_width/image_height*x
}

light_source
{
 < 12500.0, 1500.0, -500.0 >,
 rgb < 0.72265625, 0.8046875, 0.80859375 > // *10.0
}

plane {y,-1000 pigment {rgb <0.9,0.95,1>}}

#declare MyRadius = 200.0;


#declare MyOuterBalloonFinish = finish
{
 brilliance   1.50
 phong albedo 0.05
 phong_size 5
 specular 0.5
 roughness 0.05
 metallic     0.00
 ambient      0.00
 emission     0.00
 reflection   {0.050,0.15}
}

#declare MyInnerBalloonFinish = finish
{
 brilliance   1.50
 phong albedo 0.05
 phong_size 5
 specular 0.5
 roughness 0.05
 metallic     0.00
 ambient      0.00
 emission     0.00
 reflection   {0.050,0.15}
}

#declare PositiveBump=
normal {
bump_map {
 png "spaceballoon2bumpmap" map_type 0 interpolate 2
}
bump_size 0.1
 translate -0.5
 rotate < 90.0, 0.0, 0.0 >
 scale MyRadius*2
}

#declare NegativeBump=
normal {
bump_map {
 png "spaceballoon2bumpmap" map_type 0 interpolate 2
}
bump_size 0.1
 translate -0.5
 rotate < 90.0, 0.0, 0.0 >
 scale -MyRadius*2
}

#declare MyOuterBalloonTexture = texture
{
 pigment
 {
  image_map { png "spaceballoon2bumpmap" gamma 1
    map_type 0 interpolate 2 once transmit all 0.5}
  translate -0.5
  rotate < 90.0, 0.0, 0.0 >
  scale MyRadius*2
 }
 normal { gradient y
 normal_map {
   [0.5 PositiveBump]
   [0.5 NegativeBump]
 } // end normal_map
 scale <1,MyRadius*2,1>
} // end normal
 finish { MyOuterBalloonFinish }
}

#declare MyInnerBalloonTexture = texture
{
 pigment { color rgb < 0.7686275, 0.7607843, 0.7333333 > transmit 0.5 }
 normal { gradient y
 normal_map {
   [0.5 PositiveBump]
   [0.5 NegativeBump]
   } // end normal_map
} // end normal
 finish { MyInnerBalloonFinish }
}


#declare UpperBalloonShape = torus // Balloon Radius: 175 m /
//Launcher Radius: 10 m
{
 95.0, 105.0
 scale < 1.0, 0.5, 1.0 >
}

#declare LowerBalloonShape = difference
{
 sphere { < 0.0, 0.0, 0.0 >, MyRadius }
 cylinder { < 0.0, 0.0, 0.0 >, < 0.0, MyRadius+0.001, 0.0 >, MyRadius+0.001 }
 scale < 1.0, 1.5, 1.0 >
}

#declare MyBalloonHullOutside = union
{
 object { UpperBalloonShape }
 object { LowerBalloonShape }
 texture { MyOuterBalloonTexture }
}

#declare MyBalloonHull = difference
{
 object { MyBalloonHullOutside }
 object
 {
  MyBalloonHullOutside
  scale 0.99999
  texture { MyInnerBalloonTexture }
 }
 cylinder  // Launcher Openings
 {
  < 0.0, -((MyRadius*1.5)+0.001), 0.0 >, < 0.0, (MyRadius+0.001), 0.0 >, 3.5
  texture { MyInnerBalloonTexture }
 }
}

#declare Launcher = difference
{
 union
 {
  #declare MyLength = 10.0;
  #declare MyHeight = 0.0;
  #declare MyTop = 35.0;
  cylinder { < 0.0, -((MyRadius*1.5)+30.0), 0.0 >, < 0.0, MyTop, 0.0 >, 3.5 }
  box { < MyLength, -MyHeight, -0.1 >, < -MyLength, MyTop, 0.1 >
rotate <0.0, 000.0, 0.0 > }
  box { < MyLength, -MyHeight, -0.1 >, < -MyLength, MyTop, 0.1 >
rotate <0.0, 045.0, 0.0 > }
  box { < MyLength, -MyHeight, -0.1 >, < -MyLength, MyTop, 0.1 >
rotate <0.0, 090.0, 0.0 > }
  box { < MyLength, -MyHeight, -0.1 >, < -MyLength, MyTop, 0.1 >
rotate <0.0, 135.0, 0.0 > }
  box { < MyLength, -MyHeight, -0.1 >, < -MyLength, MyTop, 0.1 >
rotate <0.0, 180.0, 0.0 > }
  box { < MyLength, -MyHeight, -0.1 >, < -MyLength, MyTop, 0.1 >
rotate <0.0, 225.0, 0.0 > }
  box { < MyLength, -MyHeight, -0.1 >, < -MyLength, MyTop, 0.1 >
rotate <0.0, 270.0, 0.0 > }
  box { < MyLength, -MyHeight, -0.1 >, < -MyLength, MyTop, 0.1 >
rotate <0.0, 315.0, 0.0 > }
 }
 cylinder { < 0.0, -((MyRadius*1.5)+30.001), 0.0 >,
< 0.0, MyTop+0.001, 0.0 >, 3.3 }
 pigment { color rgb 1.0 }
}

#declare DoublePositionLight = union
{
 union
 {
  cylinder { < 0.0, 0.0,  2.5 >, < 10, 0.0,  2.5 >, 0.20 }
  cylinder { < 0.0, 0.0, -2.5 >, < 10, 0.0, -2.5 >, 0.20 }
  pigment { color rgb < 0.05, 0.05, 0.05 > }
  finish { MyOuterBalloonFinish }
 }
 union
 {
  sphere { < 10.0, 0.0, 2.5 >, 0.35 }
  sphere { < 10.0, 0.0, -2.5 >, 0.35 }
  pigment { color rgbf < 1.0, 0.0, 0.0, 0.5 > }
  finish { emission rgb < 0.3, 0.1, 0.1 > }
 }
 union
 {
  light_source
  {
   < 10.25, 0.0, 2.5 >,
   rgb 1//< 0.7, 0.0, 0.0 > // *10.0
   fade_distance 15.0
   fade_power 2
  }
  light_source
  {
   < 10.25, 0.0, -2.5 >,
   rgb 1//< 0.7, 0.0, 0.0 > // *1.0
   fade_distance 15.0
   fade_power 2
  }
 }
}

#declare PositionLights = union
{
 #declare MyDistance = MyRadius-0.1;
 object { DoublePositionLight translate < MyDistance, 0.0, 0.0 >
rotate < 0.0, 000.0, 0.0 > }
 object { DoublePositionLight translate < MyDistance, 0.0, 0.0 >
rotate < 0.0, 045.0, 0.0 > }
 object { DoublePositionLight translate < MyDistance, 0.0, 0.0 >
rotate < 0.0, 090.0, 0.0 > }
 object { DoublePositionLight translate < MyDistance, 0.0, 0.0 >
rotate < 0.0, 135.0, 0.0 > }
 object { DoublePositionLight translate < MyDistance, 0.0, 0.0 >
rotate < 0.0, 180.0, 0.0 > }
 object { DoublePositionLight translate < MyDistance, 0.0, 0.0 >
rotate < 0.0, 225.0, 0.0 > }
 object { DoublePositionLight translate < MyDistance, 0.0, 0.0 >
rotate < 0.0, 270.0, 0.0 > }
 object { DoublePositionLight translate < MyDistance, 0.0, 0.0 >
rotate < 0.0, 315.0, 0.0 > }
}

union
{
 object { MyBalloonHull }
 object { Launcher }
// object { PositionLights }
}

background { rgb < 0.02392157,  0.03490196,  0.04627451 > }


Post a reply to this message


Attachments:
Download 'spaceballoon2bumpmap.png' (3960 KB)

Preview of image 'spaceballoon2bumpmap.png'
spaceballoon2bumpmap.png


 

From: omniverse
Subject: Re: QUESTION: Bump not showing?
Date: 24 Jul 2017 03:50:00
Message: <web.5975a1d69f453b979c5d6c810@news.povray.org>
"omniverse" <omn### [at] charternet> wrote:
>  normal { gradient y
>  normal_map {
>    [0.5 PositiveBump]
>    [0.5 NegativeBump]
>  } // end normal_map
>  scale <1,MyRadius*2,1>
> } // end normal

Mistakes... And wouldn't surprise me if it's still wrong somehow. I get confused
easily.  ;)

Replace both normal statements for outer and inner textures with this:


 normal { gradient y
 normal_map { /* 0.175 equates to 105/2 or balloon top (torus half vertical
scale) height from 0 */
   [0.175 PositiveBump]
   [0.175 NegativeBump]
 } // end normal_map
 scale <1,1.5*MyRadius,1> // rescale only y to fit whole balloon


And maybe it will be right. I neglected to see the 1.5 times rescale later on
for the balloon object.
And that flattened torus top (scale <1,0.5,1>) was simply being overlooked
because I was only thinking in terms of the gradient y
going upward and downward from 0, or starting at the max width part of balloon,
and not about actual distances for the gradient.

BTW, the gamma 1 for image file was arbitrarily chosen to brighten it for the
sake of seeing the bump map. You may have also noticed I changed the original
light source from 10 times to 1.5 times.

Bob


Post a reply to this message

From: Sven Littkowski
Subject: Re: QUESTION: Bump not showing?
Date: 24 Jul 2017 19:38:16
Message: <597684e8@news.povray.org>
On 24.07.2017 03:46, omniverse wrote:
> normal_map {
>    [0.5 PositiveBump]
>    [0.5 NegativeBump]
>  } // end normal_map
>  scale <1,MyRadius*2,1>
Hi. Now I am irritated, I admit. :-)

Did you see the bump images I added to the GENERAL group (same topic there)
?

However, someone else mentioned I should size down the bump image and
increase the contrast between bright and dark areas, and also to make it
16bit. I now did all this, still no success.

Please have a look to the attached bump image, this might help you to
know more about my problem and errors I do. Lots of thanks for your help!


---
Diese E-Mail wurde von AVG auf Viren geprüft.
http://www.avg.com


Post a reply to this message


Attachments:
Download 'space - launcher - balloon - type 001 - moon runnings - balloon bumpmap.png' (314 KB)

Preview of image 'space - launcher - balloon - type 001 - moon runnings - balloon bumpmap.png'
space - launcher - balloon - type 001 - moon runnings - balloon bumpmap.png


 

From: Sven Littkowski
Subject: Re: QUESTION: Bump not showing?
Date: 24 Jul 2017 19:41:23
Message: <597685a3@news.povray.org>
Thanks a lot for your assistance, so far. But I admit, I am now irritated.

Did you see the bump image I posted inside the other group (GENERAL)
with the same topic? Someone there told me to reduce the image size,
make it 16bit, and increase the contrast between dark and bright areas
there. I did that all. Still - no success.

I attached the new bump image, please have a look. It should give you a
better understanding of what I want to achieve (and maybe what I am
doing wrong).

Sven


---
Diese E-Mail wurde von AVG auf Viren geprüft.
http://www.avg.com


Post a reply to this message


Attachments:
Download 'space - launcher - balloon - type 001 - moon runnings - balloon bumpmap.png' (314 KB)

Preview of image 'space - launcher - balloon - type 001 - moon runnings - balloon bumpmap.png'
space - launcher - balloon - type 001 - moon runnings - balloon bumpmap.png


 

From: Sven Littkowski
Subject: Re: QUESTION: Bump not showing?
Date: 24 Jul 2017 19:47:53
Message: <59768729$1@news.povray.org>
Another problem: The same thread exists inside the GENERAL section. I
posted here at first before making up my mind that it might be a GENERAL
topic. Now we have two identical threads. I think, we all should just
use the GENERAL thread there, not this one.

---
Diese E-Mail wurde von AVG auf Viren geprüft.
http://www.avg.com


Post a reply to this message

From: omniverse
Subject: Re: QUESTION: Bump not showing?
Date: 24 Jul 2017 20:30:01
Message: <web.597690689f453b979c5d6c810@news.povray.org>
Sven Littkowski <I### [at] SvenLittkowskiname> wrote:
> Another problem: The same thread exists inside the GENERAL section. I
> posted here at first before making up my mind that it might be a GENERAL
> topic. Now we have two identical threads. I think, we all should just
> use the GENERAL thread there, not this one.

From general group message:
> Here's the updated bump image. I reduced its size, made it 16bit, and
> increased the contrast between dark and bright areas. Still - no
> success.   :-(
>
> Another problem: The same thread exists inside the IMAGE section. I
> posted there at first before making up my mind that it might be a
> GENERAL topic. Now we have two identical threads. I think, we all should
> just use THIS thread here, inside GENERAL.

I was avoiding general group because of image uploads not being accepted there,
so I'm not sure how you were able to do that.

Showing the render here that I was able to make using *your updated* bump_map
file, along with the SDL I posted here before (including fixed normal
statements).
And I regret uploading my version of the bump_map in PNG while leaving the
resolution size large, made almost 4 MB download file. Sorry!

I did not use reflection and radiosity, and also removed the image_map to use
only color rgb 1 which allows seeing only the bumpiness without any other visual
effects other than light source shadowing.

If you could show your resulting render here, to compare with this, it might
help figure out why you can't get "success". Must be an answer anyhow.

Bob


Post a reply to this message


Attachments:
Download 'test-bump_map-balloon.jpg' (34 KB)

Preview of image 'test-bump_map-balloon.jpg'
test-bump_map-balloon.jpg


 

From: clipka
Subject: Re: QUESTION: Bump not showing?
Date: 25 Jul 2017 00:28:50
Message: <5976c902$1@news.povray.org>
Am 25.07.2017 um 01:42 schrieb Sven Littkowski:
> 
> My e-mail client seems to ignore if I try to stop an unfinished posting.
> Please ignore the above posting with the wrong contents.

Select the posting in question, then open the "Nachricht" menu (Alt-N),
and choose "Beitrag zurückziehen" (Alt-Z).


Post a reply to this message

From: clipka
Subject: Re: QUESTION: Bump not showing?
Date: 25 Jul 2017 00:34:05
Message: <5976ca3d$1@news.povray.org>
Am 25.07.2017 um 01:41 schrieb Sven Littkowski:
> Thanks a lot for your assistance, so far. But I admit, I am now irritated.

I hope you're just "confused" ("irritiert"), not "irritated" ("verärgert").


Post a reply to this message

Goto Latest 10 Messages Next 10 Messages >>>

Copyright 2003-2023 Persistence of Vision Raytracer Pty. Ltd.