Darren New wrote:
> Actually, I'd like to see the file into which you injected your DF3. 
> That is, the surrounding lighting and statements and such.

Okay, here it is. I can also post the df3 file if you are interested. I 
have the max_gradient for the isosurface set at 80, even though POV 
suggested 2037.859:

/*
CAdf3B.pov

June 2009
Samuel Benge
*/

#default{finish{ambient 0}}

camera{
  location <-0.1735,10.3,-13>
  look_at<0,.5,0>
  angle 20/1.75
}

#declare air = <.1 .2 .5>;
#declare lres = 3;
#declare lpos = <.5,.5,1>;

light_source{
  lpos*100000,1.75
  area_light x*80000,z*80000,lres,lres
  adaptive 2 jitter
}

background{rgb <92,30,1>/1024}

#declare densityFile = "brainB.df3";

#declare DF3B=
pigment{
  pigment_pattern{planar scale 2 translate -y}
  pigment_map{
   [0 rgb 0]
   [.05
    density_file df3 densityFile
    interpolate 1
    translate -1/2
    rotate x*90+y*90
    scale 2*<1,-1,1>
   ]
  }
}

#declare DF3=
function{
  pigment{
   pigment_pattern{DF3B}
   color_map{
    [0 rgb 0]
    [.25 rgb 1]
   }
  }
}

isosurface{
  function{
   -DF3(x,y,z).grey+.5
  }
  accuracy .001
  max_gradient 80
  contained_by{box{-1,1}}
  pigment{
   bumps scale<100,.1,100>
   frequency 20
   translate y*.25
   color_map{
    [0 rgb<.8,.8,1>]
    [.25 rgb 1]
    [.5 rgb<.8,.7,1>]
    [1 rgb<1,.8,.7>]
   }
  }
  finish{brilliance 0}
  translate -y/8
  scale<2,1,2>
  double_illuminate
  no_shadow
}

box{-1.01,1.01
  pigment{rgbt 1}
  interior{
   media{
    absorption 70*air
    density{
     pigment_pattern{DF3B}
     color_map{
      [.1 rgb 0]
      [.125 rgb 1]
     }
    }
   }
  }
  translate -y/8
  scale<2,1,2>
  hollow
}

Post a reply to this message

stbenge wrote:
> Okay, here it is. I can also post the df3 file if you are interested. 

Thank you!  I wanted to play with different CAs, not fiddle with the POV ray 
itself. :-)

Actually, I have a CA that generates a nice 3D cave structure kind of thing 
(sorta). Originally built for an automated dungeon-crawl type game. I've put 
off building an actual scene because the blobs never seemed to come out 
right. I never thought to try a DF3 instead. I'll give this a go (in my 
copious spare time ;-).

-- 
   Darren New, San Diego CA, USA (PST)
   There's no CD like OCD, there's no CD I knoooow!

Post a reply to this message

Darren New wrote:
> stbenge wrote:
>> Okay, here it is. I can also post the df3 file if you are interested. 
> 
> Thank you!  I wanted to play with different CAs, not fiddle with the POV 
> ray itself. :-)

No problem! I know how you feel. I should feel bad about not learning 
vector.h and how to write df3s with it, but I don't :)

> Actually, I have a CA that generates a nice 3D cave structure kind of 
> thing (sorta). Originally built for an automated dungeon-crawl type 
> game. I've put off building an actual scene because the blobs never 
> seemed to come out right. I never thought to try a DF3 instead. I'll 
> give this a go (in my copious spare time ;-).

I would like to see it when you have something to show. I'm always 
interested in those types of things!

Sam

Post a reply to this message

Really intriguing!
;-)
Paolo

Post a reply to this message

> Really intriguing!

   Now that I think of it, apart from the technical wonders and the highly
artistic look, there is always "the intriguing touch" in Sam images.

   Great Work on this one, BTW...

--
Jaime

Post a reply to this message

Paolo Gibellini wrote:
> Really intriguing!
> ;-)
> Paolo

Thank you.

Sam

Post a reply to this message

Jaime Vives Piqueres wrote:

>> Really intriguing!
> 
>   Now that I think of it, apart from the technical wonders and the highly
> artistic look, there is always "the intriguing touch" in Sam images.
> 
>   Great Work on this one, BTW...

Thanks, it was just a test. I figured I should post *something* :)

Sam

Post a reply to this message

"stbenge" <" <-"@hotmail.com> schreef in bericht 
news:4a2d6535$1@news.povray.org...
>
> Thanks, it was just a test. I figured I should post *something* :)

Somehow, your tests are always more than just a test.

Thomas

Post a reply to this message

> Somehow, your tests are always more than just a test.

   Test scenes are almost whole genre in visual arts, and some people are
very good at it, including Samuel. Making a non-boring test scene is really
an art...

--
Jaime

Post a reply to this message

"Jaime Vives Piqueres" <jai### [at] ignoranciaorg> schreef in bericht 
news:4a2e7e05$1@news.povray.org...
>   Test scenes are almost whole genre in visual arts, and some people are
> very good at it, including Samuel. Making a non-boring test scene is 
> really
> an art...

I fully agree.

Thomas

Post a reply to this message