Hello, I'm a bit of a newbie at povray, and I was wondering if it's possible
to make a sphere of water that you can see text inside... like the old skool
demos.

-Trancequence

Post a reply to this message

"Trancequence" <tra### [at] trancequencef2scom> wrote in message
news:3bd9a6a6@news.povray.org...
> Hello, I'm a bit of a newbie at povray, and I was wondering if it's
possible
> to make a sphere of water that you can see text inside... like the old
skool
> demos.

As long as you are talking of just refraction of the text through a clear
sphere, very easily done.

// no camera needed

light_source {<15,20,-10>,1}

background {.5}

plane {y,-2
        pigment {checker rgb <1,1,0>, rgb <0,1,0>}
}

// water sphere with text inside
union {

sphere {
    0,1
        pigment {rgbft <.7,.9,1,.9,.1>} // color and clearness
        normal {wrinkles .2 scale .3} // watery look
        finish {
                ambient 0 diffuse 0 specular .9 roughness .001 // highlights
                reflection .2 //
                }
            interior {
    ior 1.3 caustics 1 // refractive with light interaction
    fade_distance 2 fade_power 1
                        }
 scale 2
}

text {
    ttf "timrom.ttf", "Text", .5, 0
        pigment {rgb 1}
        finish {ambient .2 diffuse .8 specular .3 roughness .01}
 translate <-1,-.25,-.5> scale 1.5
}

 translate 5*z

}


Bob H.

Post a reply to this message