|
 |
Anyone had any success in getting rolling mist with media? I've been
experimenting for days and this is the best I can get.
Advice, tips, suggestions please???
Thanks very much
Gail
-- code follows
plane {y,-0.5 pigment {rgb <0,0,0.5>}}
box {<-20,0.001,-10>,<35,1,25>
material {
texture {pigment {Clear} finish {ambient 0 diffuse 0}}
interior {
media {
emission 0.5
scattering {2, rgb 0.7 extinction 0.5}
density {
gradient z
color_map {
[0.0 rgb 1]
[0.3 rgb 0.1]
[1.0 rgb 0]
}
scale <1,1,35> //55
translate z*-10
}
density {
function {y-f_noise3d(x*2,y,z*2)*0.5+0.3} // +0.4
color_map {
[0.0 rgb 1]
[0.4 rgb 0.5]
[0.8 rgb 0.5]
[1.0 rgb 0]
}
}
}
}
}
hollow
scale <1,0.4,1>
translate y*-0.5
}
Post a reply to this message
Attachments:
Download 'SwampMistTest.jpg' (18 KB)
Preview of image 'SwampMistTest.jpg'
|
|
|
|
"Slime" <fak### [at] email address> wrote in message
news:40cff8c2$1@news.povray.org...
> > function {y-f_noise3d(x*2,y,z*2)*0.5+0.3} // +0.4
>
> I'm wondering why you're basing your function off of the height, when
you've
> already got a gradient y pattern density. Why don't you just use f_noise3d
> without the "y - "?
>
I don't have a gradient y. I've got a gradient z to stop the backgroud
getting too bright
Gail
--
*************************************************************************
* gsh### [at] sentechsacom * If one is going to lose one's mind, *
* http://gail.rucus.net/ * one might as well savor the experience *
*************************************************************************
* This is how the world ends. Swallowed in fire, but not in darkness *
*************************************************************************
Post a reply to this message
|
|
|
|
Hi there Gail.
I tried something with it by using repeat warps and turbulence and-- well, I
ended up changing it to the point where I think it best to paste it into the
message here so you can see what I see when rendering it. It's somewhat like
a rolling fog bank or cloud.
Just got a little slow to render, though, because it needed samples added to
smooth it out. In fact, it might be too choppy-looking to be useful unless
something is changed.
Hmm, like sine_wave for the second density, which I just now commented into
this. Yeah, that doesn't look too bad, to me anyway. Still having trouble
with a overly one direction wave appearance I wanted to control but I'll
stop there.
Bob H.
/* BEGIN rolling fog or cloud */
camera {location <5,2,-5> angle 60 look_at 0}
light_source {-1000*z,1 rotate <45,30,0>}
#include "functions.inc"
plane {y,-0.5 pigment {rgb <0,0,0.5>}}
box {<-20,0.001,-10>,<35,2,25>
material {
texture {pigment {color rgbf 1} finish {ambient 0 diffuse 0}}
interior {
media {
// samples 15 // smoother
emission 0.5
scattering {2, rgb 0.1 extinction 1}
density {
gradient z
color_map {
[0.0 rgb 1]
[0.3 rgb 0.1]
[1.0 rgb 0]
}
scale <1,1,35> //55
translate z*-10
}
density {
function {
((z/4)*f_noise3d(x/3,y*2,z)) // don't ask... only guessing.
*
(f_noise3d(x*2,y,z*2)*0.5) // *0.5
}
color_map {
[0.0 rgb 0.75]
[0.4 rgb 0.5]
[0.6 rgb 0.25]
[1.0 rgb 0]
}
// sine_wave // softer
warp {repeat y/3 offset <1,4,3>/5 flip <0,1,1>}
warp {turbulence <0.1,0.3,1.2>}
warp {repeat z*4 offset <2,3,4>/5 flip <1,1,0>}
warp {turbulence <0.4,0.2,1.3>}
}
}
}
}
hollow
//scale <1,0.4,1>
translate -y
}
/* END */
Post a reply to this message
|
|
