Hello!

I am currently writing my dissertation at the University of Vienna
(Psychological Institute) in Austria (Europe) and I have the problem to
develop items (for an adaptive computertest of spatial abilities) such as
the one attached to this email.

My question: Is it possible to create test-items like the one attached to
this email with the software "Povray"?


Thank you,

Martin


---------------------------------------------------------
Martin E. Arendasy, MSc, PhD-Candidate
Vienna, Austria

Tel, FAX: (+43 1) 2789727
Email:    mel### [at] netwayat
---------------------------------------------------------

Post a reply to this message

Attachments:
Download 'EST.jpg' (23 KB)

Preview of image 'EST.jpg'

Martin E. Arendasy wrote:

> Hello!
>
> I am currently writing my dissertation at the University of Vienna
> (Psychological Institute) in Austria (Europe) and I have the problem
> to
> develop items (for an adaptive computertest of spatial abilities) such
> as
> the one attached to this email.
>
> My question: Is it possible to create test-items like the one attached
> to
> this email with the software "Povray"?

It is not difficult at all to do this with POV.  There are many ways,
but I like to use blob cylinders along splines.  You get a nice smooth
result this way with fewer pieces needed.  Here is a quick demo I did
for someone else.  Get Chris Colefax's spline include file at
http://www.geocities.com/SiliconValley/Lakes/1434 and use it with this
file.  The documentation for the spline include (along with the comments
in this demo) should get you going. Email if you need more information.
Here are Spldem.pov and Spldem.spl:

//Begin POV-Ray file Spldem.pov

// Blob Spline demo - a bent wire

#include "colors.inc"
#include "textures.inc"
#include "metals.inc"

camera
{
  location <5,10,-12>
  look_at  <4,5,0>
}

light_source
{
  <0,20,-40>
  color rgb 1
}

#declare Size = 1000 // How many pieces in the spline; more = smoother
but slower

#declare Radius = .25 // Adjusts thickness of wire

#declare Acc = 1/Size // How far apart spline points are

#declare spline_clock  = 0 // Spline.inc uses this

 blob { threshold .6 // The whole wire is one big blob object
  #while ( spline_clock < 1 )

  #include "Spldem.spl" // Use Spline.inc to generate points

   #if ( spline_clock >= Acc )

      #declare P = spline_pos // get this cylinder ending point

   #if ( spline_clock = Acc )

    #declare OldP = P - .00001 // Get first cylinder starting point

   #end

   cylinder { OldP, P, Radius, 1
    texture { T_Gold_3C } } // Blob component

      #declare OldP = P // Get next cylinder starting point

    #end

    #declare spline_clock = spline_clock + Acc

  #end
}

// End Spldem.pov

// Begin spline points file Spldem.spl

#declare spline_segments = 5 // how many segments
#declare spline_loop = false // make this true to close the spline

// It can help to pick points halfway between the sharp bends instead of
at them

#declare point0 = <0,0,0>
#declare point1 = <1,2,4>
#declare point2 = <3,5,4>
#declare point3 = <2,4,7>
#include "Spline.inc"

#declare point2 = <5,1,3>
#declare point3 = <7,6,9>
#include "Spline.inc"

#declare point2 = <3,8,5>
#declare point3 = <6,2,4>
#include "Spline.inc"

#declare point2 = <9,0,5>
#declare point3 = <7,4,3>
#include "Spline.inc"

#declare point2 = <5,3,7>
#declare point3 = <10,10,10>
#include "Spline.inc"

// if you want to close the spline smoothly, adding a segment with
// point2 and point3 = point0 and point1 helps

// End Spldem.spl

Jerry Anning
cle### [at] dholcom

Post a reply to this message