Here I have both the black and blue and the WHite and gold simply by  
changing the sky colour
It\s all in the radiosity and exposure

// begin code ---

//--------------------------------------------------------------------------
#version 3.7;
#default{ finish{ ambient 0.1 diffuse 0.9 }}
//--------------------------------------------------------------------------
#default{ finish{ ambient 0 diffuse 1 }}
//------------------------------------------
#include "shapes.inc"
#include "colors.inc"
#include "textures.inc"
//------------------------------------------

global_settings{
   ambient_light 1
   radiosity {
          // pretrace_start 1
          // pretrace_end 1
           error_bound 0.6
           count 1000
          // brightness 1
          // gray_threshold 0
          // media on
          // normal on
           recursion_limit 2
        } // --------------
  }// end global_settings
// ----------------------------------------



camera{ location  <0, 14, -20>
         right   x*image_width/image_height
         rotate 12*y
         look_at   <-1.25,2.8,0>
         angle 33
       }
//sky_sphere{ pigment { color rgb 1} } // Blue/Black
sky_sphere{ pigment { color rgb <1,1,.3>*20} } // gold/white

// fog  
---------------------------------------------------------------------

// ground  
------------------------------------------------------------------
plane{ <0,1,0>, 0
       pigment{ // solid pattern for use in texture/pigment/normal(/density)
// cube checker pattern, alternates color1 and color2
   checker
     color rgb <1, 1, .1>,
     color rgb .5
     scale 5
}

      } // end of plane
// -----------------------------------------
//box{-50,50 hollow pigment{colour rgb <1,1,0>}finish{diffuse 1}}

union {
#for (Cnt,1,3)
   difference {
      box {<-1,-1,-1>,<1,1,1> }
      sphere {0,1.40 inverse /* texture{ pigment{ color rgb<1,1,1>*0.5}}*/   
}
      sphere {0,1.25}
      texture{ pigment{ color rgb ((Cnt/2)=(int(Cnt/2)))*<.1,.1,.7>+.03}//  
blue / black
               finish{ phong 1 diffuse 1-Cnt/10 reflection{  
0,.1*((Cnt/2)!=(int(Cnt/2)))} }
             }
      translate<0,0,0>
      scale 1+Cnt*0.65
      translate <0,1+Cnt*0.30,0>
      rotate Cnt*<0,-22,0>
    }//----------
#end
scale <1,1,1>
translate<0,1,0>
}
// -----------------------------------------

// End code ---


-- 
-Nekar Xenos-

Post a reply to this message

Attachments:
Download '!blueblack.png' (57 KB) Download 'blueblack.png' (64 KB)

Preview of image '!blueblack.png'

Preview of image 'blueblack.png'

Am 01.03.2015 um 09:26 schrieb Nekar Xenos:
> Here I have both the black and blue and the WHite and gold simply by
> changing the sky colour
> It\s all in the radiosity and exposure

Not the same effect as with the dress though. You just hit the dynamic 
range limit of the file format; that's not the case with the dress.

Post a reply to this message

On 03/01/2015 02:04 PM, clipka wrote:
> Am 01.03.2015 um 09:26 schrieb Nekar Xenos:
>> Here I have both the black and blue and the WHite and gold simply by
>> changing the sky colour
>> It\s all in the radiosity and exposure
>
> Not the same effect as with the dress though. You just hit the dynamic
> range limit of the file format; that's not the case with the dress.

OK, Christoph, challenge accepted.  In the right-side render, the dress 
is within the dynamic range, except for some of the brighter-lit blue 
areas.  The rest of the scene is washed out, as it was in the original 
photograph.

The left side uses an rgb 1 light source, appropriately adjusted for 
inverse square fading.  The right side uses hsv <40, 0.8, 9>, also 
1/sq-adjusted.  Ambient values were auto-calculated by my private render 
rig (as were the light source values and camera position), although for 
an experiment like this, you'd probably want to stick with radiosity. 
(The scene turns off ambient when it uses radiosity, even if you're 
still using POV-Ray 3.6.2.)

To keep it realistic, the scene uses assumed_gamma 1.  An even more 
realistic scene would use spectral rendering, but with this working POC, 
that seems like overkill.
_____________________________________________________________

#version 3.5;

#ifndef (Rad) #declare Rad = on; #end

global_settings
{ assumed_gamma 1
   #if (Rad)
     radiosity
     { count 100
       error_bound 0.5
       pretrace_end 0.01
       pretrace_start 0.08
       recursion_limit 2
     }
   #end
}

camera
{ location <0, 1, -5.6713>
   look_at <0, 1, 0>
   right 0.6667 * x
   up y
   angle 16.0585
}

#if (frame_number = 2)
   light_source
   { <-3.3125, 7.6250, -5.7374>,
     rgb <36409, 26700, 7282>
     fade_power 2 fade_distance 0.10417
     spotlight point_at <0, 1, 0> radius 45 falloff 90
   }
   #default
   { finish
     { diffuse 0.6
       ambient rgb (Rad? 0: <1.6278, 1.1937, 0.3256>)
     }
   }
#else
   light_source
   { <-3.3125, 7.6250, -5.7374>,
     rgb <4045.5, 4045.5, 4045.5>
     fade_power 2 fade_distance 0.10417
     spotlight point_at <0, 1, 0> radius 45 falloff 90
   }
   #default
   { finish
     { diffuse 0.6
       ambient rgb (Rad? 0: 0.18087)
     }
   }
#end

box
{ -1, 1 scale <7, 9, 7> hollow
   pigment { rgb 1 }
}

plane
{ y, 0
   pigment { checker rgb 0.5 rgb 1 }
}

sor
{ 8, <0.60, -0.50>, <0.37, 0.00>, <0.26, 0.60>, <0.31, 1.10>,
   <0.23, 1.40>, <0.30, 1.85>, <0.15, 2.00>, <0.00, 2.01>
   sturm
   pigment
   { gradient y color_map
     { [0.5 rgb <0.07, 0.09, 0.8>]
       [0.5 rgb 0.04]
     }
     scale 0.25
   }
}

Post a reply to this message

Attachments:
Download 'dresses.jpg' (41 KB)

Preview of image 'dresses.jpg'

On 03/01/2015 10:13 PM, Cousin Ricky wrote:
> #version 3.5;
>
> [snip]

Render with: +KFF2 +W320 +H480

Post a reply to this message

On 02/03/2015 02:16, Cousin Ricky wrote:
> On 03/01/2015 10:13 PM, Cousin Ricky wrote:
>> #version 3.5;

Are you using Moray?

-- 

Regards
     Stephen

Post a reply to this message

On 03/02/2015 03:42 AM, Stephen wrote:
> On 02/03/2015 02:16, Cousin Ricky wrote:
>> On 03/01/2015 10:13 PM, Cousin Ricky wrote:
>>> #version 3.5;
>
> Are you using Moray?

No, I'm just failing to assume that everyone has upgraded since 2004.

It doesn't need any features beyond 3.5, so I went with that.

Post a reply to this message

On 02/03/2015 14:55, Cousin Ricky wrote:
> On 03/02/2015 03:42 AM, Stephen wrote:
>> On 02/03/2015 02:16, Cousin Ricky wrote:
>>> On 03/01/2015 10:13 PM, Cousin Ricky wrote:
>>>> #version 3.5;
>>
>> Are you using Moray?
>
> No, I'm just failing to assume that everyone has upgraded since 2004.
>
> It doesn't need any features beyond 3.5, so I went with that.
>

Fair enough. Just a thought. :-)

-- 

I am a fairy and my name is Nuff.

Fairy Nuff.

Post a reply to this message