What would be the easiest way to fade in/out a single object in a
scene?  (I have a tiled floor that I would like to just fade out over a
few frames.)  Any help and suggestions would be greatly appreciated.

Matt

Post a reply to this message

> What would be the easiest way to fade in/out a single object in a
> scene?  (I have a tiled floor that I would like to just fade out over a
> few frames.)  Any help and suggestions would be greatly appreciated.

try it with <transmit> or <filter> in a global <pigment> statement for your
object.

Post a reply to this message

> What would be the easiest way to fade in/out a single object in a
> scene?  (I have a tiled floor that I would like to just fade out over a
> few frames.)  Any help and suggestions would be greatly appreciated.

Say you are using a clock that goes from 0 to 5 and want it to be visible
to frame 1 and fade out up to frame 2, then you might do this:

#if (clock < 2)

plane {y, 0

#if (clock < 1)
pigment {color rgb <1, 1, 1>}
#else
pigment {color rgbt <1, 1, 1, 0+(clock-1)>}
#end

}

#end

The idea here being that the color is static from frames 0 to 1, then has
the transparency increase from 0 to 1 from frame 1 to 2.  After that the
plane is not rendered, which should help save on some rendering time.

-Mike

Post a reply to this message

Benk Stefan <Ste### [at] ruhr-uni-bochumde> wrote:
: try it with <transmit> or <filter> in a global <pigment> statement for your
: object.

  That will not fade out finishes.

-- 
main(i,_){for(_?--i,main(i+2,"FhhQHFIJD|FQTITFN]zRFHhhTBFHhhTBFysdB"[i]
):5;i&&_>1;printf("%s",_-70?_&1?"[]":" ":(_=0,"\n")),_/=2);} /*- Warp -*/

Post a reply to this message

On Tue, 05 Oct 1999 23:29:56 -0500, Matt <mat### [at] wctcnet> wrote:

>What would be the easiest way to fade in/out a single object in a
>scene?  (I have a tiled floor that I would like to just fade out over a
>few frames.)  Any help and suggestions would be greatly appreciated.
>
>Matt

Render two versions of the scene (or the anim). Put the floor in one
of the version and omit it in the other. Then use simple weighted
averaging to fade between both. You can use the POV average pattern in
an image_map, and map the averaged result on a box or plane in front
of the camera. You can also use Warp's Averager, DTA or my averager.


Peter Popov
ICQ: 15002700

Post a reply to this message

// BEGIN

/* FADER by Bob, for use with 'clock' variable */

// white pointlight at camera position
#declare LCX = 1;
#declare LCY = 3;
#declare LCZ = -10;

light_source { <LCX,LCY,LCZ> color rgb <1.5,1.5,1.5>
}
camera {
  location  <LCX,LCY,LCZ>
  angle 22.5
  look_at   <0,0,0>
}

/* FADER [note: imortant factor is the equivalence to zero at onset of
fading ranges] */
#switch (clock)
#range (0,.25)
#declare Fade=1
#break
#range (.25,.5)
// the numbers within parenthesis need to equal 0 at first switch over
#declare Fade=1-((-.25+clock)*4)  // 0.25 * 4 = 1
#break
#range (.5,.75)
#declare Fade=0
#break
#range (.75,1)
// the numbers within parenthesis need to equal 0 at first switch over
#declare Fade=0+((-.75+clock)*4)  // 0.25 * 4 = 1
#break
#end

plane {y,-1
 pigment {checker color rgb <1,1,0>*Fade color rgb <0,1,1>*Fade}
  finish {ambient .25*Fade diffuse .75*Fade specular 1*Fade roughness .05
 // do not use Fade on 'roughness'
             reflection .3*Fade}
}

sphere {0,1 pigment {rgb<1,0,0>}}

// END

Bob

Matt <mat### [at] wctcnet> wrote in message news:37FAD044.5C078306@wctc.net...
> What would be the easiest way to fade in/out a single object in a
> scene?  (I have a tiled floor that I would like to just fade out over a
> few frames.)  Any help and suggestions would be greatly appreciated.
>
> Matt
>

Post a reply to this message

Matt <mat### [at] wctcnet> wrote:
> What would be the easiest way to fade in/out a single object in a
> scene?  (I have a tiled floor that I would like to just fade out over a
> few frames.)  Any help and suggestions would be greatly appreciated.

Perhaps you could look at the Automatic Clock Modifier macros; this will let
you map textures to clock values, eg:

    #declare Checkers = texture {
        pigment {checker rgb 0, rgb 1}}
        normal {bumps .1}
        finish {phong .4 reflection .2}}

    #declare Clear = texture {pigment {rgbt 1}}

    plane {y, 0 texture {
        Texture_From (0.1, Checkers)
        Texture_To (0.9, Clear)}}
        }

In this example the texture goes from the checkered at clock = 0.1 to
completely transparent at clock = 0.9.  Of course any clock values may be
used, and the list can have as many texture entries as you like.  Also,
using the clock modification features you can make the fade accelerate,
decelerate, wave, repeat, etc.  The file is available from my site:

   http://www.geocities.com/SiliconValley/Lakes/1434

and a tutorial by Steve Strickland can be found at:

    http://www.puzzlecraft.com/cm/ClockMod.html

Post a reply to this message

Maybe you could try a layered texture with a completely transparent part
using the 'phase' keyword
(this is just an idea that came across my mind)

-Gerd

Post a reply to this message

Declare two textures, the texture you want the thing to have, then a
perfectly clear texture:

#declare basetexture = texture {pigment {radial frequency 8}
finish{specular 1}}
#declare cleartexture = texture { pigment { rgbt 1 } }
#declare anim_clock = xxx; // 0 to 1
sphere { 0.0, 1
         texture { average
                   texture_map { [(1- anim_clock) basetexture ]
                                 [(anim_clock) cleartexture ] } } }

as anim_clock goes from 0 to 1, the object will fade.

Matt wrote:

> What would be the easiest way to fade in/out a single object in a
> scene?  (I have a tiled floor that I would like to just fade out over a
> few frames.)  Any help and suggestions would be greatly appreciated.
>
> Matt

--

Josh English
eng### [at] spiritonecom
icq 1946299
"Stress is when you wake up screaming and realize you haven't fallen
asleep yet."

Post a reply to this message