 |
|
|
|
|
|
| |
| |
|
|
|
|
| |
| |
|
|
As a part of a scene, I create the figure shown below (on the left side - WIP
and untextured).
In the center of this model, I want to place a dark-blue, glossy
sphere, encased by a red aura.Wheras the red aura should
on the top more bright....and of course this shoud looking
very magical.
In my attempt (seen on the right side) the red aura is too hard and clear
and looks very "unmagical".
The code is this:
----[Snip]-------------
sphere { <0, 0, 0>, 0.95
pigment { color rgbt <0, 0, 0.58824, 0.2> }
finish { Phong_Glossy }
translate y*1.61
}
//*PMName Red Aura
sphere { <0, 0, 0>, 1.075
pigment { color rgbt <0, 0, 0, 0.55> }
interior {
media {
density {
cylindrical
density_map {
[ 0 color rgb <0, 0, 0> ]
[ 0.4 color rgb <1, 0, 0> ]
[ 0.8 color rgb <1, 1, 0> ]
[ 1 color rgb <1, 1, 1> ]
}
}
emission rgb <1, 1, 1>
}
}
translate y*1.612
hollow
}
----[Snap]--------------------------
So I want to ask you....how can I do it better ?
Post a reply to this message
Attachments:
Download 'wip.png' (110 KB)
Preview of image 'wip.png'
|
|
| |
| |
|
|
|
|
| |
| |
|
|
"Meothuru" <nomail@nomail> wrote:
> ----[Snip]-------------
> sphere { <0, 0, 0>, 0.95
> pigment { color rgbt <0, 0, 0.58824, 0.2> }
> finish { Phong_Glossy }
> translate y*1.61
> }
>
> //*PMName Red Aura
> sphere { <0, 0, 0>, 1.075
> pigment { color rgbt <0, 0, 0, 0.55> }
>
> interior {
> media {
> density {
> cylindrical
> density_map {
> [ 0 color rgb <0, 0, 0> ]
> [ 0.4 color rgb <1, 0, 0> ]
> [ 0.8 color rgb <1, 1, 0> ]
> [ 1 color rgb <1, 1, 1> ]
> }
> }
> emission rgb <1, 1, 1>
> }
> }
> translate y*1.612
> hollow
> }
> ----[Snap]--------------------------
First thing I notice is that the aura container is visible; this may be
intentional, but I think it makes the whole thing look crappy. So I'd try with
rgbt <0,0,0,1>. Also make sure that you don't have any finish on it (i.e.
ambient 0 diffuse 0 specular 0).
The next issue is that media effects totally filling a container generally don't
lool too convincing, so you want to have the density fall off towards the
outside.
You can achieve this by using a second density{} statements in the media, using
e.g. a properly scaled onion density map; this will effectively multiply both
densities, i.e. where any one of them is zero the total density will be zero,
and only where both are 1 the total density will be 1.
You may also want to give the whole thing some irregularity - you can use a
third density map for that, using a bozo pattern and some warp turbulence, for
instance.
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
"clipka" <nomail@nomail> wrote:
>
> First thing I notice is that the aura container is visible; this may be
[...]
> You may also want to give the whole thing some irregularity - you can use a
> third density map for that, using a bozo pattern and some warp turbulence, for
> instance.
Thanks for the tips. I will try out.
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
"Meothuru" <nomail@nomail> wrote:
> In the center of this model, I want to place a dark-blue, glossy
> sphere, encased by a red aura. Whereas the red aura should
> on the top more bright....and of course this should looking
> very magical.
> So I want to ask you....how can I do it better ?
I was wondering about your cylindrical pattern. I think there is a better (and
more controllable) way to get what you want. Here is what I came up with; it
uses two spherical densities, combined in an 'averaged' density_map. It also
shows that you can scale, translate and even rotate an individual density
inside your media sphere.
Replace your 'aura' sphere with this, and see how you like it.
Ken W.
-------
//*PMName Red Aura
sphere {<0, 0, 0>, 1 // don't scale it here--a spherical pattern
// is designed to exactly 'fill' a 1-unit-radius sphere. Scale the entire
// sphere later.
hollow
pigment {color rgbt 1}
interior {
media {
emission rgb 2.0*<1, 1, 1>
#declare density_1 =
density{
spherical
color_map{
[ 0.0 color rgb 0] // OUTSIDE
[ 0.05 rgb 0]
[ 0.2 color rgb <1, .2, 0>]
[ 1.0 color rgb <1, .2, 0>] // CENTER
}
}
#declare density_2 =
density{
spherical
color_map{ // smaller 'radius'
[0.0 rgb 0] // OUTSIDE
[0.6 rgb 0]
[0.7 rgb <1,1,0>]
[0.8 rgb <1,.3,0>]
[1.0 rgb <1,.3,0>] // CENTER
}
scale <1,.6,1> // to flatten it
translate .65*y
rotate -20*x // optional
}
density{
average
density_map{
[.4 density_1] // reduced density
[1.0 density_2]
}
}
}
}
scale 1.3
translate y*1.612
}
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
I found a very simple solution for the "magic light".
I remembered that "GIMP" can export gradients into POV-Ray Color_maps (Select
the gradient you want to export and click the right mouse button).
So I searched in "GIMP" for a suitable gradient for "magic lights" and found it
in
the gradient "Deep Sea".
The colors of this GIMP-generated Color_map I took over into the media
density_map....and
that was it.
In my WIP-Scene the "magic light" currently looks like in the attached image
shown.
And here a sample scene:
(exported code out of the KPOV-modeler)
---[Snip]-----
global_settings {
assumed_gamma 1.5
noise_generator 2
}
union {
//*PMName Magische Kugel
sphere { <0, 0, 0>, 1.1
pigment { color rgbt <1, 1, 1, 1> }
interior {
media {
density { spherical
density_map {
[ 0 color rgb <0, 0.00904, 0.166667> ]
[ 0.580968 color rgb <0.089516, 0.199522, 0.393939> ]
[ 0.764608 color rgb <0.179032, 0.390004, 0.621212> ]
[ 0.764608 color rgb <0.179032, 0.390004, 0.621212> ]
[ 0.888147 color rgb <0.08951, 0.679851, 0.795454> ]
[ 1 color rgb <0, 0.969697, 0.969697> ]
}
}
density { spherical }
emission rgb <1, 1, 0.9999>
}
}
scale 2
hollow
}
sphere { <0, 0, 0>, 1.15
pigment { color rgbt <1, 1, 1, 1> }
interior {
media {
density { spherical
density_map {
[ 0 color rgb <0, 0.00904, 0.166667> ]
[ 0.580968 color rgb <0.089516, 0.199522, 0.393939> ]
[ 0.764608 color rgb <0.179032, 0.390004, 0.621212> ]
[ 0.764608 color rgb <0.179032, 0.390004, 0.621212> ]
[ 0.888147 color rgb <0.08951, 0.679851, 0.795454> ]
[ 1 color rgb <0, 0.969697, 0.969697> ]
}
}
density { spherical }
emission rgb <1, 1, 0.9999>
}
}
scale 1.5
matrix < 1.61803, 0, 0,
0, 1.61803, 0,
0, 0, 1.61803,
0, 0, 0 >
hollow
}
}
light_source { <4, 5, -5>, rgb <1, 1, 1> }
camera {
perspective
location <0, 0, -5>
sky <0, 1, 0>
direction <0, 0, 1>
right <1.3333, 0, 0>
up <0, 1, 0>
look_at <0, 0, 0>
}
---[Snap]-----
Post a reply to this message
Attachments:
Download 'magiclight.png' (385 KB)
Preview of image 'magiclight.png'
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Meothuru wrote:
> In my WIP-Scene the "magic light" currently looks like in the attached image
> shown.
sweet
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
You're 2nd image is very nice--much improved!
"Meothuru" <nomail@nomail> wrote:
[*snip*]
> interior {
> media {
> density { spherical
>
> density_map {
> [ 0 color rgb <0, 0.00904, 0.166667> ]
> [ 0.580968 color rgb <0.089516, 0.199522, 0.393939> ]
> [ 0.764608 color rgb <0.179032, 0.390004, 0.621212> ]
> [ 0.764608 color rgb <0.179032, 0.390004, 0.621212> ]
> [ 0.888147 color rgb <0.08951, 0.679851, 0.795454> ]
> [ 1 color rgb <0, 0.969697, 0.969697> ]
> }
[*snip*]
I thought you might like to know that a density_map isn't necessary here--just a
color_map. (But both of them work, of course.) I was confused about that as
well, for a long time. A density_map is really for listing multiple density
blocks, rather than just colors.
I also noticed that you had a second density in each
sphere...spherical{density}...without a color_map. I guess you wanted that on
purpose, but all it is doing is adding media brightness (no color) to your
sphere. (It is using a default color_map, which I think is just black to
white--or in the case of media, it represents 'no' media to 'full' media.) You
could eliminate those extra densities, to get richer colors.
Ken W.
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
|
|
